#INCLUDE State_Manager

INIT
	USING State_Manager
	CHARACTER:__Me

	INT:%CanDoAD = 1
	FLOAT:%ADDelayTime = 24.0
	FIXEDSTRING:%MainDialog = "6bb143b8-a086-68ed-3310-420e7dccc3e5"
	ITEM:%CageDoor = S_GOB_WolfPens_CageDoor_002_19b032a0-e027-4524-96f9-1c0cd48d726e

BEHAVIOUR

REACTION State_Act1WolfPens, 0
USAGE PEACE
ACTIONS
	DebugText(__Me, "DEBUG: I'm in Wolf Pens, imprisoned")
	Sleep(2.0)
	CallFunction("Function_Talk")
	Sleep(%ADDelayTime)

// Default state for Helia in Forest
REACTION State_Act1Forest, 0
USAGE PEACE
ACTIONS
	DebugText(__Me, "DEBUG: I'm in Forest, waiting for recruitment")
	Sleep(4.0)

REACTION State_WolfForm, 0
USAGE PEACE
ACTIONS
	IF "c1&!c2"//&!c3"
		CharacterIsInTrigger(__Me, S_GOB_WolfPens_Cage002Trigger_59104718-66ff-418a-b7ac-46696a1e2fc3)
		ItemIsDestroyed(%CageDoor)
		//ItemIsOpen(%CageDoor)
	THEN
		DebugText(__Me, "DEBUG: Attacking the door animation")
		ItemEvent(%CageDoor, "GOB_WolfPens_Splatter")
		Sleep(1.0)
		SetPriority(%currentAction, 0)
	ENDIF

REACTION State_Act1Camp, 0
USAGE PEACE
VARS
	FLOAT:_Dist
CHECK "c1"
	HasFlag(__Me, "CAMP_GLO_State_InCamp")
ACTIONS
	IF "!c1&c2&c3"
		IsInDangerousSurface(TRIGGER:S_CAMP_DenLeader_471b881e-bff2-41c9-b4e1-fe3ef0d82520, __Me, 2.0)
		GetDistance(_Dist, __Me, TRIGGER:S_CAMP_DenLeader_471b881e-bff2-41c9-b4e1-fe3ef0d82520)
		IsGreaterThen(_Dist, 2.0)
	THEN
		CharacterMoveTo(TRIGGER:S_CAMP_DenLeader_471b881e-bff2-41c9-b4e1-fe3ef0d82520)
		CharacterLookFrom(TRIGGER:S_CAMP_DenLeader_471b881e-bff2-41c9-b4e1-fe3ef0d82520)
	ENDIF
	IF "c1"
		IsInDangerousSurface(__Me)
	THEN
		CharacterFleeFromDangerousSurface()
	ENDIF
	Sleep(1.0)

EVENTS
EVENT Function_Talk
ON
	OnFunction("Function_Talk")
ACTIONS
	IF "!c1&c2"
		IsEqual(%MainDialog, "")
		IsEqual(%CanDoAD, 1)
	THEN
		DialogStart(_, %MainDialog, __Me)
		Set(%CanDoAD,0)
		StartTimer("PreventADFromPlaying", %ADDelayTime, 0)
	ENDIF

EVENT Event_ADTimerOff
ON
	OnTimer("PreventADFromPlaying")
ACTIONS
	Set(%CanDoAD,1)

EVENT Event_OnDenLeaderTransformedIntoWolf
ON
	OnGlobalFlagSet("GOB_WolfPens_State_DenLeaderTransformed")
ACTIONS
	SetPriority("State_WolfForm", 1700)

EVENT Event_OnDenLeaderTransformedIntoHuman
ON
	OnGlobalFlagCleared("GOB_WolfPens_State_DenLeaderTransformed")
	OnGlobalFlagSet("GLO_DenLeader_State_IsFree")
ACTIONS
	SetPriority("State_WolfForm", 0)