Realtek 8852XX Settings

@echo off
title Realtek 8852XX Settings
color 02

:CheckPermissions
    fltmc >nul 2>&1 || (
        echo Requesting administrative privileges . . .
        powershell -NoProfile -Command "$p=@{FilePath='%~f0';Verb='RunAs'};if('%*'){$p.ArgumentList='%*'};Start-Process @p" 2>nul
        exit /b 0
    )

cd /d "%~dp0"

if /i "%~1" == "nopause" (
    set NOPAUSE=1
) else (
    set NOPAUSE=0
)

:Work
    echo Searching for Realtek 8852XX NIC in registry . . .

    set "FOUND=0"
    set "CLASSKEY=HKLM\SYSTEM\CurrentControlSet\Control\Class\{4d36e972-e325-11ce-bfc1-08002be10318}"
    for /f "tokens=*" %%K in ('reg query "%CLASSKEY%"') do (
        for /f "tokens=2*" %%A in ('reg query "%%K" /v "DriverDesc" 2^>nul ^| findstr /i /c:"Realtek 8852"') do (
            if "%%B" neq "" (
                set "NIC_KEY=%%K"
                set "FOUND=1"
                goto :ReadNetCfgInstanceId
            )
        )
    )

    if "%FOUND%"=="0" (
        echo Realtek 8852XX NIC not found.
        goto :End
    )

:ReadNetCfgInstanceId
    REM Read NetCfgInstanceId directly from the already-found NIC_KEY.
    set "NIC_GUID="
    for /f "tokens=3" %%G in ('reg query "%NIC_KEY%" /v "NetCfgInstanceId" 2^>nul') do set "NIC_GUID=%%G"

    if "%NIC_GUID%"=="" (
        echo Could not read NetCfgInstanceId from %NIC_KEY%.
        goto :End
    )

    REM echo Found Realtek 8852XX at %NIC_KEY%
    REM echo NIC GUID: %NIC_GUID%

:ApplySettings
    echo Applying settings . . .

    REM Set Power Management > [ ] Allow the computer to turn off this device to save power
    REM NOTE: The default value was "PnPCapabilities"=dword:00000010.
    reg add "%NIC_KEY%" /v "PnPCapabilities" /t REG_DWORD /d 0x18 /f

    REM -----

    REM Set 2.4G Wireless Mode from IEEE 802.11b/g/n/ax to IEEE 802.11b/g/n.
    REM NOTE: The default value was "WifiProtocol_2g"="45".
    reg add "%NIC_KEY%" /v "WifiProtocol_2g" /t REG_SZ /d "13" /f

    REM Set 5G Wireless Mode from IEEE 802.11a/n/ac/ax to IEEE 802.11a/n/ac.
    REM NOTE: The default value was "WifiProtocol_5g"="58".
    reg add "%NIC_KEY%" /v "WifiProtocol_5g" /t REG_SZ /d "26" /f

    REM Set 6GHz Band: Disabled.
    REM NOTE: The default value was "WifiProtocol_6G"="34".
    reg add "%NIC_KEY%" /v "WifiProtocol_6G" /t REG_SZ /d "0" /f

    REM Set 802.11d: Disabled.
    REM NOTE: The default value was "Dot11dEnable"="0".
    reg add "%NIC_KEY%" /v "Dot11dEnable" /t REG_SZ /d "0" /f

    REM Set Bandwidth: Auto.
    REM NOTE: The default value was "WifiBandwidth_phy0"="15".
    reg add "%NIC_KEY%" /v "WifiBandwidth_phy0" /t REG_SZ /d "15" /f

    REM Set Beacon Interval: 100.
    REM NOTE: The default value was "AH_BcnIntv"="100".
    reg add "%NIC_KEY%" /v "AH_BcnIntv" /t REG_SZ /d "100" /f

    REM Set MAC Randomization: Disabled.
    REM NOTE: The default value was "SupportMACRandom"="1".
    reg add "%NIC_KEY%" /v "SupportMACRandom" /t REG_SZ /d "0" /f

    REM Set Multi-Channel Concurrent: Enabled.
    REM NOTE: The default value was "MCCSup"="1".
    reg add "%NIC_KEY%" /v "MCCSup" /t REG_SZ /d "1" /f

    REM Set Preamble Mode: Short & long.
    REM NOTE: The default value was "PreambleMode"="2".
    reg add "%NIC_KEY%" /v "PreambleMode" /t REG_SZ /d "2" /f

    REM Set Preferred Band: 3. 5G first.
    REM NOTE: The default value was "PreferBand"="2", the 0-based index for option "3. 5G first".
    reg add "%NIC_KEY%" /v "PreferBand" /t REG_SZ /d "2" /f

    REM -----

    REM Set Roaming Aggressiveness: 2. Lowest.
    REM NOTE: The default value was "RegRoamLevel"="3", the 0-based index for option "2. Lowest".
    REM reg add "%NIC_KEY%" /v "RegRoamLevel" /t REG_SZ /d "1" /f

    REM Set Roaming Aggressiveness: 1. Disable.
    REM NOTE: The default value was "RegRoamLevel"="0", the 0-based index for option "1. Disable".
    reg add "%NIC_KEY%" /v "RegRoamLevel" /t REG_SZ /d "0" /f

    REM -----

    REM Set Wake on Magic Packet: Disabled.
    REM NOTE: The default value was "*WakeOnMagicPacket"="1".
    reg add "%NIC_KEY%" /v "*WakeOnMagicPacket" /t REG_SZ /d "0" /f

    REM Set Wake on Pattern Match: Disabled.
    REM NOTE: The default value was "*WakeOnPattern"="1".
    reg add "%NIC_KEY%" /v "*WakeOnPattern" /t REG_SZ /d "0" /f

    REM -----

    REM Disable aggressive power savings that results in high pings when not downloading, i.e. when matchmaking in games.
    REM NOTE: The default value was "LpsEn"="2".
    REM SOURCE: https://www.reddit.com/r/gigabyte/comments/1bhw1n7/b650_realtek_wifi_dropsping_spikes_solution/
    REM SOURCE: https://h30434.www3.hp.com/t5/Notebook-Wireless-and-Networking/connection-issues-with-Realtek-RTL8852AE-WiFi-6-802-11ax/td-p/8157951/page/5
    reg add "%NIC_KEY%" /v "LpsEn" /t REG_SZ /d "0" /f

:RestartNIC
    echo Restarting NIC . . .

    REM Use NetCfgInstanceId (stored in NIC_GUID) to locate the adapter via InterfaceGuid.
    powershell -Command "$a = Get-NetAdapter | Where-Object { $_.InterfaceGuid -eq '%NIC_GUID%' }; if (-not $a) { Write-Error 'Adapter could not be located.'; exit 1 }; $a | Disable-NetAdapter -Confirm:$false; Start-Sleep -Seconds 2; $a | Enable-NetAdapter -Confirm:$false"
    if %errorlevel% neq 0 (
        echo NIC restart failed.
        goto :End
    )

:End
    if %NOPAUSE% equ 0 pause
    goto :eof