tupplespacepackage-realtupples.ads

pragma Ada_2022;
with Ada.Containers.Hashed_Maps, Ada.Containers.Synchronized_Queue_Interfaces, Ada.Tags, Ada.Finalization, System.Storage_Elements, Ada.Containers.Unbounded_Synchronized_Queues, Ada.Strings.Unbounded;
use Ada.Strings.Unbounded;
private with Ada.Strings.Hash, Ada.Containers.Vectors;

package tupplespacepackage.RealTupples is
	type MyMapType is limited private;
	protected type RealTuppleSpace is new TuppleSpace with
	   overriding
	   procedure Out_Operation
	     (T : Tupple'Class);
	   overriding
	   entry In_Operation
	     (Result  : out Tupple'Class);
	   overriding
	   entry RD_Operation
	     (Result  : out Tupple'Class);
	   overriding
	   procedure Inp_Operation
	     (Result  : out Tupple'Class);
	   overriding
	   procedure RDP_Operation
	     (Result  : out Tupple'Class);
	private
	   The_Map : MyMapType;
	end RealTuppleSpace;

	type Integer_Positive_String_Tupple is new Tupple with private;
	type String_String_Tupple is new Tupple with private;
	function Encode (I: Integer; Pos: Positive; A: String) return Integer_Positive_String_Tupple;
	function Encode (A, B: String) return String_String_Tupple;
	procedure Decode (the_Tupple: Integer_Positive_String_Tupple; I: out Integer; Pos: out Positive; A: out Ada.Strings.Unbounded.Unbounded_String);
	procedure Decode (the_Tupple: String_String_Tupple; A, B: out Ada.Strings.Unbounded.Unbounded_String);
	overriding procedure Copy_Into (A: Tupple'Class; B: out Integer_Positive_String_Tupple);
	overriding procedure Copy_Into (A: Tupple'Class; B: out String_String_Tupple);

private
	use Ada.Tags;
	type AccessToClass is access Tupple'Class;
	package newQueues is new Ada.Containers.Vectors (Positive, AccessToClass);
	subtype Queue is newQueues.Vector;
	protected type LockedQueue is
		procedure Out_Operation
		  (T : Tupple'Class);
		entry In_Operation
		  (Result  : out Tupple'Class);
		entry RD_Operation
		  (Result  : out Tupple'Class);
	private
		PatternQueue: Queue;
	end LockedQueue;
	type AccessToProtected is access LockedQueue;
	function Hash (A: Ada.Tags.Tag) return Ada.Containers.Hash_Type is (Ada.Strings.Hash (Ada.Tags.External_Tag(A)));
	package newMaps is new Ada.Containers.Hashed_Maps (Key_Type => Ada.Tags.Tag, Element_type => AccessToProtected, Hash => Hash, Equivalent_Keys => "=");
	type MyMapType is new newMaps.Map with null record;
	type Integer_Positive_String_Tupple is new Tupple with record
		I: Integer;
		Pos: Positive;
		A: Unbounded_String;
	end record;
	type String_String_Tupple is new Tupple with record
		A, B: Unbounded_String;
	end record;

end tupplespacepackage.RealTupples;