POST_48

/*  TITULO: Controlando LEDS con un mando a distancia y un receptor IR.

    AUTOR:

    MARIANO DEL CAMPO GARCÍA (@2016) --> INGENIERO TÉCNICO INDUSTRIAL ESPECIALIDAD ELECTRÓNICA
    - FACEBOOK: https://www.facebook.com/mariano.delcampogarcia
    - TWITTER: https://twitter.com/MarianoCampoGa
    - CORREO: marianodc83@gmail.com


    DESCRIPCIÓN DEL PROGRAMA

    Este programa nos sirve para controlar dos LEDS desde un mando a distancia IR.
    - Botón (-) --> Se enciende el LED ROJO.
    - Botón (+) --> Se enciende el LED AZUL.
    - Botón EQ --> Se apagan los dos LEDS.


    ESQUEMA DE CONEXION

                                      +-----+
         +----[PWR]-------------------| USB |--+
         |                            +-----+  |
         |         GND/RST2  [ ][ ]            |
         |       MOSI2/SCK2  [ ][ ]  A5/SCL[ ] |
         |          5V/MISO2 [ ][ ]  A4/SDA[ ] |
         |                             AREF[ ] |
         |                              GND[ ] |
         | [ ]N/C                    SCK/13[ ] |
         | [ ]IOREF                 MISO/12[ ] |
         | [ ]RST                   MOSI/11[ ]~|
         | [ ]3V3    +---+               10[ ]~|
         | [ ]5v    -| A |-               9[ ]~|
         | [ ]GND   -| R |-               8[ ] |
         | [ ]GND   -| D |-                    |
         | [ ]Vin   -| U |-               7[ ] |
         |          -| I |-               6[ ]~|
         | [ ]A0    -| N |-               5[ ]~|
         | [ ]A1    -| O |-               4[ ] |   LED_ROJO(+)
         | [ ]A2     +---+           INT1/3[ ]~|   LED_AZUL(+)
         | [ ]A3                     INT0/2[ ] |   Pin "S" (datos) del receptor IR
         | [ ]A4/SDA  RST SCK MISO     TX>1[ ] |
         | [ ]A5/SCL  [ ] [ ] [ ]      RX<0[ ] |
         |            [ ] [ ] [ ]              |
         |  UNO_R3    GND MOSI 5V  ____________/
          \_______________________/

  NOTAS:

   - Alimentación del módulo receptor IR  modelo AX 1838HS:
     - Pin central del receptor IR --> VCC de Arduino
     - Pin (-) del receptor IR --> GND de Arduino
   - Cátodos(-) de los LEDS a GND a través de una R=220 omhs (diferente para cada uno).

*/

  // Incluimos la librería IR
  #include <IRLremote.h>

  // Pin digital 2 (INT0: Interrupción 0) --> Terminal de datos (S) del receptor IR
  const int interruptIR = 0;

  // Variables para recibir los datos
  uint8_t Protocolo = 0;
  uint16_t Direccion = 0;
  uint32_t Comando = 0;

  int LED_AZUL = 3; // Pin digital para el LED de color azul
  int LED_ROJO = 4; // Pin digital para el LED de color rojo


  void setup()
  {
    Serial.begin(115200);  // Comienzo de la comunicación serie

    pinMode(LED_AZUL, OUTPUT); // Pin digital 3 como salida
    pinMode(LED_ROJO, OUTPUT); // Pin digital 4 como salida

    Serial.println("Esperando lecturas IR...\n");
    IRLbegin<IR_ALL>(interruptIR); // Comienzo de la recepción IR
  }

  void loop()
  {
    // Si se ha leido un protocolo existente en la librería
    if(Protocolo)
    {
      // Se presentan valores de protocolo, dirección y comando IR.
      Serial.println("-------------------------------");
      Serial.print("Protocolo:");
      Serial.println(Protocolo);
      Serial.print("Direccion:");
      Serial.println(Direccion, HEX);
      Serial.print("Comando:");
      Serial.println(Comando, HEX);
      Serial.println("-------------------------------");

      // Dependiendo del valor del comando, estaremos pulsando un botón u otro
      switch(Comando)
      {
        case 0xE01F:
          Serial.println("Boton -");
          digitalWrite(LED_ROJO, HIGH);
          break;
        case 0xA857:
          Serial.println("Boton +");
          digitalWrite(LED_AZUL, HIGH);
          break;
        case 0x906F:
          Serial.println("Boton EQ");
          digitalWrite(LED_ROJO, LOW);
          digitalWrite(LED_AZUL, LOW);
          break;
        default:
          Serial.println("Boton sin etiquetar");
          break;
      }
      Serial.println("-------------------------------");
      Protocolo = 0;
    }
  }

  // Rutina de servicio de la interrupción INT 0 --> Pin 2 de Arduino
  void IREvent(uint8_t protocol, uint16_t address, uint32_t command)
  {
    // Se guardan los valores de protocolo, dirección y comando recibidos
    Protocolo = protocol;
    Direccion = address;
    Comando = command;
  }