Generate QLab OSC Cues

tell application id "com.figure53.QLab.4"
    set workspaceTitle to q number of front document as string
    try
        display dialog "Set cue prefix: " default answer "AV" with title "Set Prefix" buttons {"Cancel", "OK"} default button "OK" cancel button "Cancel"
        set theResponse to text returned of result
        repeat with theCue in (selected of front workspace as list)
            set theCueNumber to the q number of theCue
            if theCueNumber is not "" then
                if first word of theCueNumber is equal to theCueNumber then
                    set theCueName to the q display name of theCue
                    make front workspace type "Network"
                    set newCue to last item of (selected of front workspace as list)
                    set custom message of newCue to "/workspace/" & workspaceTitle & "/cue/" & theCueNumber & "/go"
                    set q name of newCue to theResponse & theCueNumber & ": " & theCueName
                    set q color of newCue to "green"
                else
                    my creationError("Cue number should not include spaces", theCue)
                end if
            else
                my creationError("Cue does not have a number", theCue)
            end if
        end repeat
    end try
end tell
on creationError(errorMessage, theCue)
    tell application id "com.figure53.QLab.4"
        make front workspace type "Goto"
        set newCue to last item of (selected of front workspace as list)
        set cue target of newCue to theCue
        set q name of newCue to errorMessage & (q name of theCue)
        set flagged of newCue to true
        set q color of newCue to "red"
    end tell
end creationError