lastusermake

on *:connect: { .timer.lastuser 0 20 lastuser }
alias lastuser {
  if ($window(@NewUsers) == $null) { window -n @NewUsers }
  sockclose lu
  sockopen lu spcn.io 80
}
on *:sockopen:lu:{
  if ($sockerr) { sockclose $sockname | echo -a error | halt }
  sockwrite -n $sockname GET /Members/ HTTP/1.1
  sockwrite -n $sockname HOST: spcn.io
  sockwrite -n $sockname $crlf $+ $crlf
}
on *:sockread:lu: {
  if ($sockerr < 0) { echo -a $sockerr | halt }
  var %lu
  sockread -fn %lu
  if ($regex(%lu,/<li><a href="/Members/(.*?)">&gt;&gt;</a></li>/gi)) {
    getlastuser $regml(1)
    sockclose $sockname
  }
}
alias getlastuser {
  sockclose glu
  sockopen glu spcn.io 80
  sockmark glu $1
}
on *:sockopen:glu:{
  if ($sockerr) { sockclose $sockname | echo -a error | halt }
  sockwrite -n $sockname GET /Members/ $+ $sock($sockname).mark HTTP/1.1
  sockwrite -n $sockname HOST: spcn.io
  sockwrite -n $sockname $crlf $+ $crlf
}
on *:sockread:glu: {
  if ($sockerr < 0) { echo -a $sockerr | halt }
  var %glu
  sockread -fn %glu
  if ($regex(%glu,/<td><a href="/u/(.*)">(.*)</a></td>/gi)) {
    set %lastruserid $regml(1)
    set %lastruser $regml(2)
  }
  if (</table> isin %glu) {
    sockclose $sockname
    if (%lastruserstored != %lastruser) {
      set %lastruserstored %lastruser
      echo @NewUsers Logged: $asctime(m/dd/yyyy $+ $chr(44) h:nn:ss TT)
      echo @NewUsers New User: %lastruser - http://spcn.io/u/ $+ %lastruserid
      echo @NewUsers ===================================================
      /msg %#SPCNHQ Logged: $asctime(m/dd/yyyy $+ $chr(44) h:nn:ss TT)
      /msg %#SPCNHQ New User: %lastruser - http://spcn.io/u/ $+ %lastruserid
      /msg %#SPCNHQ ===================================================
    }
  }
}