03_05

//  EXT_ROM_Ram_03_05 2025 August 17 ( 16:38 )
//  КР580ВВ55А РАБОТАЕТ! с резистором pull-up к /WR
//
//  Этот тест для проверки КР580ВВ55А или 82C55A





  const int CS_PIN    = 11;                                                            // /CS (Chip Select)    82C55
//const int RESET_PIN = 19;   //  A5                                                   // Reset                82C55
  #define RESET_PIN     A5                                                             // Reset                82C55
  const int OE_PIN    = 12;                                                            // Output Enable     74HCT573
  const int LE_PIN    = 13;                                                            // Latch  Enable     74HCT573


const int DATA_PINS[] = {2, 3, 4, 5, 6, 7, 8, 9};                                      //   Пины данных для 74HCT573


////////////////////////////////////////////////
void setup()
{

     pinMode(CS_PIN,    OUTPUT);  digitalWrite(CS_PIN,   1);                           //         Запрет выбора ВВ55
     pinMode(RESET_PIN, OUTPUT);
     pinMode(OE_PIN,    OUTPUT);  digitalWrite(OE_PIN, LOW);                           //     74HCT573 output enable
     pinMode(LE_PIN,    OUTPUT);  digitalWrite(LE_PIN,   1);

     for(int i = 0; i < 8; i++)
     {
         pinMode(DATA_PINS[i], OUTPUT);
     }


    digitalWrite(RESET_PIN, 1);        delay(5);                  //           Сброс КР580ВВ55А  (Активируем RESET)
    digitalWrite(RESET_PIN, 0);        delay(5);




     // STEP 1                                                    //   Запишем байт в 74HCT573 ( /WR, /RD, A1, A0 )
                                                                  //                         ...для управления ВВ55
                                                                  //    Используются только 4 младших бита (справа).
     set_value(0b00000111);                                       //   A1 = 1,  A0 = 1  ( выбирают регистр "РУС")
     digitalWrite(LE_PIN,   0);                                   //  /WR = 0, /RD = 1  ( разрешение записи     )


     // STEP 2
                                                                  // Теперь надо поместить конфигурирующий байт в "РУС"
     set_value(0b10000000);                                       // 10000000 - все порты ВВ55, как выходы ( режим 0 )
     digitalWrite(CS_PIN,   0);                                   // Выбран (для записи) ВВ55
     digitalWrite(OE_PIN,   1);                                   // Выключаем на мгновение 573, чтобы защёлкнулся байт
     digitalWrite(CS_PIN,   1);                                   // Отключаем ВВ55 ( Порты продолжают удерживать биты)
     digitalWrite(OE_PIN,   0);                                   // Снова активируем 573

                         //   Настройка ВВ55 завершена! Установлен режим = 0 и все порты (A, B, C) настроены на вывод.
}








/////////////////////////////////////////////////       Тут циклически перебирем биты ( порт A ) разными способами.
void loop()
{

                                               //  Один бит движется влево, затем вправо ( 8 раз это повторяется ).
     for(int i1 = 0; i1 <  8; i1++)   {
     for(int i2 = 0; i2 <  8; i2++)   { to_port_A(1 << i2); delay(250);  }
     for(int i3 = 7; i3 >= 0; i3--)   { to_port_A(1 << i3); delay(250);  }  }



     for(int i = 0; i < 10; i++)               // Здесь биты через один горят в шахматном порядке. ( 10 повторов ).
     {
         to_port_A(170);   delay( 500);        //                                                 170 = 0b10101010
         to_port_A( 85);   delay(1000);        //                                                  85 = 0b01010101
     }

     for(int i = 0; i < 256; i++)              //                           Перебор битов, как в двоичном счётчике.
     {
         to_port_A(i);
         delay(100);                           //                Задержка (0,1 секунда) для визуального наблюдения.
     }
}





//
//    *1  Чтобы 573 перешла в Z-состояние и pull-up резистор подтянул сигнал /WR_55 к 1. Это нужно для "защёлкивания"
//        байта с шины данных именно для ВВ55. 82C55A не капризна, при записи байта.
//
//
//
//
//
//
//
//



////////////////////////////////////////////////
void to_port_A(byte  value)
{

     digitalWrite(LE_PIN,   1);
     set_value(0b00000100);                                       //   A1 = 0,  A0 = 0  ( выбираем порт А )
     digitalWrite(LE_PIN,   0);                                   //  /WR = 0, /RD = 1  (разрешение записи)

     set_value(   value);                                         // 10000000 - все порты ВВ55, как выходы ( режим 0 )
     digitalWrite(CS_PIN,   0);
     digitalWrite(OE_PIN,   1);                                   // Откл.   573 (*1)
     digitalWrite(CS_PIN,   1);                                   // Откл.  ВВ55
     digitalWrite(OE_PIN,   0);                                   // Вкл.    573
}


////////////////////////////////////////////////
void to_port_B(byte  value)
{
     digitalWrite(LE_PIN,   1);
     set_value(0b00000101);                                       //    A1 = 0,  A0 = 1 ( выбираем порт B )
     digitalWrite(LE_PIN,   0);                                   //   /WR = 0, /RD = 1  (разрешение записи)

     set_value(   value);                                         // 10000000 - все порты ВВ55, как выходы ( режим 0 )
     digitalWrite(CS_PIN,   0);                                   // Обращаемся для записи байта к ВВ55
     digitalWrite(OE_PIN,   1);
     digitalWrite(CS_PIN,   1);
     digitalWrite(OE_PIN,   0);                                   // Снова включаем-активируем   74HCT573
}



////////////////////////////////////////////////
void set_value(byte value)                                        //  Функция установки байта на пины D2-D9
{                                                                 //  Это внутренняя шина (D2-D9) данных. Она свя-
                                                                  //  зывает ARDUINO UNO, 74HCT573 и КР580ВВ55А.
     for(int i = 0; i < 8; i++)
     {
         digitalWrite(DATA_PINS[i], bitRead(value, i));           //  Выставляем данные на выходы
     }
}