woecreditshop

//===== Hercules Script ======================================
//= War of Emperium Credit Store
//===== By ===================================================
//= Wolfie
//===== Description ==========================================
//= Shop data to redeem War of Emperium Credits.
//= Shop opened through /npc/blackout/donate/CommonRedeem.txt
//============================================================

-   trader  WOE_Credit_Shop FAKE_NPC,{

OnMon0000:
    .@i = 2; // change this number to how many items get rotated per week
    .@size[0] = getarraysize(.TwoCred);
    .@size[1] = getarraysize(.TenCred);

    if ($WOECREDSHOP[0] + .@i >= .@size[0])
        $WOECREDSHOP[0] = cap_value($WOECREDSHOP[0] + - .@size[0] -1, 0, .@size[0]);
    else
        $WOECREDSHOP[0] += .@i;

    if ($WOECREDSHOP[1] + .@i >= .@size[1])
        $WOECREDSHOP[1] = cap_value($WOECREDSHOP[1] + - .@size[1] -1, 0, .@size[1]);
    else
        $WOECREDSHOP[1] = .@i;

    globalmes("New items in stock in the WoE Credit Shop!", "Item Redeeming Services");

OnTue0000:
OnWed0000:
OnThu0000:
OnFri0000:
OnSat0000:
OnSun0000:
OnInit:
    .Currency = WOE_Credit;
    tradertype(NST_CUSTOM);

    .@d = gettime(GETTIME_DAYOFMONTH);
    .@m = gettime(GETTIME_MONTH);
    .@y = gettime(GETTIME_YEAR);

    // Temp remove all items
    for (.@i = 0; .@i < getarraysize(.Item); .@i += 2) {
        if (.Item[.@i] > 0)
            stopselling(.Item[.@i]);
    }

    //  2 WOE Credits Rotation
    setarray(.TwoCred,
        Aztec_Helm, // Aztec Headdress
        callsub(S_Drooping_Falcon), // Drooping Falcon
        Kitty_Ribbon_Hat,
        Br_Beret, // Banana Beret
        Mosquito_Coil,
        Tongue_Mask_,
        B_Feather_Beret,
        Fallen_Leaves_,
        Engineer_Cap,
        Jaguar_Hat,
        Sinsuncho_Hat,
        Desert_Prince,
        Strawberry_Hat,
        Turtle_Hat,
        Coati_Hat,
        Kettle_Hat,
        Pig_Head_Balloon,
        Rasta_Wig,
        Sapling_Hat,
        Tiger_Mask,
        Saci_Hat, // Luxury Hat
        Fox_Hat_J, // Fox Mask
        24_Bolt // Screw Stuck Head
    );

    //  10 WOE Credits Rotation
    setarray(.TenCred,
        Red_Wing_Hat,
        Clock_Tower_Hat,
        Ninja_Helm,
        Cygnus_Helm,
        Schmidt_Helm, // Dip Schmidtz Helm
        C_Dark_Night_Veil,
        C_Undertaker_Hat,
        Trident_Helmet,
        Ancient_Admiral_Helm,
        SS_Bandana, // Secret Society Hood
        Midas_Whispers,
        Heart_Wing_Hairband,
        Humming_Bird,
        Chinese_Knot,
        Moogle_Antenna,
        Owl_Noir,
        Rabbit_Knit_Hat,
        Holy_Egg_Hat, // Sacred Egg Hat
        Cat_of_Doom,
        Golden_Wing,
        Robin_Hands, // Hana Hana no Mi
        Space_Cat,
        Cool_FB_Hat, // Cool Football Hat
        Glory_FB_Hat, // Glorious Football Hat
        Passion_FB_Hat, // Passionate Football Hat
        Victory_FB_Hat, // Football Hat
        Hawk_Eye,
        Shining_Pirate_Dagger,
        Deviruchi_Balloon,
        Piamette_Hood,
        Sleeping_Kitty_Cat,
        C_Bf_Recruiter_Hat,
        C_Friend_Recruiter_Hat,
        C_Gf_Recruiter_Hat,
        C_Guildsman_Recruiter,
        C_Party_Recruiter_Hat,
        B_Dragon_Hat,
        Blue_Pajamas_Hat,
        Pink_Pajamas_Hat,
        Notice_Board, // Afk Hat
        C_Black_Cat_Hood,
        C_Drooping_Eleanor,
        C_Feathered_Top_Hat,
        C_Starry_Night_Beret,
        callsub(S_FlowerBunnyHat),
        callsub(S_FrilledFlowerCollar),
        C_Kittens_In_Basket,
        callsub(S_SweetBalloonHat),
        C_Khalitzburg_KN_Helm,
        C_Gryphon_Hat,
        (rand(2)) ? C_Lamb_Hat1 : C_Lamb_Hat2,
        C_Monkey_Fur_Hat,
        Vagabond_Wolf_Hat,
        C_Soft_Sheep_Hat,
        Puppy_Ears_Hat,
        C_Polar_Bear_Cap
    );

    // Collab Shops Revamp Edit - Began from Dec 22, 2020
    setarray(.Item,
        //  2 WOE Credits
        callsub(S_Rotation, 2, 0), 2,
        callsub(S_Rotation, 2, 1), 2,
        callsub(S_Rotation, 2, 2), 2,
        callsub(S_Rotation, 2, 3), 2,
        callsub(S_Rotation, 2, 4), 2,

        //  10 WOE Credits
        callsub(S_Rotation, 10, 0), 10,
        callsub(S_Rotation, 10, 1), 10,
        callsub(S_Rotation, 10, 2), 10,
        callsub(S_Rotation, 10, 3), 10,
        callsub(S_Rotation, 10, 4), 10,

        //  50 WOE Credits
        Chubby_Chick, 50,
        Glowing_Rose_Eye_Patch, 50,
        Warm_Cat_Muffler_, 50,
        (rand(10) < 7) ? C_Panda_Hood : C_Panda_Hood_Pink, 50, // 30% chance of Pink version
        C_Cute_Baby_Chicks, 50,
        C_Clock_Tower_Manager_Incom, 50,
        C_Wing_Frame_Sunglasses, 50,
        callsub(S_CrazyInLoveAura), 50,
        callsub(S_DaftPunk), 50,    // Choose which Daft Punk Helmet
        callsub(S_IcicleWings), 50,
        callsub(S_MusicRing), 50,
        callsub(S_MythicalWings), 50,
        C_White_Black_Temp, 50,
        callsub(S_EremesScarf), 50,
        Wolf_Masquerade, 50,
        C_Drooping_Dorasuke, 50,
        C_Oliver_Wolf_Hood, 50,
        Wolf_Tail, 50,

        // [REMOVE] Classic_Loot_Box, 25,
        // [REMOVE] callsub(S_ClassicLootBox), 45,
        // [REMOVE] Mysterious_Dyestuff, 50,

    -1, -1); // End don't edit

    for (.@i = 0; .@i < getarraysize(.Item); .@i += 2) {
        if (.Item[.@i] > 0)
            sellitem(.Item[.@i], .Item[.@i + 1]);
    }
    end;


S_Rotation:
    switch (getarg(0)) {
    case 2:
        .@i = $WOECREDSHOP[0] + getarg(1);
        .@size = getarraysize(.TwoCred) - 1;
        if (.@i > .@size)
            .@i -= .@size + 1;
        return .TwoCred[.@i];

    case 10:
        .@i = $WOECREDSHOP[1] + getarg(1);
        .@size = getarraysize(.TenCred) - 1;
        if (.@i > .@size)
            .@i -= .@size + 1;
        return .TenCred[.@i];

    default:
        return -1;
    }

S_Drooping_Falcon:
    setarray(.@id, Drooping_Falcon, Drooping_Falcon, Drooping_Falcon, Fire_Drooping_Falcon, Ice_Drooping_Falcon);
    return .@id[rand(getarraysize(.@id))];

S_FlowerBunnyHat:
    if (rand(10) < 8)
        return C_Flower_Bunny_Hat; // 20% chance of recolour
    return F_ReturnRand(C_Flower_Bunny_Hat_Black, C_Flower_Bunny_Hat_Blue, C_Flower_Bunny_Hat_Green, C_Flower_Bunny_Hat_Purple, C_Flower_Bunny_Hat_White, C_Flower_Bunny_Hat_Yellow);

S_FrilledFlowerCollar:
    if (rand(10) < 8)
        return C_Frilled_Flower_Collar; // 20% chance of recolour
    return F_ReturnRand(C_Frilled_Flower_Collar_Aqua, C_Frilled_Flower_Collar_Black, C_Frilled_Flower_Collar_Green, C_Frilled_Flower_Collar_Orange, C_Frilled_Flower_Collar_Pink, C_Frilled_Flower_Collar_Purple, C_Frilled_Flower_Collar_Red, C_Frilled_Flower_Collar_White, C_Frilled_Flower_Collar_Yellow);

S_SweetBalloonHat:
    if (rand(10) < 8)
        return C_Sweet_Balloon_Hat; // 20% chance of recolour
    return F_ReturnRand(C_Sweet_Balloon_Hat_Aqua, C_Sweet_Balloon_Hat_Black, C_Sweet_Balloon_Hat_Green, C_Sweet_Balloon_Hat_Grey, C_Sweet_Balloon_Hat_Orange, C_Sweet_Balloon_Hat_Pink, C_Sweet_Balloon_Hat_Purple, C_Sweet_Balloon_Hat_Red, C_Sweet_Balloon_Hat_Yellow);

S_CrazyInLoveAura:
    if (rand(10) < 8)
        return C_Crazy_In_Love_Aura; // 20% chance of recolour
    return F_ReturnRand(C_Crazy_In_Love_Aura_Aqua, C_Crazy_In_Love_Aura_Black, C_Crazy_In_Love_Aura_Blue, C_Crazy_In_Love_Aura_Green, C_Crazy_In_Love_Aura_Orange, C_Crazy_In_Love_Aura_Pink, C_Crazy_In_Love_Aura_Purple, C_Crazy_In_Love_Aura_White, C_Crazy_In_Love_Aura_Yellow);

// Conditions to sell Daft Punk Helmet
S_DaftPunk:
    switch (gettime(GETTIME_WEEKDAY)) {
    case WEDNESDAY:
    case FRIDAY:
        return C_Daft_Punk_Gold;
    case THURSDAY:
    case SATURDAY:
        return C_Daft_Punk_Silver;
    default:
        return -1;
    }

S_MusicRing:
    if (rand(10) < 8)
        return C_Music_Ring; // 20% chance of recolour
    return F_ReturnRand(C_Music_Ring_Black, C_Music_Ring_Blue, C_Music_Ring_Brown, C_Music_Ring_Green, C_Music_Ring_Orange, C_Music_Ring_Pink, C_Music_Ring_Purple, C_Music_Ring_Red, C_Music_Ring_White, C_Music_Ring_Yellow);

S_IcicleWings:
    if (rand(10) < 8)
        return C_Icicle_Wings; // 20% chance of recolour
    return F_ReturnRand(C_Icicle_Wings_Green, C_Icicle_Wings_Pink, C_Icicle_Wings_Red, C_Icicle_Wings_White, C_Icicle_Wings_Yellow);

S_MythicalWings:
    if (rand(10) < 8)
        return C_Mythical_Wings; // 20% chance of recolour
    return F_ReturnRand(C_Mythical_Wings_Green, C_Mythical_Wings_Red, C_Mythical_Wings_Yellow);

S_EremesScarf:
    if (rand(10) < 7)
        return C_Eremes_Scarf; // 30% chance of recolour
    return F_ReturnRand(C_Eremes_Scarf_Aqua, C_Eremes_Scarf_Black, C_Eremes_Scarf_Blue, C_Eremes_Scarf_Cyan, C_Eremes_Scarf_Gold, C_Eremes_Scarf_Green, C_Eremes_Scarf_Pink, C_Eremes_Scarf_Purple, C_Eremes_Scarf_White);

OnCountFunds:
    setcurrency(countitem(.Currency));
    end;

OnPayFunds:
    if (countitem(.Currency) < @price)
        end;
    delitem(.Currency, @price);
    purchaseok();
    F_LogTrader(.Currency);
    F_DeductCurrency(@price, .Currency);
    end;

}