Reset TCP options to default on Windows 10/11

@echo off
title Network Settings Notice

echo ==========================================
echo   IMPORTANT NOTICE ABOUT "OPTIMIZATIONS"
echo ==========================================
echo.
echo If you've used random "network optimizers", guides,
echo or videos that promise better ping or FPS, they may
echo have changed low-level network settings in risky ways.
echo.
echo This tool will push advanced TCP network tuning back
echo toward the Windows defaults and undo some of those tweaks.
echo.
echo If you do NOT want that, just close this window now.
echo Otherwise, press any key to continue.
echo.
pause >nul

::--------------------------------------------
:: Check for Administrator privileges
::--------------------------------------------
net session >nul 2>&1
if %errorlevel% neq 0 (
    echo.
    echo [ERROR] This needs to be run as Administrator.
    echo Right-click the file and choose "Run as administrator".
    echo.
    pause
    exit /b 1
)

echo.
echo Working on network settings...
echo.

::--------------------------------------------
:: Reset TCP global parameters toward defaults
::--------------------------------------------
netsh interface tcp set global ^
  rss=default ^
  autotuninglevel=normal ^
  ecncapability=disabled ^
  timestamps=default ^
  initialrto=3000 ^
  rsc=default ^
  nonsackrttresiliency=default ^
  maxsynretransmissions=2 ^
  fastopen=default ^
  fastopenfallback=default ^
  hystart=default ^
  prr=default ^
  pacingprofile=default >nul 2>&1

::--------------------------------------------
:: Reset heuristics back to their default behavior
::--------------------------------------------
netsh interface tcp set heuristics wsh=default forcews=default >nul 2>&1

echo.
echo Network tuning has been adjusted.
echo It is recommended to restart Windows so everything applies cleanly.
echo.
pause