define dmesg
        set $log_buf = log_buf
        set $log_end = log_end
        set $log_buf_len = log_buf_len
        set $logged_chars = logged_chars

        set $i = 0
        set $end_idx = (log_end - 1) & (log_buf_len - 1)

        while ($i < logged_chars)
                set $idx = (log_end - 1 - logged_chars + $i) & (log_buf_len - 1)

                #if ($idx + 100 <= $end_idx) || \
                #   ($end_idx <= $idx && $idx + 100 < log_buf_len)
                #        printf "%.100s", &log_buf[$idx]
                #        set $i = $i + 100
                #else
                        printf "%c", log_buf[$idx]
                        set $i = $i + 1
                #end
        end
end
document dmesg
        print the kernel ring buffer
end

define reload
  mon reset
  shell load_kernel.py arch/arm/boot/Image
  mon halt
  mon reg r0 0
  mon reg r1 2028
  mon reg r2 0xFFFFFFFF
  mon reg pc 0x00008000
  mon arm core_state arm
  symbol-file vmlinux
end
document reload
reload
Resets the target and reloads the kernel, halted at the kernel entry point
end

target remote :3333
mon target_request debugmsgs charmsg
mon arm7_9 fast_memory_access enable
mon arm7_9 dcc_downloads enable
reload