float range = 15.0;
float rate = 10.0;

list visitor_list;
integer tempDay;

integer isNameOnList(string name) {
    integer i;
    for(i=0;i<llGetListLength(visitor_list);i++) {
        if(llList2String(visitor_list, i) == name) {
            return TRUE;
        }
    }
    return FALSE;
}

default {
    on_rez(integer param) {
        llResetScript();
    }
    state_entry() {
        tempDay = (integer)llList2String(llParseString2List(llGetDate(), ["-"], []), 2);
        llSetTimerEvent(1800);
        llSensorRepeat("", "", AGENT, range, PI, rate);
    }
    sensor(integer number_detected) {
        integer i;
        for(i=0;i<number_detected;i++) {
            if(llDetectedKey(i) != llGetOwner()) {
                string detected_name = llDetectedName(i);
                if(isNameOnList(detected_name) == FALSE) {
                    visitor_list += detected_name;
                    llGiveInventory(llDetectedKey(i), "Store TOS");
                }
            }
        }
    }
    timer() {
        if((integer)llList2String(llParseString2List(llGetDate(), ["-"], []), 2) != tempDay) {
            llResetScript();
        }
    }
}