(Wiremod Expression 2) Lodkagan Holo Example

@name Holo Example
@inputs
@outputs Mode Holo
@persist I P:entity Pos:vector Size:vector Height
@trigger
# Expression 2 Chip by Magus / Lodkagan
interval(100)

if(first()) {
    Height = 0
    Size = vec(0,0,0)
    Holo = 0
    Mode = -0.5
    I = 0.5
    P = entity():owner()
    holoDeleteAll()

    function dMode() {
            if(I == 1) {print("Mode: "+I+"-Cube")}
        elseif(I == 2) {print("Mode: "+I+"-Cone")}
        elseif(I == 3) {print("Mode: "+I+"-Cylinder")}
        elseif(I == 4) {print("Mode: "+I+"-Torus")}
        elseif(I == 5) {print("Mode: "+I+"-Sphere")}
        elseif(I == 6) {print("Mode: "+I+"-Pyramid")}
        elseif(I == 7) {print("Mode: "+I+"-Prism")}
        elseif(I == 8) {print("Mode: "+I+"-Tetra")}
    }

    print("Right   Mouse: Reset")
    print("Reload Button: Change Model")
    print("Use    Button: Accept/Next Step")

}

if(changed(P:keyAttack2())) {
    holoDelete(Holo)
    Mode = -1
    Holo--
}

if(changed(P:keyReload())) {
    I += 0.5
    if(I > 8) {I = 0.5}
    dMode()
}

if(changed(P:keyUse())) {
    Mode += 0.5
}

if(Holo < 1) {Holo = 1}
if(Mode < 0) {Mode = 0}

if(Mode == 0.5) {
    Holo++
    Height = 0
    Size = vec(0,0,0)
    print("Set: Pos")
    holoCreate(Holo)
        if(I == 1) {holoModel(Holo,"cube")}
    elseif(I == 2) {holoModel(Holo,"cone")}
    elseif(I == 3) {holoModel(Holo,"cylinder")}
    elseif(I == 4) {holoModel(Holo,"torus")}
    elseif(I == 5) {holoModel(Holo,"sphere")}
    elseif(I == 6) {holoModel(Holo,"pyramid")}
    elseif(I == 7) {holoModel(Holo,"prism")}
    elseif(I == 8) {holoModel(Holo,"tetra")}
}

if(Mode == 1.0) {
    Pos = P:aimPos()
    holoPos(Holo,Pos)
}

if(Mode == 1.5) {
    print("Set: Size")
}

if(Mode == 2) {
    Size = (Pos-P:aimPos())/10
    holoScale(Holo,Size)
}

if(Mode == 2.5) {
    print("Set: Height")
}

if(Mode == 3) {
    Height = ( (Pos-P:aimPos()):x() + (Pos-P:aimPos()):y() )
    holoScale(Holo,vec(Size:x(),Size:y(),Height/10))
}

if(Mode == 3.5) {
    print("Set: Z Pos (Left click if you want it on the ground)")
}

if(Mode == 4) {
    if(P:keyAttack1()) {
        holoPos(Holo,Pos)
        Mode += 0.5
    }else {
        holoPos(Holo,vec(Pos:x(),Pos:y(), abs( (Pos-P:aimPos()):x()+(Pos-P:aimPos()):y() ) ))
    }
}
if(Mode == 5) {Mode = -0.5}