(rAthena) Fishing

brasilis,309,72,1   shop    Fisher Shop 564,5317:1000000000,2550:1000000000,2443:1000000000,2764:1000000000,2775:10000

-   script  Fishing Spot    -1,{
    disable_items;

    if (@Fishing)
        end;

    @Fishing = 1;
    pcblockmove getcharid(3),1;
    while (1)
    {
        if (getstatus(SC_WEIGHT90))
        {
            message strcharinfo(0), "You have carried to much weight, please remove some of item from your inventory";
            break;
        }

        if (!isequipped(.Fisher_Rod))
        {
            message strcharinfo(0), "Fishing Spot : You need to equip Fishing Rod to begin fishing.";
            break;
        }

        if (.isBaitDeleted && countitem(.Fisher_Bait) < 1)
        {
            message strcharinfo(0), "Fishing Spot : You don't have Fishing Bait to begin fishing.";
            break;
        }
        else if (.isBaitEquiped && !isequipped(.Fisher_Bait))
        {
            message strcharinfo(0), "Fishing Spot : You need to equip Fishing Bait to begin fishing.";
            break;
        }

        .@waiting = 20;
        if (isequipped(5317))
            .@waiting -= 3;
        if (isequipped(2550))
            .@waiting -= 2;
        if (isequipped(2443))
            .@waiting -= 2;
        if (isequipped(2764))
            .@waiting -= 3;


        specialeffect2 EF_BEGINSPELL;
        specialeffect2 EF_BEGINSPELL2;
        specialeffect2 EF_LOCKON;
        specialeffect EF_LOCKON;
        progressbar "FF0000", 1;
        specialeffect EF_HIT2;
        specialeffect EF_BUBBLE;

        for(.@i = 0; .@i < .@waiting; .@i++)
        {
            emotion ET_DELIGHT, getcharid(3);
            sleep2 1250;
        }


        .@rate = rand(10000);
        for (.@i = 0; .@i < .n; .@i++)
        {
            if (.@rate < .Fisher_Drops_R[.@i])
            {
                .@caught_fish[.@caught] = .Fisher_Drops_I[.@i];
                .@caught++;
            }
        }
        if (.@caught)
        {
            showscript "Got something on the hook..";
            emotion ET_BIGTHROB, getcharid(3);
            if (.@caught == 1)
            {
                getitem .@caught_fish, 1;
            }
            else
            {
                .@r = rand(.@caught);
                getitem .@caught_fish[.@r], 1;

            }
            if (.isBaitDeleted)
                delitem .Fisher_Bait, 1;
            sleep2 1000;
        }
        else
        {
            emotion ET_BIGTHROB, getcharid(3);
            sleep2 1000;
            showscript "Sigh.. Nothing caught, Excited for nothing..";
        }
    }
    @Fishing = 0;
    pcblockmove getcharid(3),0;
    end;

OnInit:
    .Fisher_Rod = 2764;
    .Fisher_Bait = 2775;

    // is bait will be deleted when getting drops?
    .isBaitDeleted = 0;

    // is bait equiped or item ?
    // Equiped bait taking priority to item that will be deleted.
    .isBaitEquiped = 1;

    /*
    Example :
        Add(nameid, rate);
    Legends :
        - nameid : item id that will be gained when fishing.
        - rate   : 10000 as 100%, 1000 as 10%...
    */
    function Add;
    freeloop(1);
    Add(501, 10000);
    Add(502,  1000);
    Add(503,  1100);
    Add(504,  2000);
    Add(505,   130);
    Add(506,  7400);
    freeloop(0);

    if (.isBaitEquiped)
        .isBaitDeleted = 0;
    end;

function    Add {
    .@id = getarg(0, 0);
    .@rate = getarg(1, 0);
    if (.@rate < 1)
        return;
    if (getitemname(.@id) == "null")
        return;
    .Fisher_Drops_I[.n] = .@id;
    .Fisher_Drops_R[.n] = .@rate;
    .n++;
    return;
}

}

brasilis,312,106,1  duplicate(Fishing Spot) Fishing Spot#1  10237
brasilis,312,97,1   duplicate(Fishing Spot) Fishing Spot#2  10237
brasilis,312,89,1   duplicate(Fishing Spot) Fishing Spot#3  10237
brasilis,325,79,1   duplicate(Fishing Spot) Fishing Spot#4  10237
brasilis,325,67,1   duplicate(Fishing Spot) Fishing Spot#5  10237