IzarianMasterChunk

//=============================================================================
// IzarianMasterChunk
//=============================================================================
class IzarianMasterChunk extends MasterCreatureChunk;


simulated function ClientExtraChunks(bool bSpawnChunks)
{
    local CreatureChunks carc;
    local bloodpuffblue Blood;
    local bloodspurtblue b;
    local int n;

    If ( Level.NetMode == NM_DedicatedServer )
    return;

    bMustSpawnChunks = false;
    b = Spawn(class 'Bloodspurtblue',,,,rot(16384,0,0));
    if ( bGreenBlood )
        b.GreenBlood();
    b.RemoteRole = ROLE_None;

    if ( !bSpawnChunks || (CarcassClass == None) )
        return;

    n = 1;

    while ( (n<8) && (CarcassClass.Default.bodyparts[n] != none) )
    {
        if ( CarcassClass.Static.AllowChunk(n, CarcassAnim) )
        {
            if ( CarcLocation == vect(0,0,0) ) CarcLocation = Location;
            carc = Spawn(class 'CreatureChunks',,, CarcLocation
                         + CarcassClass.Default.ZOffset[n] * CarcHeight * vect(0,0,1));
            if (carc != None)
            {
                carc.TrailSize = CarcassClass.Default.Trails[n];
                carc.Mesh = CarcassClass.Default.bodyparts[n];
                carc.Initfor(self);
                carc.RemoteRole = ROLE_None;
            }
        }
        n++;
    }

    if ( Level.bHighDetailMode && !bGreenBlood )
    {
        Blood = spawn(class'BloodPuffBlue',,, CarcLocation);
        Blood.drawscale = 0.2 * CollisionRadius;
        Blood.RemoteRole = ROLE_None;
    }
}

function ChunkUp(int Damage)
{
    local BloodSpurtBlue b;

    if (bHidden)
        return;
    b = Spawn(class 'Bloodspurtblue',,,,rot(16384,0,0));
    if ( bGreenBlood )
        b.GreenBlood();
    if (bPlayerCarcass)
    {
        bHidden = true;
        SetPhysics(PHYS_None);
        SetCollision(false,false,false);
        bProjTarget = false;
        if ( Trail != None )
            Trail.Destroy();
    }
    else
        destroy();
}

simulated function Landed(vector HitNormal)
{
    local rotator finalRot;
    local BloodSpurtBlue b;
    //local Bloodsplat2 BS2;

    if ( trail != None )
    {
        if ( Level.bHighDetailMode )
            bUnlit = false;
        trail.Destroy();
        trail = None;
    }
    finalRot = Rotation;
    finalRot.Roll = 0;
    finalRot.Pitch = 0;
    setRotation(finalRot);
    if ( Level.NetMode != NM_DedicatedServer )
    {
        b = Spawn(class 'Bloodspurtblue',,,,rot(16384,0,0));
        if ( bGreenBlood )
            b.GreenBlood();
        b.RemoteRole = ROLE_None;
        //BS2=Spawn(class'BloodSplat2',Owner,,,Rotator(HitNormal));
        //if (bGreenBlood && BS2 != none)
        //  BS2.Green();
    }
    SetPhysics(PHYS_None);
    SetCollision(true, false, false);
}

defaultproperties
{
     CarcassClass=Class'UnrealShare.IzarianCarcass'
     CarcHeight=20.000000
     Mesh=LodMesh'SkCampMeshes.IzarianGib1M'
}