Attiny85 pin change interrupt problem

/**
 * Extremly low power 433MHz switch
 *
 * Button0: Turn off all lights(Switch A,B,D)
 * Button1: Turn on big light(Switch B)
 */
#include <RCSwitch.h>
#include <avr/sleep.h>
#include <avr/wdt.h>

// RCSwitch config
int dataPin = 4;
int vccPin = 3;
char systemCode[6] = "01110";
char switchA[6] = "10000";
char switchB[6] = "01000";
char switchC[6] = "00100";
char switchD[6] = "00010";
char switchE[6] = "00001";
RCSwitch mySwitch = RCSwitch();

void setup() {
  // Turn off interrupts
  cli();
  // Pin to turn on and of transmitter
  pinMode(vccPin, OUTPUT);
  digitalWrite(vccPin, LOW); // Turn off radio

  // RCSwitch
  mySwitch.enableTransmit(dataPin);

  // Safe energy
  ADCSRA &= ~(1<<ADEN); //Deactivate ADC
  ACSR = (1<<ACD); // Deactivate Analog Comparator

  // Sleepmode: Power-Down
  set_sleep_mode(SLEEP_MODE_PWR_DOWN);

  // Interrupts
  GIMSK = (1 << PCIE);  //Enable Pin Change Interrupts
  PCMSK = (1 << PCINT0) | (1 << PCINT1); // Enable pin0 and pin1 interrupts
  // Enable interrupts
  sei();
}

void loop() {
  executeCommand();
  powerDown();
}

void executeCommand() {
  // Button 1?
  if (PINB & (1 << PCINT0)) {
    powerUpTransmitter();
    // Turn off all lights(Switch A,B,D)
    mySwitch.switchOff(systemCode, switchA);
    mySwitch.switchOff(systemCode, switchB);
    mySwitch.switchOff(systemCode, switchD);
  }
  // Button 2?
  else if(PINB & (1 << PCINT1)) {
    powerUpTransmitter();
    // Turn on big light(Switch B)
    mySwitch.switchOn(systemCode, switchA);
  }
}

void powerUpTransmitter() {
  digitalWrite(vccPin, HIGH);
  // Wait for module to strart
  delay(20);
}

void powerDown() {
  GIMSK |= (1 << PCIE);       //Enable Pin Change Interrupts
  digitalWrite(vccPin, LOW);  // Turn off transmitter
  sleep_mode();

  GIMSK &= ~(1 << PCIE);  //Disable Pin Change Interrupts
}

ISR (PCINT0_vect)       //the PCINT0_vect vector is used to identify the pin change interrupt.
{

}