Skyrim - [REQ] Script help with GetBaseObject

; RemoveSpellMagicEffect.psc
scriptname RemoveSpellMagicEffect extends ActiveMagicEffect
{Removes a specific spell from the player}

;/////////////////////////////////////////////////////////////////////////////
 / Properties
 /////////////////////////////////////////////////////////////////////////////;

Spell property BoundSpell = none auto
{REQUIRED -- bind via CK to MGEF}


;/////////////////////////////////////////////////////////////////////////////
 / Events
 /////////////////////////////////////////////////////////////////////////////;

event OnEffectStart(Actor unusedTarget, Actor unusedCaster)
    Actor p = Game.GetPlayer()
    if (BoundSpell != none && p.HasSpell(BoundSpell))
        p.RemoveSpell(BoundSpell)
    endif
endevent


; PerkTome.psc
scriptname PerkTome extends ObjectReference
{NOTE: The book this script is bound to must be a "learn spell" type book!!!}

;/////////////////////////////////////////////////////////////////////////////
 / Properties
 /////////////////////////////////////////////////////////////////////////////;

Perk property BoundPerk auto
{REQUIRED -- has to be bound via the CK}


;/////////////////////////////////////////////////////////////////////////////
 / Events
 /////////////////////////////////////////////////////////////////////////////;

event OnEquipped(Actor unusedSource)
    Actor p = Game.GetPlayer()
    if (BoundPerk != none && p.HasPerk(BoundPerk) == false)
        p.AddPerk(BoundPerk)
    endif
endevent