let
    url = "https://wyszukiwarkaregontest.stat.gov.pl/wsBIR/UslugaBIRzewnPubl.svc",
    klucz = "abcde12345abcde12345",
    regon = "000331501",
    soap = "<soap:Envelope xmlns:soap=""http://www.w3.org/2003/05/soap-envelope"" xmlns:ns=""http://CIS/BIR/PUBL/2014/07"">
            <soap:Header xmlns:wsa=""http://www.w3.org/2005/08/addressing"">
            <wsa:Action>http://CIS/BIR/PUBL/2014/07/IUslugaBIRzewnPubl/Zaloguj</wsa:Action>
            <wsa:To>" & url & "</wsa:To>
            </soap:Header>
            <soap:Body>
            <ns:Zaloguj>
            <ns:pKluczUzytkownika>" & klucz & "</ns:pKluczUzytkownika>
            </ns:Zaloguj>
            </soap:Body>
            </soap:Envelope>",
    options = [#"Content-Type" = "application/soap+xml;charset=UTF-8;"],
    Source = (Web.Contents(url, [Content=Text.ToBinary(soap), Headers = options])),
    #"Imported Text" = Lines.FromBinary(Source,null,null,1250){6},
    #"Imported XML" = Xml.Tables(#"Imported Text",null,1250){[Name="Body"]}[Table],
    id = #"Imported XML"{0}[Table]{0}[Table]{0}[ZalogujResult],
    soap2 = "<soap:Envelope xmlns:soap=""http://www.w3.org/2003/05/soap-envelope"" xmlns:ns=""http://CIS/BIR/PUBL/2014/07"" xmlns:dat=""http://CIS/BIR/PUBL/2014/07/DataContract"">
            <soap:Header xmlns:wsa=""http://www.w3.org/2005/08/addressing"">
            <wsa:To>" & url & "</wsa:To>
            <wsa:Action>http://CIS/BIR/PUBL/2014/07/IUslugaBIRzewnPubl/DaneSzukajPodmioty</wsa:Action>
            </soap:Header>
            <soap:Body>
            <ns:DaneSzukajPodmioty>
            <ns:pParametryWyszukiwania>
            <dat:Regon>" & regon & "</dat:Regon>
            </ns:pParametryWyszukiwania>
            </ns:DaneSzukajPodmioty>
            </soap:Body>
            </soap:Envelope>",
    options2 = [#"Content-Type" = "application/soap+xml;charset=UTF-8;", sid = id],
    Source2 = (Web.Contents(url, [Content=Text.ToBinary(soap2), Headers = options2])),
    #"Imported Text1" = Lines.FromBinary(Source2,null,null,TextEncoding.Utf8),
    #"Removed Top Items" = List.Skip(#"Imported Text1",6),
    #"Removed Bottom Items" = List.RemoveLastN(#"Removed Top Items",1),
    #"Imported XML1" = Xml.Tables(Text.Combine(#"Removed Bottom Items"),null,1250),
    result = #"Imported XML1"{1}[Table]{0}[Table]{0}[Table]{0}[DaneSzukajPodmiotyResult],
    #"Imported XML2" = Xml.Tables(result,null,1250){0}[Table],
    #"Unpivoted Columns" = Table.UnpivotOtherColumns(#"Imported XML2", {}, "Attribute", "Value")
in
    #"Unpivoted Columns"