Specific player(s) spawn at specific coordinates in DayZ

void main()
{
    //INIT WEATHER BEFORE ECONOMY INIT------------------------
    Weather weather = g_Game.GetWeather();

    weather.MissionWeather(false);    // false = use weather controller from Weather.c

    weather.GetOvercast().Set( Math.RandomFloatInclusive(0.4, 0.6), 1, 0);
    weather.GetRain().Set( 0, 0, 1);
    weather.GetFog().Set( Math.RandomFloatInclusive(0.05, 0.1), 1, 0);

    //INIT ECONOMY--------------------------------------
    Hive ce = CreateHive();
    if ( ce )
        ce.InitOffline();

    //DATE RESET AFTER ECONOMY INIT-------------------------
    int year, month, day, hour, minute;
    int reset_month = 9, reset_day = 20;
    GetGame().GetWorld().GetDate(year, month, day, hour, minute);

    if ((month == reset_month) && (day < reset_day))
    {
        GetGame().GetWorld().SetDate(year, reset_month, reset_day, hour, minute);
    }
    else
    {
        if ((month == reset_month + 1) && (day > reset_day))
        {
            GetGame().GetWorld().SetDate(year, reset_month, reset_day, hour, minute);
        }
        else
        {
            if ((month < reset_month) || (month > reset_month + 1))
            {
                GetGame().GetWorld().SetDate(year, reset_month, reset_day, hour, minute);
            }
        }
    }
}

class CustomMission: MissionServer
{
    void SetRandomHealth(EntityAI itemEnt)
    {
        if ( itemEnt )
        {
            int rndHlt = Math.RandomInt(55,100);
            itemEnt.SetHealth("","",rndHlt);
        }
    }

    override PlayerBase CreateCharacter(PlayerIdentity identity, vector pos, ParamsReadContext ctx, string characterName)
    {
        Entity playerEnt;
        playerEnt = GetGame().CreatePlayer(identity, characterName, pos, 0, "NONE");//Creates random player
        Class.CastTo(m_player, playerEnt);

        GetGame().SelectPlayer(identity, m_player);

        return m_player;
    }

    override void StartingEquipSetup(PlayerBase player, bool clothesChosen)
    {
        EntityAI itemTop;
        EntityAI itemEnt;
        ItemBase itemBs;
        float rand;

        itemTop = player.FindAttachmentBySlotName("Body");

        if ( itemTop )
        {
            itemEnt = itemTop.GetInventory().CreateInInventory("Rag");
            if ( Class.CastTo(itemBs, itemEnt ) )
                itemBs.SetQuantity(4);

            SetRandomHealth(itemEnt);

            string chemlightArray[] = { "Chemlight_White", "Chemlight_Yellow", "Chemlight_Green", "Chemlight_Red" };
            int rndIndex = Math.RandomInt(0, 4);
            itemEnt = itemTop.GetInventory().CreateInInventory(chemlightArray[rndIndex]);
            SetRandomHealth(itemEnt);

            rand = Math.RandomFloatInclusive(0.0, 1.0);
            if ( rand < 0.35 )
                itemEnt = player.GetInventory().CreateInInventory("Apple");
            else if ( rand > 0.65 )
                itemEnt = player.GetInventory().CreateInInventory("Pear");
            else
                itemEnt = player.GetInventory().CreateInInventory("Plum");

            SetRandomHealth(itemEnt);
        }

        ///////////////////////////////////////////////////////////////////////////////////////////////////////
        //    Player(s) with a specific SteamID or BI-UID will spawn at a set location. Code starts here.    //
        ///////////////////////////////////////////////////////////////////////////////////////////////////////

        // Define the X and Z coordinates below where the player(s) will spawn when they respawn.
        float xCoordinate = 7500;
        float zCoordinate = 7500;

        // Enter the SteamID or the BI-UID for the player(s) you want to spawn at the above coordinates.
        // Separate with a comma if you have more than one player.
        ref TStringArray spawnPlayers = {"76561198000000001", "76561198000000002", "76561198000000003"};

        // Check if the current player is on the above list. If so, make him/her spawn at the specified coordinates.
        // You don't need to edit anything here.
        for (int i = 0; i < spawnPlayers.Count(); ++i )
        {
            if(player.GetIdentity().GetId() == spawnPlayers[i] || player.GetIdentity().GetPlainId() == spawnPlayers[i])
            {
                float yCoordinate = GetGame().SurfaceY(xCoordinate, zCoordinate);
                vector spawnCoordinates = Vector(xCoordinate, yCoordinate, zCoordinate);
                player.SetPosition(spawnCoordinates);

                break;
            }
        }
        /////////////////////////////////////////////////////////////////////////////////////////////////////
        //    Player(s) with a specific SteamID or BI-UID will spawn at a set location. Code ends here.    //
        /////////////////////////////////////////////////////////////////////////////////////////////////////
    }
};

Mission CreateCustomMission(string path)
{
    return new CustomMission();
}