Candle-flicker-adding Brushbuilder for UE1

//=============================================================================
// BBWafflebox.
//=============================================================================
class BBWafflebox expands BrushBuilder;

var transient brush _bbrush; // builder brush
var transient levelinfo _level; // current levelinfo actor
var transient editorengine _eengine;
var transient camera _camera;
var transient object _input;
var int i;

/////////////////////////////////////////////////////////////
// SET UP REQUIRED VARS
/////////////////////////////////////////////////////////////
function bool Setup() {
    local int i;

    _bbrush=none;
    _level=none;
    _eengine=none;
    _camera=none;
    _input=none;

    for(i=0; (i<100 && _level==none); i++)
        setpropertytext("_level","levelinfo'levelinfo"$i$"'");
    if(_level==none) return badparameters("failed to find levelinfo");
    else log(getclassname(self.class)$" found levelinfo: "$_level);

    for(i=0; (i<100 && _bbrush==none); i++)
        setpropertytext("_bbrush","brush'brush"$i$"'");
    if(_bbrush==none) return badparameters("failed to find builder brush");
    else log(getclassname(self.class)$" found builder brush: "$_bbrush);

    for(i=0; (i<100 && _eengine==none); i++)
        setpropertytext("_eengine","editorengine'editorengine"$i$"'");
    if(_eengine==none) return badparameters("failed to find editor engine");
    else log(getclassname(self.class)$" found editor engine: "$_eengine);

    return true;
}

// this function gets called when the builder brush button is clicked
event bool Build()
{
    Setup(); // set up initial vars and stuff for more advanced brushbuildin'

    Waffle();

    return BadParameters("YOU FORGOT THE CODE YOU DUMPASS");
}


//==============================================================================================
// Add flickers to candles
//==============================================================================================
function Waffle()
{
    // BEST BRUSHBUILDER YET
    local Candle C;
    local EXUFlare E;

    foreach _level.Allactors( class'Candle', C )
    {
        E = _level.Spawn(Class'EXUFlare',,, c.Location + (vect(0, 0, 12.5) * c.DrawScale) );
        if( E!=None )
        {
            E.Group         = 'CandleClusterFlickers';
            E.DrawScale         = c.DrawScale * 0.3;
            E.Texture           = Texture'GenFX.LensFlar.flare7';
            E.bFlickerScaleGlow = True;
            E.bFlickerDrawScale = True;
            E.DrawScaleMax      = c.DrawScale * 0.3;
            E.DrawScaleMin      = c.DrawScale * 0.24;   // Min is 80% of max
            E.ScaleGlowMax      = 1.0;
            E.ScaleGlowMin      = 0.75;
        }
    }
}