grammar G {
    token TOP { <expression> }

    rule expression {
        | <term> $<op>='+' <expression>
        | <term> $<op>='-' <expression>
        | <term>
    }

    rule term {
        | <factor> $<op>='*' <term>
        | <factor> $<op>='/' <term>
        | <factor>
    }

    rule factor {
        | ('-')? '(' <expression> ')'
        | ('-')? <number>
    }

    token number { \d+ [ '.' \d+ ]? [ <[eE]> \d+ ]? }
}

class E {
    method TOP ($/) { make $<expression>.made }

    method expression ($/) {
        given $<op> {
            when '+' { make $<term>.made + $<expression>.made }
            when '-' { make $<term>.made - $<expression>.made }
            default  { make $<term>.made                      }
        }
    }

    method term ($/){
        given $<op> {
            when '*' { make $<factor>.made × $<term>.made }
            when '/' { make $<factor>.made ÷ $<term>.made }
            default  { make $<factor>.made                }
        }
    }

    method factor ($/) {
        my $sign = $0 ?? -1 !! 1;
        my $value;

        $value = $<expression>.made if $<expression>;
        $value = $<number>.made if $<number>;

        make $sign × $value;
    }

    method number ($/) {
        make $/.Num
    }
}

say G.parse('(((((-1)))))', actions => E).made;