baca_pzem

#include <PZEM004Tv30.h>
#include <WiFi.h>
#include <PubSubClient.h>
#include <ArduinoJson.h>
const char* ssid = ".............";
const char* password = "..............";
const char* mqtt_server = "................"; // Alamat IP Orange/RasPi
WiFiClient espClient;
PubSubClient client(espClient);
PZEM004Tv30 pzem(Serial2, 16, 17);
unsigned long saat_ini = 0;
void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  randomSeed(micros());
  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}
void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    String clientId = "ESP8266Client-";
    clientId += String(random(0xffff), HEX);
    if (client.connect(clientId.c_str())) {
      Serial.println("connected");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
}
void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();
  if (millis() - saat_ini > 5000) {
    // Baca nilai dari sensor PZEM
    float tegangan = pzem.voltage();
    float arus = pzem.current();
    float daya = pzem.power();
    float energi = pzem.energy();
    // Periksa apakah pembacaan valid (tidak NaN)
    if (isnan(tegangan) || isnan(arus) || isnan(daya) || isnan(energi)) {
      Serial.println("Error reading PZEM");
      saat_ini = millis();
      return;
    }
    // Format angka menjadi string dengan 2 desimal
    String teganganStr = String(tegangan, 2);
    String arusStr = String(arus, 2);
    String dayaStr = String(daya, 2);
    String energiStr = String(energi, 2);
    // Buat dokumen JSON dan gunakan serialized untuk mempertahankan format 2 desimal
    StaticJsonDocument<128> doc;
    doc["t"] = serialized(teganganStr);
    doc["a"] = serialized(arusStr);
    doc["d"] = serialized(dayaStr);
    doc["e"] = serialized(energiStr);
    char output[128];
    serializeJson(doc, output);
    Serial.println(output);
    client.publish("/esp32/pzem", output); // Topik publisher
    saat_ini = millis();
  }
}