Процедура ДобавитьРекурсивноЗаписиВПоследовательность(Запрос)
    // Дополняем границы последовательности недостающими документами (см комментарий в процедуре выше ПолучитьДокументыДляПерепроведения)
    РезультатЗапроса = Запрос.Выполнить();
    Если РезультатЗапроса.Пустой() Тогда
        Возврат;
    КонецЕсли;

    Выборка = РезультатЗапроса.Выбрать();
    Пока Выборка.Следующий() Цикл
        Запись = РегистрыСведений.дк_ПоследовательностьПартий.СоздатьМенеджерЗаписи();
        ЗаполнитьЗначенияСвойств(Запись, Выборка);
        Запись.Записать();
    КонецЦикла;
    Запрос.Текст =
    "ВЫБРАТЬ
    |   ВтРезультат.Склад КАК Склад,
    |   ВтРезультат.Номенклатура КАК Номенклатура,
    |   ВтРезультат.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
    |   ВтРезультат.СерияНоменклатуры КАК СерияНоменклатуры,
    |   ВтРезультат.Качество КАК Качество,
    |   ВтРезультат.ДокументГраницы,
    |   ВтРезультат.МоментВремени
    |ПОМЕСТИТЬ ВтПоследовательность
    |ИЗ
    |   ВтРезультат КАК ВтРезультат
    |
    |ИНДЕКСИРОВАТЬ ПО
    |   Склад,
    |   Номенклатура,
    |   ХарактеристикаНоменклатуры,
    |   СерияНоменклатуры,
    |   Качество
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ
    |   дк_ОстаткиТоваров.Регистратор КАК ДокументГраницы,
    |   ВЫРАЗИТЬ(дк_ОстаткиТоваров.Регистратор КАК Документ.ПеремещениеТоваров).СкладПолучатель КАК Склад,
    |   ВтПоследовательность.Номенклатура КАК Номенклатура,
    |   ВтПоследовательность.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
    |   ВтПоследовательность.СерияНоменклатуры КАК СерияНоменклатуры,
    |   ВтПоследовательность.Качество КАК Качество,
    |   дк_ОстаткиТоваров.Регистратор.МоментВремени КАК МоментВремени
    |ПОМЕСТИТЬ ВтДанные
    |ИЗ
    |   РегистрНакопления.дк_ОстаткиТоваров КАК дк_ОстаткиТоваров
    |       ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВтПоследовательность КАК ВтПоследовательность
    |       ПО дк_ОстаткиТоваров.Склад = ВтПоследовательность.Склад
    |           И дк_ОстаткиТоваров.Номенклатура = ВтПоследовательность.Номенклатура
    |           И дк_ОстаткиТоваров.ХарактеристикаНоменклатуры = ВтПоследовательность.ХарактеристикаНоменклатуры
    |           И дк_ОстаткиТоваров.СерияНоменклатуры = ВтПоследовательность.СерияНоменклатуры
    |           И дк_ОстаткиТоваров.Качество = ВтПоследовательность.Качество
    |           И дк_ОстаткиТоваров.Регистратор.МоментВремени > ВтПоследовательность.МоментВремени
    |ГДЕ
    |   дк_ОстаткиТоваров.Активность
    |   И дк_ОстаткиТоваров.Регистратор ССЫЛКА Документ.ПеремещениеТоваров
    |   И дк_ОстаткиТоваров.ВидДвижения = ЗНАЧЕНИЕ(ВидДвиженияНакопления.Расход)
    |
    |СГРУППИРОВАТЬ ПО
    |   дк_ОстаткиТоваров.Регистратор,
    |   ВтПоследовательность.Номенклатура,
    |   ВтПоследовательность.ХарактеристикаНоменклатуры,
    |   ВтПоследовательность.СерияНоменклатуры,
    |   ВтПоследовательность.Качество,
    |   ВЫРАЗИТЬ(дк_ОстаткиТоваров.Регистратор КАК Документ.ПеремещениеТоваров).СкладПолучатель,
    |   дк_ОстаткиТоваров.Регистратор.МоментВремени
    |
    |ОБЪЕДИНИТЬ ВСЕ
    |
    |ВЫБРАТЬ
    |   дк_ОстаткиТоваров.Регистратор,
    |   ВтПоследовательность.Склад,
    |   ВЫРАЗИТЬ(дк_ОстаткиТоваров.Регистратор КАК Документ.КомплектацияНоменклатуры).Номенклатура,
    |   ВтПоследовательность.ХарактеристикаНоменклатуры,
    |   ВтПоследовательность.СерияНоменклатуры,
    |   ВтПоследовательность.Качество,
    |   дк_ОстаткиТоваров.Регистратор.МоментВремени
    |ИЗ
    |   РегистрНакопления.дк_ОстаткиТоваров КАК дк_ОстаткиТоваров
    |       ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВтПоследовательность КАК ВтПоследовательность
    |       ПО дк_ОстаткиТоваров.Склад = ВтПоследовательность.Склад
    |           И дк_ОстаткиТоваров.Номенклатура = ВтПоследовательность.Номенклатура
    |           И дк_ОстаткиТоваров.ХарактеристикаНоменклатуры = ВтПоследовательность.ХарактеристикаНоменклатуры
    |           И дк_ОстаткиТоваров.СерияНоменклатуры = ВтПоследовательность.СерияНоменклатуры
    |           И дк_ОстаткиТоваров.Качество = ВтПоследовательность.Качество
    |           И дк_ОстаткиТоваров.Регистратор.МоментВремени > ВтПоследовательность.МоментВремени
    |ГДЕ
    |   дк_ОстаткиТоваров.Активность
    |   И дк_ОстаткиТоваров.Регистратор ССЫЛКА Документ.КомплектацияНоменклатуры
    |   И дк_ОстаткиТоваров.ВидДвижения = ЗНАЧЕНИЕ(ВидДвиженияНакопления.Расход)
    |
    |СГРУППИРОВАТЬ ПО
    |   дк_ОстаткиТоваров.Регистратор,
    |   ВтПоследовательность.Склад,
    |   ВтПоследовательность.ХарактеристикаНоменклатуры,
    |   ВтПоследовательность.СерияНоменклатуры,
    |   ВтПоследовательность.Качество,
    |   ВЫРАЗИТЬ(дк_ОстаткиТоваров.Регистратор КАК Документ.КомплектацияНоменклатуры).Номенклатура,
    |   дк_ОстаткиТоваров.Регистратор.МоментВремени
    |
    |ИНДЕКСИРОВАТЬ ПО
    |   Склад,
    |   Номенклатура,
    |   ХарактеристикаНоменклатуры,
    |   СерияНоменклатуры,
    |   Качество
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |УНИЧТОЖИТЬ ВтРезультат
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ
    |   ВтДанные.ДокументГраницы,
    |   ВтДанные.Склад,
    |   ВтДанные.Номенклатура,
    |   ВтДанные.ХарактеристикаНоменклатуры,
    |   ВтДанные.СерияНоменклатуры,
    |   ВтДанные.Качество,
    |   ВтДанные.МоментВремени
    |ПОМЕСТИТЬ ВтРезультат
    |ИЗ
    |   ВтДанные КАК ВтДанные
    |       ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.дк_ПоследовательностьПартий КАК дк_ПоследовательностьПартий
    |       ПО ВтДанные.Склад = дк_ПоследовательностьПартий.Склад
    |           И ВтДанные.Номенклатура = дк_ПоследовательностьПартий.Номенклатура
    |           И ВтДанные.ХарактеристикаНоменклатуры = дк_ПоследовательностьПартий.ХарактеристикаНоменклатуры
    |           И ВтДанные.СерияНоменклатуры = дк_ПоследовательностьПартий.СерияНоменклатуры
    |           И ВтДанные.Качество = дк_ПоследовательностьПартий.Качество
    |ГДЕ
    |   ВЫБОР
    |           КОГДА НЕ дк_ПоследовательностьПартий.ДокументГраницы ЕСТЬ NULL
    |               ТОГДА дк_ПоследовательностьПартий.ДокументГраницы.МоментВремени > ВтДанные.МоментВремени
    |           ИНАЧЕ ИСТИНА
    |       КОНЕЦ
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |УНИЧТОЖИТЬ ВтПоследовательность
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |УНИЧТОЖИТЬ ВтДанные
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ
    |   ВтРезультат.ДокументГраницы,
    |   ВтРезультат.Склад,
    |   ВтРезультат.Номенклатура,
    |   ВтРезультат.ХарактеристикаНоменклатуры,
    |   ВтРезультат.СерияНоменклатуры,
    |   ВтРезультат.Качество,
    |   ВтРезультат.МоментВремени
    |ИЗ
    |   ВтРезультат КАК ВтРезультат";

    ДобавитьРекурсивноЗаписиВПоследовательность(Запрос);

КонецПроцедуры