POST_53

/*  TITULO: Control del brillo de una bombilla a través de un Dimmer AC

    AUTOR:

    MARIANO DEL CAMPO GARCÍA (@2016) --> INGENIERO TÉCNICO INDUSTRIAL ESPECIALIDAD ELECTRÓNICA
    - FACEBOOK: https://www.facebook.com/mariano.delcampogarcia
    - TWITTER: https://twitter.com/MarianoCampoGa
    - CORREO: marianodc83@gmail.com


    DESCRIPCIÓN DEL PROGRAMA

    Con este programa regulamos el brillo de una bombilla de 60W/220VAC a través de un Dimmer AC,
    enviándole pulsos PWM, de un valor comprendido entre 15 y 90, desde el monitor serie del IDE
    de nuestro Arduino.


    ESQUEMA DE CONEXION

                                      +-----+
         +----[PWR]-------------------| USB |--+
         |                            +-----+  |
         |         GND/RST2  [ ][ ]            |
         |       MOSI2/SCK2  [ ][ ]  A5/SCL[ ] |
         |          5V/MISO2 [ ][ ]  A4/SDA[ ] |
         |                             AREF[ ] |
         |                              GND[ ] |
         | [ ]N/C                    SCK/13[ ] |
         | [ ]IOREF                 MISO/12[ ] |
         | [ ]RST                   MOSI/11[ ]~|
         | [ ]3V3    +---+               10[ ]~|
         | [ ]5v    -| A |-               9[ ]~|   Pin PWM del Dimmer AC
         | [ ]GND   -| R |-               8[ ] |
         | [ ]GND   -| D |-                    |
         | [ ]Vin   -| U |-               7[ ] |
         |          -| I |-               6[ ]~|
         | [ ]A0    -| N |-               5[ ]~|
         | [ ]A1    -| O |-               4[ ] |
         | [ ]A2     +---+           INT1/3[ ]~|
         | [ ]A3                     INT0/2[ ] |
         | [ ]A4/SDA  RST SCK MISO     TX>1[ ] |
         | [ ]A5/SCL  [ ] [ ] [ ]      RX<0[ ] |
         |            [ ] [ ] [ ]              |
         |  UNO_R3    GND MOSI 5V  ____________/
          \_______________________/

  NOTAS:

   - Más conexiones del Dimmer AC.
       - Pin 5V --> +5V de Arduino
       - Pin GND --> GND de Arduino
       - Pin MODE --> +5V de Arduino (Para modo PWM del Dimmer AC)
       - Conector AC IN --> 220VAC
       - Conector AC LOAD --> Bombilla de 60W/220VAC
*/

  // Variables del programa
  const int Pin_PWM = 9; // Pin digital para el pin PWM del Dimmer
  String entrada_PWM = ""; // Cadena para guardar el valor numérico que introducimos en el monitor serie
  char caracterEntrada; // Variable para almacenar un carácter leído del monitor serie
  boolean entradaCompleta = false;  // Variable que comprueba el estado de la entrada por el monitor serie
  int salida_PWM = 0; // Variable que almacena el valor del PWM que aplicamos en el Dimmer

  void setup()
  {
    Serial.begin(9600); // Comienzo de la comunicación serie
  }

  void loop()
  {
    // Mandamos el valor del PWM al Dimmer
    analogWrite(Pin_PWM, salida_PWM);
    // Si tenemos una entrada completa (valor entre 15 y 90)
    if (entradaCompleta)
    {
      Serial.print("Dimmer activado al ");
      Serial.print(entrada_PWM);
      Serial.println("%");
      salida_PWM = entrada_PWM.toInt();
      // La salida nunca puede valer 0
      if (salida_PWM == 0)
      {
        salida_PWM = 1;
      }
      // Vaciamos la cadena de entrada
      entrada_PWM = "";
      // Cambiamos el estado de la entrada
      entradaCompleta = false;
    }
  }

  // Función que se ejecuta cada vez que se envían datos a través del monitor serie.
  void serialEvent()
  {
    while (Serial.available())
    {
      // Se lee el carácter de entrada del monitor serie
      caracterEntrada = (char)Serial.read();
      // Se añade el carácter a la cadena de entrada
      if (caracterEntrada != '\n')
      {
        entrada_PWM += caracterEntrada;
      }
      // La cadena se recibe cuando pulsamos "enter" desde el  monitor serie
      if (caracterEntrada == '\n')
      {
        entradaCompleta = true;
      }
    }
  }