passport

dialog pp {
  title "Passport Editor"
  size -1 -1 278 156
  option pixels
  box "Passports", 11, 7 4 265 110
  combo 1, 20 24 241 70, drop
  edit "", 2, 69 59 192 20
  edit "", 3, 69 81 192 20
  text "Email:", 12, 16 60 50 17, right
  text "Password:", 13, 13 81 53 20, right
  button "Add", 4, 14 127 41 21, flat
  button "Remove", 5, 62 127 49 21, flat
  button "Cancel", 7, 207 124 60 25, cancel flat
  button "Switch To", 6, 135 124 60 25, ok flat
}

alias pp {
  dialog -modrv pp pp
  did -a pp 1 < Select a Passport >

  var %i 0, %e $hget(adler,$+(email,%i))
  while (%e) {
    did -a pp 1 %i - %e
    inc %i | var %e $hget(adler,$+(email,%i))
  }
  var %i $hget(adler, pp)
  did -c pp 1 $calc(%i + 2)
  did -a pp 2 $hget(adler,$+(email,%i))
  did -a pp 3 <stored>
}

;select passport
on *:DIALOG:pp:sclick:1: {
  var %i $gettok($did(pp,1),1,32)
  did -r pp 2-3
  if (%i == <) { return }
  did -a pp 2 $hget(adler,$+(email,%i))
  did -a pp 3 <stored>
}

;add passport
on *:DIALOG:pp:sclick:4: {
  var %i 0, %de $did(pp,2), %dp $md5($did(pp,3))
  if (!%de || !%dp || $did(pp,3) == <stored>) {
    var %i $gettok($did(pp,1),1,32)
    hadd adler $+(email,%i) %de
    if ($did(pp,3) != <stored>) { hadd adler $+(pw,%i) %dp }
    return
  }
  var %e $hget(adler, $+(email,%i))
  while (%e) { inc %i | var %e $hget(adler, $+(email,%i)) }
  hadd adler $+(email,%i) %de | hadd adler $+(pw,%i) %dp
  dialog -x pp | pp
}

;remove passport
on *:DIALOG:pp:sclick:5: {
  var %i $gettok($did(pp,1),1,32)

  var %e $hget(adler, $+(email,%i))
  while (%e) {
    inc %i
    var %e $hget(adler, $+(email,%i))
    if (%e) { hadd adler $+(email,$calc(%i - 1)) $hget(adler, $+(email,%i)) | hadd adler $+(pw,$calc(%i - 1)) $hget(adler, $+(pw,%i)) }
  }
  hdel adler $+(email,$calc(%i - 1))
  hdel adler $+(pw,$calc(%i - 1))
  dialog -x pp | pp
}

;switch pasport
on *:DIALOG:pp:sclick:6: {
  var %i $gettok($did(pp,1),1,32)
  if (%i == <) { return }
  hadd adler pp %i
  echo -sat 8Changing passport to15 $hget(adler, $+(email,%i)) 8..
  reconnect
}