Simple Clientinit

//define starting gear
startinggear = ["ACE_Earplugs",
                "ItemGPS",
                "ItemWatch",
                "ACRE_PRC343",
                "ACRE_PRC148",
                "ACRE_PRC152",
                "ACE_Map_Tools",
                "ACE_GlassesLHD_glasses",
                "ACE_GlassesGasMask_US",
                "ACE_Map",
                "ItemCompass",
                "NVGoggles",
                "Binocular"];

client_execution = {
        if (isplayer player) then
        {
                waituntil {local player};
                /////////////////////////////////
                //     Freeze player block     //
                /////////////////////////////////
                player enableSimulation false;          //Freeze player
                2003 CutText ["Initialising...", "BLACK"];
                //calculate time
                _future = time + 5;
                waitUntil {(time >= _future)};
                /////////////////////////////////
                //    Default Loadout block    //
                /////////////////////////////////
                defaultloadoutinit = [player] spawn {
                    _unit = _this select 0;
                    removeAllWeapons _unit;
                    removeAllItems _unit;
                    clearMagazineCargo (unitBackpack _unit);
                    [_unit, "ALL"] call ACE_fnc_RemoveGear;
                    {player addweapon _x} foreach startinggear;
                };
                //enables ace safety on load - don't use unless you are spawning in with weapon
                //if !(player hasweapon "ace_safe") then {player addweapon "ace_safe";};
                //waituntil {player hasweapon "ace_safe"};
                //player selectweapon "ace_safe";
                //player setVariable ["ace_sys_weaponselect_safety",[(primaryweapon player),true]];
                /////////////////////////////////
                // ACE & Player settings block //
                /////////////////////////////////
                ace_sys_tracking_markers_enabled = false;
                ace_sys_eject_fnc_weaponcheck = {};
                setViewDistance 1609;
                setTerrainGrid 50;
                onMapSingleClick {_shift}; //disable map waypoints
                player setskill 0; //saves CPU
                player setVariable ["BIS_noCoreConversations", true]; //Disable AI Convos
                enableRadio false; //Disable radio communication
                {player disableAI _x} foreach ["MOVE","ANIM","TARGET","AUTOTARGET"]; //Saves CPU, stops players from calling contacts
                [] call (compile (preprocessFileLineNumbers ("\ca\Modules\MP\data\scripts\MPframework.sqf"))); //activates remote execution
                /////////////////////////////////
                //    Unfreeze player block    //
                /////////////////////////////////
                waitUntil { scriptDone defaultloadoutinit }; //wait until loadout script is done before unfreeze
                titleFadeOut 0.1; //sexier fade
                2003 CutText ["Initialisation Completed", "BLACK IN", 5]; //fade out initialization text
                diag_log format ["Mission Initialisation Completed for: %1 at: %2", player, time]; //record player init time
                player enablesimulation true; //unfreeze
                //waits 5 seconds before activating infotext
                [] spawn {
                    sleep 5;
                    [str ("Template"), str("Chernarus"), str(date select 1) + "." + str(date select 2) + "." + str(date select 0)] spawn BIS_fnc_infoText;
                };
        };
};

player call client_execution;

if (!isServer && isNull player) then {
        waitUntil {!isNull player};
        waituntil {local player};
        player call client_execution;
        player setpos (getmarkerpos "respawn_west");
};