Tasmota Script - Verbraucher schalten

>D 40
; -- VARS --
swesp=0
swespflg=0
power=0
power2=0
; optional!!
p:btn=0
btnstate=2

;-- SML --
>M 1
;Euer SML DESCRIPTOR .....

; -- EVERY 100MS -- optional!!
>F
if (btnstate!=btn)
{
  =>websend [192.168.0.50] power %btn%
  print power %btn%
  btnstate=btn
}

; -- EVERY SECOND --
>S
; every 3s
if (secs%3==0)
{
  ; copy SML value
  power=sml[1]
  ; simply filtered power
  power2=(0.9*power2)+((1-0.9)*power)

  ; switch second ESP if power flows to grid, see >W section
  if (swesp==1)
  {
    if ((power2<-300) and (swespflg==0))
    {
      =>websend [192.168.0.50] power ON
      print power ON %power2%W
      swespflg=1
      btn=1 ;optional
    }
    if ((power>100) and (swespflg==1))
    {
      =>websend [192.168.0.50] power OFF
      print power OFF %power2%W
      swespflg=0
      btn=0 ;optional
    }
  }
}

; WEB INTERFACE
>W
; web button
; switch second ESP if power flows to grid, see >S section
bu(swesp "PV Steckdose aktivieren" "PV Steckdose deaktivieren")
; optional
bu(btn "Steckdose manuell ausschalten" "Steckdose manuell einschalten")