ColorMask3Layer

Shader "Custom/ColorMask3Layer" {
    Properties
    {
        _Color ("Color", Color) = (1,1,1,1)
        _Color_2 ("Color_2", Color) = (1,1,1,1)
        _Color_3 ("Color_3", Color) = (1,1,1,1)
        _MainTex ("Texture", 2D) = "white" {}
        _MaskTex ("MaskTexture", 2D) = "white" {}
        _MaskColor("MaskColor", Color) = (1,0,0,1)
        _MaskStrength("Mask Strength", Range(0.0, 1.0)) = 1
        _BumpMap ("Bumpmap", 2D) = "bump" {}
        _SpecGlossMap("Specular Texture", 2D) = "white" {}
        _SpecColor("SpecColor", Color) = (1,1,1,1)
        _SpecColor_2 ("SpecColor_2", Color) = (1,1,1,1)
        _SpecColor_3 ("SpecColor_3", Color) = (1,1,1,1)
        _OcclusionStrength("Occlusion Strength", Range(0.0, 1.0)) = 1
        _OcclusionMap("Occlusion Map", 2D) = "white" {}
        _Smoothness("Smoothness", Range(0.0, 1.0)) = 0.5
        _Smoothness_2("Smoothness_2", Range(0.0, 1.0)) = 0.5
        _EmissionColor("Emission Color", Color) = (0,0,0)
        _EmissionMap("Emission", 2D) = "black" {}
    }
    SubShader {
        Tags { "RenderType"="Opaque" }

        LOD 200

        CGPROGRAM
        #include "UnityPBSLighting.cginc"
        // Physically based Standard lighting model, and enable shadows on all light types
        #pragma surface surf StandardSpecular fullforwardshadows

        // Use shader model 3.0 target, to get nicer looking lighting
        #pragma target 3.0

        sampler2D _MainTex, _MaskTex, _BumpMap, _SpecGlossMap, _OcclusionMap, _EmissionMap;
        fixed4 _Color, _Color_2, _Color_3;
        fixed4 _SpecColor_2, _SpecColor_3;
        fixed4 _MaskColor;
        half3 _EmissionColor;
        half _Smoothness, _Smoothness_2;
        half _OcclusionStrength;
        half _MaskStrength;
        //float4 mask;

        struct Input {
            float2 uv_MainTex;
            float2 uv_MaskTex;
            float2 uv_BumpMap;
            float2 uv_SpecGlossMap;
            float2 uv_EmissionMap;
            float2 uv_OcclusionMap;
        };



        void surf (Input IN, inout SurfaceOutputStandardSpecular o) {
            // Albedo comes from a texture tinted by colo
            float4 c = tex2D (_MainTex, IN.uv_MainTex);
            float4 mask = tex2D (_MaskTex, IN.uv_MaskTex);
            float cmask = min(1.0 ,mask.r + mask.g + mask.b);
            float4 n = tex2D (_BumpMap, IN.uv_BumpMap);
            float4 sp = tex2D (_SpecGlossMap, IN.uv_SpecGlossMap);
            float oc = tex2D(_OcclusionMap, IN.uv_MainTex).rgb;
            fixed4 em = tex2D(_EmissionMap, IN.uv_EmissionMap);

            mask = lerp(float4(0,0,0,0), mask * _MaskColor, _MaskStrength);

            c.rgb = c.rgb * (1 - cmask) + (c * _Color * mask.r) + (c * _Color_2 * mask.g) + (c * _Color_3 * mask.b);
            sp.rgb = sp.rgb * (1 - cmask) + ((sp * _SpecColor) * mask.r) + (sp * _SpecColor_2 * mask.g) + (sp * _SpecColor_3 * mask.b);
            o.Albedo = c.rgb;
            o.Normal = UnpackNormal (n);
            o.Specular = sp.rgb;
            o.Smoothness = (sp.a * (1 - cmask) + ((sp.a * _Smoothness) * mask.r) + ((sp.a * _Smoothness_2) * mask.g) + ((sp.a * _SpecColor_3.a) * mask.b));
            o.Occlusion = lerp(float4(1,1,1,1), oc, _OcclusionStrength).rgba;
            o.Emission = em.rgb * _EmissionColor;
        }
        ENDCG
    }
    FallBack "Diffuse"
}