class SRPlayerReplicationInfo extends KFPlayerReplicationInfo;

var string PlayerLocalTime;
var float ExpMult, DamMult;
var bool bCH, bDP, CanGrabWeapon;
var Pickup LastItem;

var bool bAllowPickup;
var bool bUseNoobCross;
var bool bShowDamage;
var bool bEnhancedShoulderView;

replication
{
    reliable if ( bNetDirty && (Role == Role_Authority) )
        ExpMult, DamMult, bCH, bDP, CanGrabWeapon, LastItem;

    reliable if(Role < Role_Authority)
        SendSettingsToServer;
}

//Инициализация значения bAllowPickup из MySettings.ini файла клиента и отсылка значения на сервер.
simulated function PostNetBeginPlay()
{
    local bool bCustomView;

    if(Role < Role_Authority)
    {
        bAllowPickup=bool(class'SRMySettings'.static.Get("bAllowPickup"));
        SendSettingsToServer("bAllowPickup",string(int(bAllowPickup)));

        bUseNoobCross = bool(class'SRMySettings'.static.Get("bUseNoobCross"));
        SendSettingsToServer("bUseNoobCross", string(int(bUseNoobCross)));

        bShowDamage = bool(class'SRMySettings'.static.Get("bShowDamage"));
        SendSettingsToServer("bShowDamage", string(int(bShowDamage)));

        bCustomView=bool(class'SRMySettings'.static.Get("bCustomView"));
        SendSettingsToServer("bEnhancedShoulderView",string(int(bCustomView)));
        bEnhancedShoulderView=bCustomView;
    }
    Super.PostNetBeginPlay();
}

//Здесь я тоже сделал универсальную функцию, которая принимает 2 строки и использует SetPropertyText для изменения
//значения переменной с названием Variable на значение заданное строкой bValue
function SendSettingsToServer(string Variable, string bValue)
{
    if(bNetOwner)
        SetPropertyText(Variable,bValue);
}

simulated function PostBeginPlay()
{
    SetTimer(1.0,true);
    Super.PostBeginPlay();
}

simulated function Timer()
{
    local Controller C;

    if(((Owner != none) && Controller(Owner).Pawn != none) && LastItem != none)
    {
        if(Abs(Controller(Owner).Pawn.Location.X - LastItem.Location.X) > 5)
        {
            LastItem = none;
        }
    }
    CanGrabWeapon = false;
    UpdatePlayerLocation();
    C = Controller(Owner);
    if(C == none)
    {
        return;
    }
    if(C.Pawn == none)
    {
        PlayerHealth = 0;
    }
    else
    {
        PlayerHealth = C.Pawn.Health;
    }
    CanGrabWeapon = false;
    if(Role < ROLE_Authority)
        PlayerLocalTime=GetLocalTimeString();
    Super.Timer();
}

simulated function string GetLocalTimeString()
{
    local string Hour,Minute,Second,result;
    Hour=string(Level.Hour);
    if(Level.Hour<10) Hour=0$Hour;
    Minute=string(Level.Minute);
    if(Level.Minute<10) Minute=0$Minute;
    Second=string(Level.Second);
    if(Level.Second<10) Second=0$Second;
    result=Hour$":"$Minute$":"$Second;
    return result;
}