God mode for X minutes when spawning in DayZ #2

void main()
{
    //INIT WEATHER BEFORE ECONOMY INIT------------------------
    Weather weather = g_Game.GetWeather();

    weather.MissionWeather(false);    // false = use weather controller from Weather.c

    weather.GetOvercast().Set( Math.RandomFloatInclusive(0.4, 0.6), 1, 0);
    weather.GetRain().Set( 0, 0, 1);
    weather.GetFog().Set( Math.RandomFloatInclusive(0.05, 0.1), 1, 0);

    //INIT ECONOMY--------------------------------------
    Hive ce = CreateHive();
    if ( ce )
        ce.InitOffline();

    //DATE RESET AFTER ECONOMY INIT-------------------------
    int year, month, day, hour, minute;
    int reset_month = 9, reset_day = 20;
    GetGame().GetWorld().GetDate(year, month, day, hour, minute);

    if ((month == reset_month) && (day < reset_day))
    {
        GetGame().GetWorld().SetDate(year, reset_month, reset_day, hour, minute);
    }
    else
    {
        if ((month == reset_month + 1) && (day > reset_day))
        {
            GetGame().GetWorld().SetDate(year, reset_month, reset_day, hour, minute);
        }
        else
        {
            if ((month < reset_month) || (month > reset_month + 1))
            {
                GetGame().GetWorld().SetDate(year, reset_month, reset_day, hour, minute);
            }
        }
    }
}

class CustomMission: MissionServer
{
    void SetRandomHealth(EntityAI itemEnt)
    {
        if ( itemEnt )
        {
            float rndHlt = Math.RandomFloat( 0.45, 0.65 );
            itemEnt.SetHealth01( "", "", rndHlt );
        }
    }

    override PlayerBase CreateCharacter(PlayerIdentity identity, vector pos, ParamsReadContext ctx, string characterName)
    {
        Entity playerEnt;
        playerEnt = GetGame().CreatePlayer( identity, characterName, pos, 0, "NONE" );
        Class.CastTo( m_player, playerEnt );

        GetGame().SelectPlayer( identity, m_player );

        return m_player;
    }

    override void StartingEquipSetup(PlayerBase player, bool clothesChosen)
    {
        EntityAI itemClothing;
        EntityAI itemEnt;
        ItemBase itemBs;
        float rand;

        itemClothing = player.FindAttachmentBySlotName( "Body" );
        if ( itemClothing )
        {
            SetRandomHealth( itemClothing );

            itemEnt = itemClothing.GetInventory().CreateInInventory( "Rag" );
            if ( Class.CastTo( itemBs, itemEnt ) )
                itemBs.SetQuantity( 4 );

            SetRandomHealth( itemEnt );

            string chemlightArray[] = { "Chemlight_White", "Chemlight_Yellow", "Chemlight_Green", "Chemlight_Red" };
            int rndIndex = Math.RandomInt( 0, 4 );
            itemEnt = itemClothing.GetInventory().CreateInInventory( chemlightArray[rndIndex] );
            SetRandomHealth( itemEnt );

            rand = Math.RandomFloatInclusive( 0.0, 1.0 );
            if ( rand < 0.35 )
                itemEnt = player.GetInventory().CreateInInventory( "Apple" );
            else if ( rand > 0.65 )
                itemEnt = player.GetInventory().CreateInInventory( "Pear" );
            else
                itemEnt = player.GetInventory().CreateInInventory( "Plum" );

            SetRandomHealth( itemEnt );
        }

        itemClothing = player.FindAttachmentBySlotName( "Legs" );
        if ( itemClothing )
            SetRandomHealth( itemClothing );

        itemClothing = player.FindAttachmentBySlotName( "Feet" );
    }

    // Code for god mode upon spawning starts here. Only paste this code into init.c
    override void InvokeOnConnect(PlayerBase player, PlayerIdentity identity)
    {
        super.InvokeOnConnect(player, identity);
        player.SetAllowDamage(false);

        // Set in minutes for how long you want the player to have god mode upon spawning into the game. Don't edit anything else unless you know what you are doing.
        int godModeTimer = 1;

        // Convert to milliseconds.
        int godModeTimerMS = godModeTimer * 60000;

        // Call the method for removing god mode after "godModeTimerMS" milliseconds.
        GetGame().GetCallQueue(CALL_CATEGORY_GAMEPLAY).CallLater(RemoveGodMode, godModeTimerMS, false, player);

        // First warning message: 30 seconds
        int warningTime = godModeTimerMS - 30000;
        string message = "Your god mode will be removed in 30 seconds.";
        GetGame().GetCallQueue(CALL_CATEGORY_GAMEPLAY).CallLater(DisplayMessage, warningTime, false, player, message);

        // Second warning message: 10 seconds
        warningTime = godModeTimerMS - 10000;
        message = "Your god mode will be removed in 10 seconds.";
        GetGame().GetCallQueue(CALL_CATEGORY_GAMEPLAY).CallLater(DisplayMessage, warningTime, false, player, message);
    }

    void RemoveGodMode(PlayerBase player)
    {
        player.SetAllowDamage(true);
        DisplayMessage(player, "Your god mode has been removed.");
    }

    void DisplayMessage(PlayerBase player, string message)
    {
        Param1<string> m_MessageParam = new Param1<string>(message);
        GetGame().RPCSingleParam(player, ERPCs.RPC_USER_ACTION_MESSAGE, m_MessageParam, true, player.GetIdentity());
    }
    // Code for god mode upon spawning ends here. Don't paste anything else into init.c.
};

Mission CreateCustomMission(string path)
{
    return new CustomMission();
}