POST_72_B

/*  TITULO: Comunicación bidireccional entre Arduinos con módulos NRF24L01
            >> Programa Arduino "B"

    AUTOR:

    MARIANO DEL CAMPO GARCÍA (@2016) --> INGENIERO TÉCNICO INDUSTRIAL ESPECIALIDAD ELECTRÓNICA
    - FACEBOOK: https://www.facebook.com/mariano.delcampogarcia
    - TWITTER: https://twitter.com/MarianoCampoGa
    - CORREO: marianodc83@gmail.com


    DESCRIPCIÓN DEL PROGRAMA

    Con este programa controlamos el encendido y apagado de un LED con un solo pulsador, mediante una
    conexión por radiofrecuencia (RF) bidireccional entre dos Arduinos, a través de módulos NRF24L01.
    Vamos a recibir el valor de la variable estado_pulsador_A[0] vía RF desde el Arduino "A", cada
    vez que se presione el pulsador conectado a él, si esta variable tiene el valor de "1" se enciende
    el LED conectado a este Arduino ("B") y si vale "0" el LED se apaga. En el supuesto de que nunca
    recibamos ningún valor de la variable estado_pulsador_A[0], el LED permanecerá apagado (no se ha
    presionado todavía el pulsador del Arduino "A").
    Por otro lado, cada vez que presionamos el pulsador conectado a este Arduino, se envía mediante RF
    el valor de la variable estado_pulsador_B[0], si es la primera vez que lo presionamos se envía un
    "1" y si es la segunda vez un "0", repitiéndose el proceso contínuamente, para que se encienda o
    apage el LED conectado al Arduino "A", que es el que obtiene, a través de RF, el valor de la
    variable estado_pulsador_B[0]. En el supuesto de que nunca presionemos el pulsador, no se envía
    ningún valor mediante RF y como consecuencia el LED permanecerá apagado.



    ESQUEMA DE CONEXION

                                      +-----+
         +----[PWR]-------------------| USB |--+
         |                            +-----+  |
         |         GND/RST2  [ ][ ]            |
         |       MOSI2/SCK2  [ ][ ]  A5/SCL[ ] |
         |          5V/MISO2 [ ][ ]  A4/SDA[ ] |
         |                             AREF[ ] |
         |                              GND[ ] |
         | [ ]N/C                    SCK/13[ ] |   Pin "SCK" del módulo NRF24L01
         | [ ]IOREF                 MISO/12[ ] |   Pin "MISO" del módulo NRF24L01
         | [ ]RST                   MOSI/11[ ]~|   Pin "MOSI" del módulo NRF24L01
         | [ ]3V3    +---+               10[ ]~|   Pin "CSN" del módulo NRF24L01
         | [ ]5v    -| A |-               9[ ]~|   Pin "CE" del módulo NRF24L01
         | [ ]GND   -| R |-               8[ ] |
         | [ ]GND   -| D |-                    |
         | [ ]Vin   -| U |-               7[ ] |   PA
         |          -| I |-               6[ ]~|   LED(+)
         | [ ]A0    -| N |-               5[ ]~|
         | [ ]A1    -| O |-               4[ ] |
         | [ ]A2     +---+           INT1/3[ ]~|
         | [ ]A3                     INT0/2[ ] |
         | [ ]A4/SDA  RST SCK MISO     TX>1[ ] |
         | [ ]A5/SCL  [ ] [ ] [ ]      RX<0[ ] |
         |            [ ] [ ] [ ]              |
         |  UNO_R3    GND MOSI 5V  ____________/
          \_______________________/

  NOTAS:
   - Alimentación del módulo NRF24L01:
     - GND del módulo NRF24L01--> GND de Arduino.
     - VCC del módulo NRF24L01--> +3.3V de Arduino.
   - El pin "IRQ" del modulo NRF24L01 no se conecta a nuestro Arduino.
   - Los pulsadores suelen tener dos pines, que vamos a denominar PA y PB (si es de 4 sólo usamos 2 de ellos)
   - Conexión PULL-DOWN del pulsador.
       - PB conectado a VCC.
       - PA conectado a GND a través de una R=10K ohms.
   - Cátodo(-) del LED (pata más corta) a GND a través de una R=220 ohms.
*/


  // Incluimos las librerías necesarias
  #include <SPI.h> // Librería para la comunicación SPI
  // Librerías para el funcionamiento del módulo NRF24L01
  #include <nRF24L01.h>
  #include <RF24.h>

  // Declaramos los pines de control del módulo NRF24L01
  #define CE 9
  #define CSN 10

  // Se crea el objeto tipo RF24
  RF24 radio(CE, CSN);

  // Se declaran los canales (64 bits en hexadecimal) para transmisión RF
  const uint64_t canal[2] = {0xF0F0F0F0E1LL,0xF0F0F0F0D2LL};

  // Variable que enviamos mediante RF (de tipo string siempre)
  unsigned int estado_pulsador_B[1];

  // Variable que recibimos mediante RF (de tipo string siempre)
  unsigned int estado_pulsador_A[1];

  int pulsador = 7; // Pin digital 7 para el pulsador
  int LED = 6; // Pin digital 6 para el LED

  // Inicializamos las variables internas para el pulsador
  int encender = 0;
  int anterior = 0;
  int estado = 0;


  void setup()
  {
      pinMode(LED, OUTPUT); // Pin digital 6 como salida
      pinMode(pulsador, INPUT); // Pin digital 7 como entrada
      pinMode(CSN, OUTPUT); // Pin digital 10 como salida

      digitalWrite(LED, LOW); // Inicialmente el LED se apaga

      radio.begin();  // Inicialización de la comunicación RF

      // Establece el retardo y el número de reintentos tras fallo en la comunicación RF
      radio.setRetries(15,15);

      radio.openWritingPipe(canal[1]); // Abro el canal "1" para escribir
      radio.openReadingPipe(1,canal[0]); // Abro el canal "0" para leer
  }

  void loop()
  {
      // ************************ PARTE CORRESPONDIENTE A LA RECEPCIÓN B ****************************

      radio.startListening(); // Comienzo a escuchar por el canal "0"

      // Siempre que haya información disponible vía RF...
      while(radio.available())
      {
        // Se recibe el valor de la variable estado_pulsador_A[0] a través de RF
        radio.read(estado_pulsador_A, sizeof(estado_pulsador_A));

        // Si el valor de la variable estado_pulsador_A[0] es igual a "1" se enciende el LED
        if (estado_pulsador_A[0] == 1)
        {
          digitalWrite(LED, HIGH);
        }

        // Si el valor de la variable estado_pulsador_A[0] es igual a "0" se apaga el LED
        if (estado_pulsador_A[0] == 0)
        {
          digitalWrite(LED, LOW);
        }
      }
      delay(20); // Doy tiempo de lectura al receptor B

      radio.stopListening(); // Paro de escuchar por el canal "0"


      // ************************ PARTE CORRESPONDIENTE A LA EMISIÓN B ****************************

      estado = digitalRead(pulsador); // Guardamos el estado actual del pulsador B

      if(estado && anterior == 0) // Comparamos el estado actual y el anterior del pulsador B
      {
        encender = 1 - encender;
      }

      anterior = estado; // Actualizamos el estado del pulsador B.

      if(encender) // Si el estado interno del pulsador B pasa de "LOW" a "HIGH".
      {
        estado_pulsador_B[0] = 1; // La variable vale 1
      }

      else // Si el estado interno del pulsador B pasa de "HIGH" a "LOW".
      {
        estado_pulsador_B[0] = 0; // La variable vale 0
      }

      // Se envía el valor de la variable estado_pulsador_B[0] a través de RF
      radio.write(estado_pulsador_B, sizeof(estado_pulsador_B));
      delay(20); // Doy tiempo de escritura al emisor B
  }