Maestro's SIT_FLAG_NO_DAMAGE LSL test script

reportCollision(string type, integer detected)
{
    integer i;
    string report;
    for(i = 0; i < detected; i++)
    {
        report += type + "# " + (string)i + ": hit '"
         + llDetectedName(i) + "' " + (string)llDetectedKey(i)
         + "\n\tof type " + (string)llDetectedType(i)
         + "\n\towned by " + (string)llDetectedOwner(i)
         + "\n\tat our link #" + (string)llDetectedLinkNumber(i)
         + "\n\twith pos and vel " + (string)llDetectedPos (i) + " " + (string)llDetectedVel(i)
         + "\n\tand rotation " + (string)llDetectedRot(i);
    }
    llSay(0, report);
}

default
{
    state_entry()
    {
        llSetObjectName("seat");
        llSetScale(<3, 3, 0.5>);
        llSitTarget(<-1, 0, 0.5>, ZERO_ROTATION);
        integer sitMask = SIT_FLAG_SIT_TARGET | SIT_FLAG_NO_DAMAGE;
        llSetLinkSitFlags(LINK_THIS, sitMask );
        llSay(0, "Sit flags set to " + (string)sitMask
            + ". My key is " + (string)llGetKey() + ". Touch to rez a bullet."
        );
    }

    touch_start(integer detected)
    {
        string bullet = llGetInventoryName(INVENTORY_OBJECT, 0);
        llSay(0, "Rezzing '" + bullet + "'");
        llRezObjectWithParams(bullet, [
            REZ_FLAGS, REZ_FLAG_TEMP | REZ_FLAG_PHYSICAL,
            REZ_POS, <1,0,2>, TRUE, FALSE,
            REZ_DAMAGE, 10
        ]);
    }

    object_rez(key id)
    {
        llSay(0, "Rezzed " + (string)id);
    }

    collision_start(integer detected)
    {
        reportCollision("collision_start", detected);
    }

    collision(integer detected)
    {
        reportCollision("collision", detected);
    }

    collision_end(integer detected)
    {
        reportCollision("collision_end", detected);
    }
}