IBM Cplex AUR PKGBUILD

# Maintainer: Maximilian Stahlberg <maximilian.stahlberg tu-berlin de>
# Contributor: Alberto Santini <alberto.santini at upf dot edu>

# You need to manually download the IBM ILOG CPLEX Optimization Studio installer
# and place it into the same directory as this PKGBUILD, before you proceed.

pkgname='cplex'
pkgdesc="A commercial solver for mathematical optimization problems."
pkgver=12.8
pkgrel=2
arch=('x86_64')
url='https://www.ibm.com/software/products/de/ibmilogcpleoptistud'
license=('custom')
depends=('gcc-libs')
optdepends=(
    'python2: for Python2 bindings'
    'python: for Python bindings'
)
options=('!strip')

_basename="cplex_studio${pkgver//./}.linux-${arch/_/-}"
_installer="${_basename}.bin"

source=("file://${_installer}" installer.properties.template)

prepare() {
    chmod +x "${_installer}"

    cd "${srcdir}"

    # Installer can only work with absolute paths.
    sed "s,ROOT,${pkgdir}/opt/ibm/ILOG/CPLEX," installer.properties.template > installer.properties
}

package() {
    # Extract source by running the installer.
    "./${_installer}" -f "${srcdir}/installer.properties"

    # Fix /opt permissions to avoid a warning (leave everything else as-is)
    chmod 755 "$pkgdir/opt"

    # Remove uninstaller files and logs (avoid build directory warning)
    rm -Rf "$pkgdir/opt/ibm/ILOG/CPLEX/Uninstall"
}

md5sums=('1cb4b29131433491a95efd73b145b821'
         'f295f6c4ecd0f3a6d2fdca21788efd0f')