(Wiremod Expression 2) Lodkagan Holo Enderman

@name Lodkagan Holo Enderman
@persist E:entity Timer T Enderman:vector Distance Range
# Expression 2 Chip by Magus / Lodkagan
interval(100)

if( first() ) {
    # ===== CONFIG =====

    PlayerName = "Magus"    # Which Player should he follow?
    T = 50                  # How often should the chip run until the Enderman teleports?
    Distance = 500          # teleport when the player gets too close.
    Range = 2500            # How far should the Enderman teleport.

    # =================
    # ===== HOLOS =====
    # =================

    # === BODY ===
    holoCreate(10,
            (entity():pos() + vec(0,0,70)),
            vec(1,1.5,2),
            ang(0,0,0),
            vec(0,0,0)
    )

    # === LEGS ===
    holoCreate(11,
            (entity():pos() + vec(0,5,30)),
            vec(0.5,0.5,5),
            ang(0,0,0),
            vec(0,0,0)
    )
    holoParent(11,10)

    holoCreate(12,
            (entity():pos() + vec(0,-5,30)),
            vec(0.5,0.5,5),
            ang(0,0,0),
            vec(0,0,0)
    )
    holoParent(12,10)

    # === HEAD ===
    holoCreate(13,
            (entity():pos() + vec(0,0,90)),
            vec(1.4,1.4,1.4),
            ang(0,0,0),
            vec(0,0,0)
    )
    holoParent(13,10)

    holoCreate(14,
            (entity():pos() + vec(8.1,4,92)),
            vec(0.1,0.5,0.21),
            ang(0,0,0),
            vec(255,255,255)
    )
    holoParent(14,13)

    holoCreate(15,
            (entity():pos() + vec(8.1,-4,92)),
            vec(0.1,0.5,0.21),
            ang(0,0,0),
            vec(255,255,255)
    )
    holoParent(15,13)

    holoCreate(16,
            (entity():pos() + vec(8.15,-4,92)),
            vec(0.1,0.2,0.2),
            ang(0,0,0),
            vec(255,0,255)
    )
    holoParent(16,13)

    holoCreate(17,
            (entity():pos() + vec(8.15,4,92)),
            vec(0.1,0.2,0.2),
            ang(0,0,0),
            vec(255,0,255)
    )
    holoParent(17,13)

    # === ARMS ===
    holoCreate(18,
            (entity():pos() + vec(10,11,55)),
            vec(4,0.4,0.4),
            ang(65,0,0),
            vec(0,0,0)
    )
    holoParent(18,10)

    holoCreate(19,
            (entity():pos() + vec(10,-11,55)),
            vec(4,0.4,0.4),
            ang(65,0,0),
            vec(0,0,0)
    )
    holoParent(19,10)

    # === BLOCK ===
    holoCreate(20,
            (entity():pos() + vec(20,0,35)),
            vec(1,1,1),
            ang(65,50,0),
            vec(0,110,0)
    )
    holoParent(20,10)

    # =================
    # ===== CODE ======
    # =================

    E = findPlayerByName(PlayerName)
    Enderman = entity():pos()
    Timer = 0

    function void warpEnderman() {
        Enderman = E:pos() + vec(random(-Range,Range), random(-Range,Range), 75)
        #print("Warp Random Location", Enderman)
        holoPos(10,Enderman)

        Timer = 0
    }

}

if( Timer >= T ) {

    warpEnderman()

} else {

    if( E:pos():distance(Enderman) < Distance ) {
        warpEnderman()
    }
    Angle = bearing( E:pos(), ang(0,180,0), Enderman )
    holoAng(10,ang(0,Angle*-1,0))
    Timer++
}