Media Player Classic, PicPick, CherryTree import

#include <Array.au3>
#include <File.au3>

Func GetHoveredHwnd($i_xpos, $i_ypos)
    Local $iRet = DllCall("user32.dll", "int", "WindowFromPoint", "long", $i_xpos, "long", $i_ypos)
    If IsArray($iRet) Then
        Local $appHandle = $iRet[0]
        Return HWnd($iRet[0])
    Else
        Return SetError(1, 0, 0)
    EndIf
 EndFunc   ;==>GetHoveredHwnd

Func _read_file($file_loc)

   Local $hFileOpen = FileOpen($file_loc, 0)
   Local $file_read = FileRead($hFileOpen)
   FileClose($hFileOpen)

   Return $file_read
EndFunc

Func _GetWindowHandle($deoNaslova)
    Local $WinList = WinList()
    ;_ArrayDisplay($WinList)
    For $i = 1 to $WinList[0][0]
        If StringInStr(($WinList[$i][0]), $deoNaslova) then
            Return $WinList[$i][1]
        EndIf
    Next
    Return 0
 EndFunc

Func _screenshot_mpc_cherryTree_import()
   Local $mPos = MouseGetPos()
   Local $active_win_handle = GetHoveredHwnd($mPos[0], $mPos[1])
   WinActivate($active_win_handle)
   Sleep(200)

   Local $folder_za_slike = _read_file(@ScriptDir & "\folder_za_slike.txt")
   Local $sleep = 100, $mPos, $mpc_title, $mpc_title_tmp
   If $folder_za_slike = "" Then
      MsgBox(262144, "Greska:", "napraviti fajl folder_za_slike.txt i upisati lokaciju foldera za slike")
      Return
   EndIf
   Local $hWnd_tmp, $podela_tmp, $podela_tmp2
   Local $lok_slike
   Local $pozicija_videa = ""
   Local $rucica_cherryTree = _GetWindowHandle(" - CherryTree")

   ; obrada brojanja slika
   Local $br_slika, $br_slika_tmp
   Local $niz_fajlovi = _FileListToArray($folder_za_slike, "*." & "png", 1)
   If @error Then $br_slika = 0
   If UBound($niz_fajlovi) - 1 > 0 Then $br_slika = UBound($niz_fajlovi) - 1
   $br_slika = $br_slika + 1
   Select
      Case $br_slika < 10 And $br_slika > 0
         $br_slika = "000" & $br_slika
      Case $br_slika < 100 And $br_slika > 9
         $br_slika = "00" & $br_slika
      Case $br_slika < 1000 And $br_slika > 99
         $br_slika = "0" & $br_slika
   EndSelect
   ; kraj obrade brojanja slika

   ; detekcija pozicije u windows classic palyer-u
   Local $mpc_vreme = WinGetText("[CLASS:MediaPlayerClassicW]", "")
   If StringInStr($mpc_vreme, @LF & @LF & @LF) Then
      ;MsgBox(0, "Vrednost je:", $mpc_vreme)
      $podela_tmp = StringSplit($mpc_vreme, @LF & @LF & @LF, 1)
      If IsArray($podela_tmp) And UBound($podela_tmp) - 1 >= 2 Then
         ;MsgBox(0, "Vrednost je:",$podela_tmp[2])
         ;_ArrayDisplay($podela_tmp, "$podela_tmp")
         If StringInStr($podela_tmp[2] , "/") Then
            $podela_tmp2 = StringSplit($podela_tmp[2], "/", 1)
            If IsArray($podela_tmp2) Then
               ;_ArrayDisplay($podela_tmp2, "$podela_tmp2")
               $pozicija_videa = StringStripWS(StringReplace($podela_tmp2[1], ":", "-"), 8)
               ;MsgBox(0, "Vrednost je:", $pozicija_videa)
            EndIf
         EndIf
      EndIf
   EndIf
   If $pozicija_videa = "" Then
      MsgBox(262144, "Greska:", "U imenu fajla nece biti pozcije videa")
   EndIf
   ; kraj detekcije pozicije

   ; picpic cuvanje slike
   $mPos = MouseGetPos()
   Send("+{PRINTSCREEN}")
   Sleep(500)
   MouseClick("primary")
   Do
      Sleep(100)
      $hWnd_tmp = _GetWindowHandle("PicPick ")
   Until WinActive($hWnd_tmp)
   WinWaitActive($hWnd_tmp)
   Sleep($sleep)
   Send("^s")
   WinWaitActive("Save As")
   $mpc_title = WinGetTitle("[CLASS:MediaPlayerClassicW]", "")
   If StringInStr($mpc_title, "\") Then
      $mpc_title_tmp = StringSplit($mpc_title, "\")
      If IsArray($mpc_title_tmp) Then
         ;_ArrayDisplay($mpc_title_tmp)
         $mpc_title = $mpc_title_tmp[UBound($mpc_title_tmp)-1]
      EndIf
   EndIf
   $lok_slike = $folder_za_slike & "\" & $br_slika & "_" & $mpc_title & "_"  & $pozicija_videa & "_" & @MDAY & "-" & @MON & "-" & @YEAR & "+" & @HOUR & "-" & @MIN & "-" & @SEC & "-" & @MSEC & ".png"
   ClipPut($lok_slike)
   Send("^v")
   Sleep($sleep)
   Send("{ENTER}")
   WinWaitClose("Save As")
   $hWnd_tmp = _GetWindowHandle("PicPick")
   WinActivate($hWnd_tmp)
   WinWaitActive($hWnd_tmp)
   If WinActive($hWnd_tmp) Then
      Send("^w")
      Sleep($sleep)
      WinClose($hWnd_tmp)
;~    Send("!{F4}")
   Else
      MsgBox(0, "Greska:", "Nije aktiviran krajnji picpic prozor")
   EndIf
   ; kraj picpic cuvanje slike

   If FileGetSize($lok_slike) > 100 Then
      ; unos u cherry tree
      WinActivate($rucica_cherryTree)
      WinWaitActive($rucica_cherryTree)
      Send("^!i")
      WinWaitActive("Select File")
      Send("^!i")
      Sleep($sleep)
      Send("^v")
      Sleep($sleep)
      Send("{ENTER}")
      WinWaitActive("Image Properties")
      Send("{ENTER}")
      WinWaitActive($rucica_cherryTree)
      ;Send("{ENTER 2}")
      MouseMove($mPos[0], $mPos[1], 0)
      ; kaj unosa cherry tree
   Else
      FileDelete($lok_slike)
      MsgBox(0, "Greska:", "Fajl manji od 100 bytes, obrisan, slikati ponovo", 3)
      WinActivate($rucica_cherryTree)
      MouseMove($mPos[0], $mPos[1], 0)
   EndIf
EndFunc

_screenshot_mpc_cherryTree_import()
; dependencies
   ; MeidaPlayerClassic, PicPick, CherryTree
   ; file folder_za_slike.txt, script folder, content, d:\slike