AutoArmor

$${

toggle(sleep_macro);
if(sleep_macro);
    log("&6[AutoArmor] &aLigado");
    log("&e&l» &7Script desenvolvido por &9SLEEP&7.");
    set(elmo_estoque);
    set(peito_estoque);
    set(calca_estoque);
    set(bota_estoque);
    unset(autoarmor);
else;
    log("&6[AutoArmor] &cDesligado ");
    stop;
endif;
do;
    if((HELMID == 0)&&(elmo_estoque));
        set(autoarmor);
        set(&armor_name,"&9Elmo");
        set(#arm_id,"310");
        set(#arm_id_netherite,"748");
    elseif((CHESTPLATEID == 0)&&(peito_estoque));
        set(autoarmor);
        set(&armor_name,"&9Peitoral");
        set(#arm_id,"311");
        set(#arm_id_netherite,"749");
    elseif((LEGGINGSID == 0)&&(calca_estoque));
        set(autoarmor);
        set(&armor_name,"&9Calças");
        set(#arm_id,"312");
        set(#arm_id_netherite,"750");
    elseif((BOOTSID == 0)&&(bota_estoque));
        set(autoarmor);
        set(&armor_name,"&9Botas");
        set(#arm_id,"313");
        set(#arm_id_netherite,"751");
    endif;
    if(autoarmor);
        gui(INVENTORY);
        if(KEY_W);
            keydown(FORWARD);
        elseif(KEY_S);
            keydown(BACK);
        endif;
        if(KEY_A);
            keydown(LEFT);
        elseif(KEY_D);
            keydown(RIGHT);
        endif;
        if(SHIFT);
            keydown(SNEAK);
        elseif(KEY_SPACE);
            keydown(JUMP);
        endif;
        if(RMOUSE);
            key(USE);
        endif;
        getslot(%#arm_id_netherite%,#sleep_slot,9);
        if(#sleep_slot == -1);
            getslot(%#arm_id%,#sleep_slot,9);
        endif;
        if(#sleep_slot == -1);
            log("&e&l» %&armor_name% &7sem estoque.");
            if((#arm_id == 310)||(#arm_id == 748));
                unset(elmo_estoque);
            elseif((#arm_id == 311)||(#arm_id == 749));
                unset(peito_estoque);
            elseif((#arm_id == 312)||(#arm_id == 750));
                unset(calca_estoque);
            elseif((#arm_id == 313)||(#arm_id == 751));
                unset(bota_estoque);
            endif;
        else;
            slotclick(%#sleep_slot%,L,TRUE);
            log("&e&l» %&armor_name% &7equipado.");
        endif;
        gui();
        wait(15MS);
        if((!elmo_estoque)&&(!peito_estoque)&&(!calca_estoque)&&(!bota_estoque));
            log("&6[AutoArmor] &cDesligado ");
            toggle(sleep_macro);
            stop;
        endif;
    endif;
    unset(autoarmor);
loop;

}$$