API tools faq
paste
Advertisement
Guest User

QTGMC 3.33s for avs 2.60

a guest
Aug 5th, 2015
419
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
Avisynth 84.50 KB | None | 0 0
raw download clone embed print report diff
  1. #-------------------------------------------------------------------#
  2. #                                                                   #
  3. #                    QTGMC 3.33, by Vit, 2012                       #
  4. #                                                                   #
  5. #   A high quality deinterlacer using motion-compensated temporal   #
  6. #  smoothing, with a range of features for quality and convenience  #
  7. #          Originally based on TempGaussMC_beta2 by Didée           #
  8. #                                                                   #
  9. #-------------------------------------------------------------------#
  10. #
  11. # Full documentation is in the 'QTGMC' html file that comes with this script
  12. #
  13. # --- LATEST CHANGES ---
  14. #
  15. # v3.33s (mod) 2015 8 6
  16. # - some changes in bob to speed up
  17. #
  18. # v3.33s (mod) 2015 8 4
  19. # - fix bug in YUY2 with SourceMatch
  20. # - add slice=false to ditherpost to avoid artefacts
  21. #
  22. # v3.33s (mod)
  23. # - fix bob chroma
  24. # - work with new masktool2 for avs 2.60
  25. #
  26. # v3.33d (mod)
  27. # - Added 32 bit precision option through the lsbd (for dfttest) and lsb (mdegrain) options.
  28. # - optimized some mask handling a bit as originally suggested by Vit
  29. # - others
  30. #
  31. # v3.33
  32. # - Increased maximum value for Rep0, Rep1 and Rep2 to 7 (from 5). Higher values help with flicker on static detail, potential for minor motion blur
  33. # - Bug fix for the fact that Bob always outputs a BFF clip regardless of field order of input (thanks ajp_anton)
  34. # - Improved generation of noise (NoiseDeint="Generate") for noise bypass / EZKeepGrain
  35. # - Minor change to denoising
  36. #
  37. # v3.32
  38. # - Bugfix with shutter blur and ChromaMotion (thanks Heaud)
  39. # - Tweaked vector recalculation for shutter motion blur
  40. # - Changed defaults for TR2 when using source-match
  41. # - Minor bugfix with SLMode/SLRad on pass-through settings
  42. #
  43. # --- REQUIREMENTS ---
  44. #
  45. # Input colorspaces: YV12, YUY2
  46. #
  47. # Core plugins:
  48. #   MVTools2 (2.5.11.3 or above)
  49. #   MaskTools v2 (recommend 2.0a48 or above. Must use the 2.5 version with YUY2)
  50. #   NNEDI3 (recommend 0.9.4 or above for speed)
  51. #   RemoveGrain + Repair (several versions of this plugin, use the SSE2 dlls from the file called "RemoveGrain-1.0.rar". Don't use the SSE3 versions )
  52. #   SSE2Tools for YUY2 support (from the earlier 0.9 version of RemoveGrain, use only SSE2Tools.dll from this version. Don't use the SSE3 version)
  53. #
  54. # Additional plugins:
  55. #   NNEDI2, NNEDI, EEDI3, EEDI2, TDeInt - if selected directly or via a source-match preset
  56. #   Yadif - for Preset="Ultra Fast" or if selected directly (cannot be autoloaded, must be loaded in the calling script)
  57. #   VerticalCleaner - for SVThin or Lossless modes
  58. #   FFT3DFilter - if selected for noise processing
  59. #   dfttest - if selected for noise processing
  60. #       For FFT3DFilter & ddftest you also need the FFTW3 library (FFTW.org). On Windows the file needed for both is libfftw3f-3.dll. However, for FFT3DFilter
  61. #       the file needs to be called FFTW3.dll, so you will need two copies and rename one. On Windows put the files in your System32 or SysWow64 folder
  62. #   AddGrainC - if NoiseDeint="Generate" selected for noise bypass
  63.  
  64.  
  65. # --- GETTING STARTED ---
  66. #
  67. # Install AviSynth and ensure you have at least the core plugins listed in the requirements section above. Put them in the plugins autoload folder.
  68. # To use QTGMC write a script like this:
  69. #   YourSource("yourfile")   # DGDecode_mpeg2source, FFVideoSource, AviSource, whatever your source requires
  70. #   QTGMC( Preset="Slow" )
  71. #   SelectEven()             # Add this line to keep original frame rate, leave it out for smoother doubled frame rate
  72. #
  73. # Save this script with an ".avs" extension. You can now use it as an AVI source for encoding.
  74. #
  75. # The "Preset" used selects sensible settings for a given encoding speed. Choose a preset from:
  76. #   "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast" & "Draft"
  77. # The default preset is "Slower"
  78. # Don't be obsessed with using slower settings as the differences can be small. HD material benefits little from extreme settings (and will be very slow)
  79. # For much faster speeds read the full documentation, the section on 'Multi-threading'
  80. #
  81. # There are many settings for tweaking the script, full details in the main documentation. You can display settings currently being used with "ShowSettings":
  82. #   QTGMC( Preset="Slow", ShowSettings=true )
  83.  
  84.  
  85. function QTGMC( clip Input, string "Preset", int "TR0", int "TR1", int "TR2", int "Rep0", int "Rep1", int "Rep2", string "EdiMode", bool "RepChroma", \
  86.                     int "NNSize", int "NNeurons", int "EdiQual", int "EdiMaxD", string "ChromaEdi", int "EdiThreads", clip "EdiExt", float "Sharpness", \
  87.                     int "SMode", int "SLMode", int "SLRad", int "SOvs", float "SVThin", int "Sbb", int "SrchClipPP", int "SubPel", int "SubPelInterp", \
  88.                     int "BlockSize", int "Overlap", int "Search", int "SearchParam", int "PelSearch", bool "ChromaMotion", bool "TrueMotion", int "Lambda", \
  89.                     int "LSAD", int "PNew", int "PLevel", bool "GlobalMotion", int "DCT", int "ThSAD1", int "ThSAD2", int "ThSCD1", int "ThSCD2", \
  90.                     int "SourceMatch", string "MatchPreset", string "MatchEdi", string "MatchPreset2", string "MatchEdi2", int "MatchTR2", \
  91.                     float "MatchEnhance", int "Lossless", int "NoiseProcess", float "EZDenoise", float "EZKeepGrain", string "NoisePreset", string "Denoiser", \
  92.                     int "DftThreads", bool "DenoiseMC", int "NoiseTR", float "Sigma", bool "ChromaNoise", val "ShowNoise", float "GrainRestore", \
  93.                     float "NoiseRestore", string "NoiseDeint", bool "StabilizeNoise", int "InputType", float "ProgSADMask", int "FPSDivisor", \
  94.                     int "ShutterBlur", float "ShutterAngleSrc", float "ShutterAngleOut", int "SBlurLimit", bool "Border", bool "Precise", string "Tuning", \
  95.                     bool "ShowSettings", string "GlobalNames", string "PrevGlobals", int "ForceTR", \
  96.                     val "BT", val "DetailRestore", val "MotionBlur", val "MBlurLimit", val "NoiseBypass", bool "lsbd", bool "lsb" )
  97. {
  98.     # The preset "Ultra Fast" & EdiMode="RepYadif"/"Yadif" require the Yadif plugin, which doesn't autoload. Typically the calling script would load it.
  99.     # To have this script load Yadif put it's full path in string below (e.g. "C:\Plugins\Yadif.dll"). Use empty string ("") if calling script will load Yadif
  100.     YadifPath = "" # Or just enter "yadif.dll" if Yadif is placed in the system path (e.g. windows\system32)
  101.  
  102.     # Temporary Warnings
  103.     Assert( !defined(BT),            "QTGMC: Setting BT has been replaced by setting NoiseTR" )
  104.     Assert( !defined(DetailRestore), "QTGMC: Setting DetailRestore has been renamed to GrainRestore" )
  105.     Assert( !defined(MotionBlur),    "QTGMC: Setting MotionBlur has been renamed to ShutterBlur" )
  106.     Assert( !defined(MBlurLimit),    "QTGMC: Setting MBlurLimit has been renamed to SBlurLimit" )
  107.     Assert( !defined(NoiseBypass),   "QTGMC: Setting NoiseBypass has been renamed to NoiseProcess" )
  108.  
  109.     #---------------------------------------
  110.     # Presets
  111. lsbd=default(lsbd, false)
  112. lsb=default(lsb, false)
  113.     # Select presets / tuning
  114.     Preset = default( Preset, "Slower" )
  115.     pNum = (Preset == "Placebo"   ) ? 0 : \
  116.            (Preset == "Very Slow" ) ? 1 : \
  117.            (Preset == "Slower"    ) ? 2 : \
  118.            (Preset == "Slow"      ) ? 3 : \
  119.            (Preset == "Medium"    ) ? 4 : \
  120.            (Preset == "Fast"      ) ? 5 : \
  121.            (Preset == "Faster"    ) ? 6 : \
  122.            (Preset == "Very Fast" ) ? 7 : \
  123.            (Preset == "Super Fast") ? 8 : \
  124.            (Preset == "Ultra Fast") ? 9 : \
  125.            (Preset == "Draft"     ) ? 10 : 11
  126.     Assert( pNum  < 11, "'Preset' choice is invalid" )
  127.  
  128.     mpNum1 = (!defined(MatchPreset))       ? ((pNum + 3 <= 9) ? (pNum + 3) : 9) : \
  129.              (MatchPreset == "Placebo"   ) ? 0 : \
  130.              (MatchPreset == "Very Slow" ) ? 1 : \
  131.              (MatchPreset == "Slower"    ) ? 2 : \
  132.              (MatchPreset == "Slow"      ) ? 3 : \
  133.              (MatchPreset == "Medium"    ) ? 4 : \
  134.              (MatchPreset == "Fast"      ) ? 5 : \
  135.              (MatchPreset == "Faster"    ) ? 6 : \
  136.              (MatchPreset == "Very Fast" ) ? 7 : \
  137.              (MatchPreset == "Super Fast") ? 8 : \
  138.              (MatchPreset == "Ultra Fast") ? 9 : \
  139.              (MatchPreset == "Draft"     ) ? 10 : 11
  140.     Assert( mpNum1 < 10, "'MatchPreset' choice is invalid/unsupported" )
  141.     MatchPreset = Select( mpNum1, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  142.  
  143.     mpNum2 = (!defined(MatchPreset2))       ? ((mpNum1 + 2 <= 9) ? (mpNum1 + 2) : 9) : \
  144.              (MatchPreset2 == "Placebo"   ) ? 0 : \
  145.              (MatchPreset2 == "Very Slow" ) ? 1 : \
  146.              (MatchPreset2 == "Slower"    ) ? 2 : \
  147.              (MatchPreset2 == "Slow"      ) ? 3 : \
  148.              (MatchPreset2 == "Medium"    ) ? 4 : \
  149.              (MatchPreset2 == "Fast"      ) ? 5 : \
  150.              (MatchPreset2 == "Faster"    ) ? 6 : \
  151.              (MatchPreset2 == "Very Fast" ) ? 7 : \
  152.              (MatchPreset2 == "Super Fast") ? 8 : \
  153.              (MatchPreset2 == "Ultra Fast") ? 9 : \
  154.              (MatchPreset2 == "Draft"     ) ? 10 : 11
  155.     Assert( mpNum2 < 10, "'MatchPreset2' choice is invalid/unsupported" )
  156.     MatchPreset2 = Select( mpNum2, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  157.  
  158.     NoisePreset = default( NoisePreset, "Fast" )
  159.     npNum = (NoisePreset == "Slower" ) ? 0 : \
  160.             (NoisePreset == "Slow"   ) ? 1 : \
  161.             (NoisePreset == "Medium" ) ? 2 : \
  162.             (NoisePreset == "Fast"   ) ? 3 : \
  163.             (NoisePreset == "Faster" ) ? 4 : 5
  164.     Assert( npNum < 5, "'NoisePreset' choice is invalid" )
  165.  
  166.     Tuning = default( Tuning, "None" )
  167.     tNum = (Tuning == "None"  ) ? 0 : \
  168.            (Tuning == "DV-SD" ) ? 1 : \
  169.            (Tuning == "DV-HD" ) ? 2 : 3
  170.     Assert( tNum < 3, "'Tuning' choice is invalid" )
  171.  
  172.     # Tunings only affect blocksize in this version
  173.     bs = Select( tNum,  16, 16, 32 )
  174.     bs2 = (bs >= 16) ? 32 : bs * 2
  175.  
  176.     #                                                               Very                                                        Very      Super      Ultra
  177.     # Preset groups:                                     Placebo    Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast       Fast       Draft
  178.     TR0          = default( TR0,          Select( pNum,  2,         2,        2,        2,        2,        2,        1,        1,        1,         1,         1      ) )
  179.     TR1          = default( TR1,          Select( pNum,  2,         2,        2,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  180.     TR2X         = default( TR2,          Select( pNum,  3,         2,        1,        1,        1,        0,        0,        0,        0,         0,         0      ) )
  181.     Rep0         = default( Rep0,         Select( pNum,  4,         4,        4,        4,        3,        3,        0,        0,        0,         0,         0      ) )
  182.     Rep1         = default( Rep1,         Select( pNum,  0,         0,        0,        0,        0,        0,        0,        0,        0,         0,         0      ) )
  183.     Rep2         = default( Rep2,         Select( pNum,  4,         4,        4,        4,        4,        4,        4,        4,        3,         3,         0      ) )
  184.     EdiMode      = default( EdiMode,      Select( pNum, "NNEDI3",  "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3",  "RepYadif","Bob"   ) )
  185.     NNSize       = default( NNSize,       Select( pNum,  1,         1,        1,        1,        5,        5,        4,        4,        4,         4,         4      ) )
  186.     NNeurons     = default( NNeurons,     Select( pNum,  2,         2,        1,        1,        1,        0,        0,        0,        0,         0,         0      ) )
  187.     EdiQual      = default( EdiQual,      Select( pNum,  1,         1,        1,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  188.     EdiMaxD      = default( EdiMaxD,      Select( pNum,  12,        10,       8,        7,        7,        6,        6,        5,        4,         4,         4      ) )
  189.     SMode        = default( SMode,        Select( pNum,  2,         2,        2,        2,        2,        2,        2,        2,        2,         2,         0      ) )
  190.     SLModeX      = default( SLMode,       Select( pNum,  2,         2,        2,        2,        2,        2,        2,        2,        0,         0,         0      ) )
  191.     SLRad        = default( SLRad,        Select( pNum,  3,         1,        1,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  192.     Sbb          = default( Sbb,          Select( pNum,  3,         1,        1,        0,        0,        0,        0,        0,        0,         0,         0      ) )
  193.     SrchClipPP   = default( SrchClipPP,   Select( pNum,  3,         3,        3,        3,        3,        2,        2,        2,        1,         1,         0      ) )
  194.     SubPel       = default( SubPel,       Select( pNum,  2,         2,        2,        2,        1,        1,        1,        1,        1,         1,         1      ) )
  195.     Blocksize    = default( Blocksize,    Select( pNum,  bs,        bs,       bs,       bs,       bs,       bs,       bs2,      bs2,      bs2,       bs2,       bs2    ) )
  196.     bs = Blocksize
  197.     Overlap      = default( Overlap,      Select( pNum,  bs/2,      bs/2,     bs/2,     bs/2,     bs/2,     bs/2,     bs/2,     bs/4,     bs/4,      bs/4,      bs/4   ) )
  198.     Search       = default( Search,       Select( pNum,  5,         4,        4,        4,        4,        4,        4,        4,        0,         0,         0      ) )
  199.     SearchParam  = default( SearchParam,  Select( pNum,  2,         2,        2,        2,        2,        2,        2,        1,        1,         1,         1      ) )
  200.     PelSearch    = default( PelSearch,    Select( pNum,  2,         2,        2,        2,        1,        1,        1,        1,        1,         1,         1      ) )
  201.     ChromaMotion = default( ChromaMotion, Select( pNum,  true,      true,     true,     false,    false,    false,    false,    false,    false,     false,     false  ) )
  202.     Precise      = default( Precise,      Select( pNum,  true,      true,     false,    false,    false,    false,    false,    false,    false,     false,     false  ) )
  203.     ProgSADMask  = default( ProgSADMask,  Select( pNum,  10.0,      10.0,     10.0,     10.0,     10.0,     0.0,      0.0,      0.0,      0.0,       0.0,       0.0    ) )
  204.  
  205.     # Noise presets                                           Slower     Slow       Medium     Fast       Faster
  206.     Denoiser       = default( Denoiser,       Select( npNum, "dfttest", "dfttest", "dfttest", "fft3df",  "fft3df" ) )
  207.     DenoiseMC      = default( DenoiseMC,      Select( npNum,  true,      true,      false,     false,     false   ) )
  208.     NoiseTR        = default( NoiseTR,        Select( npNum,  2,         1,         1,         1,         0       ) )
  209.     NoiseDeint     = default( NoiseDeint,     Select( npNum, "Generate","Bob",      "",        "",        ""      ) )
  210.     StabilizeNoise = default( StabilizeNoise, Select( npNum,  true,      true,      true,      false,     false   ) )
  211.  
  212.     # The basic source-match step corrects and re-runs the interpolation of the input clip. So it initialy uses same interpolation settings as the main preset
  213.     SourceMatch   = default( SourceMatch, 0 )
  214.     MatchNNSize   = NNSize
  215.     MatchNNeurons = NNeurons
  216.     MatchEdiMaxD  = EdiMaxD
  217.     MatchEdiQual  = EdiQual
  218.  
  219.     # However, can use a faster initial interpolation when using source-match allowing the basic source-match step to "correct" it with higher quality settings
  220.     Assert( SourceMatch == 0 || mpNum1 >= pNum, "'MatchPreset' cannot use a slower setting than 'Preset'" )
  221.     #                                                                    Very                                                        Very      Super     Ultra
  222.     # Basic source-match presets                                Placebo  Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast      Fast
  223.     NNSize   = (SourceMatch == 0) ? NNSize   : Select( mpNum1,  1,       1,        1,        1,        5,        5,        4,        4,        4,        4     )
  224.     NNeurons = (SourceMatch == 0) ? NNeurons : Select( mpNum1,  2,       2,        1,        1,        1,        0,        0,        0,        0,        0     )
  225.     EdiMaxD  = (SourceMatch == 0) ? EdiMaxD  : Select( mpNum1,  12,      10,       8,        7,        7,        6,        6,        5,        4,        4     )
  226.     EdiQual  = (SourceMatch == 0) ? EdiQual  : Select( mpNum1,  1,       1,        1,        1,        1,        1,        1,        1,        1,        1     )
  227.     TempEdi  = EdiMode # Main interpolation is actually done by basic-source match step when enabled, so a little swap and wriggle is needed
  228.     EdiMode  = (SourceMatch == 0) ? EdiMode  : default( MatchEdi, ((mpNum1 < 9) ?  EdiMode : "Yadif") ) # Force Yadif for "Ultra Fast" basic source match
  229.     MatchEdi = TempEdi
  230.  
  231.     #                                                          Very                                                        Very      Super     Ultra
  232.     # Refined source-match presets                   Placebo   Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast      Fast
  233.     MatchEdi2 = default( MatchEdi2, Select( mpNum2, "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "TDeint",  ""    ) )
  234.     MatchNNSize2                  = Select( mpNum2,  1,        1,        1,        1,        5,        5,        4,        4,        4,        4     )
  235.     MatchNNeurons2                = Select( mpNum2,  2,        2,        1,        1,        1,        0,        0,        0,        0,        0     )
  236.     MatchEdiMaxD2                 = Select( mpNum2,  12,       10,       8,        7,        7,        6,        6,        5,        4,        4     )
  237.     MatchEdiQual2                 = Select( mpNum2,  1,        1,        1,        1,        1,        1,        1,        1,        1,        1     )
  238.  
  239.  
  240.     #---------------------------------------
  241.     # Settings
  242.  
  243.     # Core and Interpolation defaults
  244.     TR2        = (SourceMatch > 0) ? default(TR2, ((TR2X == 0) ? 1 : TR2X)) : TR2X  # ***TR2 defaults always at least 1 when using source-match***
  245.     RepChroma  = default( RepChroma,  true )
  246.     EdiThreads = default( EdiThreads, 0    )
  247.     ChromaEdi  = default( ChromaEdi,  ""   )
  248.     NNeurons   = (EdiMode == "NNEDI2" && NNeurons > 2) ? 2 : NNeurons # Smaller range for NNeurons in NNEDI2 (which calls it nsize)
  249.     EdiQual    = (EdiMode == "NNEDI3" && EdiQual > 2 ) ? 2 : EdiQual  # Smaller range for EdiQual in NNEDI3
  250.     ((FindStr( EdiMode, "Yadif" ) != 0 || FindStr( MatchEdi, "Yadif" ) != 0 || FindStr( MatchEdi2, "Yadif" ) != 0  ) && YadifPath != "") ? \
  251.         Load_Stdcall_Plugin( YadifPath ) : NOP() # Load Yadif as required
  252.  
  253.     # Source-match / lossless defaults
  254.     MatchTR1     = TR1
  255.     MatchTR2     = default( MatchTR2,     1   )
  256.     MatchEnhance = default( MatchEnhance, 0.5 )
  257.     Lossless     = default( Lossless,     0   )
  258.     Assert( Lossless <= 2, "Lossless setting only supports mode 1 ('true lossless') and mode 2 ('fake lossless') - see documentation in script and consider source-match settings" )
  259.  
  260.     # Sharpness defaults. Sharpness default is always 1.0 (0.2 with source-match), but adjusted to give roughly same sharpness for all settings
  261.     SMode      = (defined(Sharpness) && Sharpness == 0.0) ? 0 : SMode
  262.     SLMode     = (SourceMatch > 0) ? default(SLMode, 0) : SLModeX  # ***Sharpness limiting disabled by default for source-match***
  263.     SLMode     = (SLRad <= 0)      ? 0 : SLMode
  264.     spatialSL  = (SLMode == 1 || SLMode == 3)
  265.     temporalSL = (SLMode == 2 || SLMode == 4)
  266.     Sharpness  = default( Sharpness, (SMode == 0) ? 0.0 : ((SourceMatch > 0) ? 0.2 : 1.0) )      # Default sharpness is 1.0, or 0.2 if using source-match
  267.     sharpMul   = (temporalSL) ? 2 : (spatialSL) ? 1.5 : 1                                        # Adjust sharpness based on other settings
  268.     sharpAdj   = Sharpness * (sharpMul * (0.2 + TR1*0.15 + TR2*0.25) + ((SMode == 1) ? 0.1 : 0)) # [This needs a bit more refinement]
  269.     Sbb        = (SMode == 0) ? 0 : Sbb
  270.     SOvs       = default( SOvs,   0   )
  271.     SVThin     = default( SVThin, 0.0 )
  272.  
  273.     # Noise processing settings
  274.     Assert( !defined(EZDenoise) || EZDenoise <= 0.0 || !defined(EZKeepGrain) || EZKeepGrain <= 0.0, "QTGMC: EZDenoise and EZKeepGrain cannot be used together" )
  275.     NoiseProcess = defined(NoiseProcess) ? NoiseProcess : \
  276.                    (defined(EZDenoise)   && EZDenoise   > 0.0)    ? 1 : \
  277.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0)    ? 2 : \
  278.                    (Preset == "Placebo" || Preset == "Very Slow") ? 2 : 0
  279.     GrainRestore = defined(GrainRestore) ? GrainRestore : \
  280.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? 0.0 : \
  281.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.3 * sqrt(EZKeepGrain) : \
  282.                                                                 Select( NoiseProcess, 0.0, 0.7, 0.3 )
  283.     NoiseRestore = defined(NoiseRestore) ? NoiseRestore : \
  284.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? 0.0 : \
  285.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.1 * sqrt(EZKeepGrain) : \
  286.                                                                 Select( NoiseProcess, 0.0, 0.3, 0.1 )
  287.     Sigma        = defined(Sigma)       ? Sigma : \
  288.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? EZDenoise : \
  289.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 4.0 * EZKeepGrain : 2.0
  290.     DftThreads   = default( DftThreads, EdiThreads )
  291.     ChromaNoise  = default( ChromaNoise, false )
  292.     ShowNoise    = default( ShowNoise, 0.0 )
  293.     ShowNoise    = IsBool( ShowNoise ) ? (ShowNoise ? 10.0 : 0.0) : ShowNoise
  294.     NoiseProcess = (ShowNoise > 0.0)   ? 2   : NoiseProcess
  295.     NoiseRestore = (ShowNoise > 0.0)   ? 1.0 : NoiseRestore
  296.     NoiseTR      = (NoiseProcess == 0) ? 0   : NoiseTR
  297.     GrainRestore = (NoiseProcess == 0) ? 0.0 : GrainRestore
  298.     NoiseRestore = (NoiseProcess == 0) ? 0.0 : NoiseRestore
  299.     totalRestore = GrainRestore + NoiseRestore
  300.     StabilizeNoise = (totalRestore <= 0) ? false : StabilizeNoise
  301.     noiseTD  = Select( NoiseTR, 1, 3, 5 )
  302.     noiseCentre = (Denoiser == "dfttest") ? "128" : "128.5"
  303.  
  304.     # MVTools settings
  305.     SubPelInterp = default( SubPelInterp, 2     )
  306.     TrueMotion   = default( TrueMotion,   false )
  307.     GlobalMotion = default( GlobalMotion, true  )
  308.     Lambda       = default( Lambda, ((TrueMotion) ? 1000 : 100 ) * (BlockSize*BlockSize)/(8*8) )
  309.     LSAD         = default( LSAD,    (TrueMotion) ? 1200 : 400 )
  310.     PNew         = default( PNew,    (TrueMotion) ? 50   : 25  )
  311.     PLevel       = default( PLevel,  (TrueMotion) ? 1    : 0   )
  312.     DCT          = default( DCT,     0          )
  313.     ThSAD1       = default( ThSAD1,  10 * 8*8   )
  314.     ThSAD2       = default( ThSAD2,   4 * 8*8   )
  315.     ThSCD1       = default( ThSCD1,  180        )
  316.     ThSCD2       = default( ThSCD2,  98         )
  317.  
  318.     # Motion blur settings
  319.     FPSDivisor  = default( FPSDivisor, 1 )
  320.     ShutterBlur = default( ShutterBlur, 0 )
  321.     ShutterAngleSrc = default( ShutterAngleSrc, 180 )
  322.     ShutterAngleOut = default( ShutterAngleOut, 180 )
  323.     SBlurLimit  = default( SBlurLimit, 4 )
  324.     ShutterBlur = (ShutterAngleOut * FPSDivisor == ShutterAngleSrc) ? 0 : ShutterBlur  # If motion blur output is same as input
  325.  
  326.     # Miscellaneous
  327.     InputType      = default( InputType,     0        )
  328.     Border         = default( Border,        false    )
  329.     ShowSettings   = default( ShowSettings,  false    )
  330.     GlobalNames    = default( GlobalNames,  "QTGMC"   )
  331.     PrevGlobals    = default( PrevGlobals,  "Replace" )
  332.     ForceTR        = default( ForceTR,       0        )
  333.     ReplaceGlobals = (PrevGlobals == "Replace" || PrevGlobals == "Reuse") # If reusing existing globals put them back afterwards - simplifies logic later
  334.     ReuseGlobals   = (PrevGlobals == "Reuse")
  335.     ProgSADMask    = (InputType != 2 && InputType != 3) ? 0.0 : ProgSADMask
  336.     rgBlur         = (Precise) ? 11 : 12
  337.  
  338.     # Get maximum temporal radius needed
  339.     maxTR = (temporalSL)       ? SLRad : 0
  340.     maxTR = (MatchTR2 > maxTR) ? MatchTR2 : maxTR
  341.     maxTR = (TR1 > maxTR)      ? TR1 : maxTR
  342.     maxTR = (TR2 > maxTR)      ? TR2 : maxTR
  343.     maxTR = (NoiseTR > maxTR)  ? NoiseTR : maxTR
  344.     maxTR = (ProgSADMask > 0.0 || StabilizeNoise || ShutterBlur > 0) ? (maxTR > 1 ? maxTR : 1) : maxTR
  345.     maxTR = (ForceTR > MaxTR)  ? ForceTR : maxTR
  346.  
  347.  
  348.     #---------------------------------------
  349.     # Pre-Processing
  350.  
  351.     w = Input.Width()
  352.     h = Input.Height()
  353.     yuy2 = Input.IsYUY2()
  354.     epsilon = 0.0001
  355.  
  356.     # Reverse "field" dominance for progressive repair mode 3 (only difference from mode 2)
  357.     compl = (InputType == 3) ? Input.ComplementParity() : Input
  358.  
  359.     # Pad vertically during processing (to prevent artefacts at top & bottom edges)
  360.     clip = (Border) ? compl.PointResize( w,h+8, 0,-4,0,h+8+epsilon ) : compl
  361.     h = (Border) ? h+8 : h
  362.  
  363.     # Calculate padding needed for MVTools super clips to avoid crashes [fixed in latest MVTools, but keeping this code for a while]
  364.     hpad = w - (Int((w - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  365.     vpad = h - (Int((h - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  366.     hpad = (hpad > 8) ? hpad : 8 # But match default padding if possible
  367.     vpad = (vpad > 8) ? vpad : 8
  368.  
  369.  
  370.     #---------------------------------------
  371.     # Motion Analysis
  372.  
  373.     # >>> Planar YUY2 for motion analysis, interleaved whilst blurring search clip
  374.     planarClip = yuy2 ? clip.Interleaved2Planar() : clip
  375.  
  376.     # Bob the input as a starting point for motion search clip
  377.     bobbed = (InputType == 0) ? planarClip.QTGMC_Bob( 0,0.5 ) : \
  378.              (InputType == 1) ? planarClip : \
  379.                                 planarClip.Blur( 0,1 )
  380.  
  381.     # If required, get any existing global clips with a matching "GlobalNames" setting. Unmatched values get NOP (= 0)
  382.     srchClip  = QTGMC_GetUserGlobal( GlobalNames, "srchClip",  ReuseGlobals )
  383.     srchSuper = QTGMC_GetUserGlobal( GlobalNames, "srchSuper", ReuseGlobals )
  384.     bVec1     = QTGMC_GetUserGlobal( GlobalNames, "bVec1",     ReuseGlobals )
  385.     fVec1     = QTGMC_GetUserGlobal( GlobalNames, "fVec1",     ReuseGlobals )
  386.     bVec2     = QTGMC_GetUserGlobal( GlobalNames, "bVec2",     ReuseGlobals )
  387.     fVec2     = QTGMC_GetUserGlobal( GlobalNames, "fVec2",     ReuseGlobals )
  388.     bVec3     = QTGMC_GetUserGlobal( GlobalNames, "bVec3",     ReuseGlobals )
  389.     fVec3     = QTGMC_GetUserGlobal( GlobalNames, "fVec3",     ReuseGlobals )
  390.  
  391.     CMmt = ChromaMotion ? 3   :  1
  392.     CMts = ChromaMotion ? 255 :  0
  393.     CMrg = ChromaMotion ? 12  : -1
  394.  
  395.     # The bobbed clip will shimmer due to being derived from alternating fields. Temporally smooth over the neighboring frames using a binomial kernel. Binomial
  396.     # kernels give equal weight to even and odd frames and hence average away the shimmer. The two kernels used are [1 2 1] and [1 4 6 4 1] for radius 1 and 2.
  397.     # These kernels are approximately Gaussian kernels, which work well as a prefilter before motion analysis (hence the original name for this script)
  398.     # Create linear weightings of neighbors first                                                 -2    -1     0    1     2
  399.     ts1 = (!IsClip(srchClip) && TR0 > 0) ? bobbed.TemporalSoften( 1, 255,CMts, 28, 2 ) : NOP()  # 0.00  0.33  0.33  0.33  0.00
  400.     ts2 = (!IsClip(srchClip) && TR0 > 1) ? bobbed.TemporalSoften( 2, 255,CMts, 28, 2 ) : NOP()  # 0.20  0.20  0.20  0.20  0.20
  401.  
  402.     # Combine linear weightings to give binomial weightings - TR0=0: (1), TR0=1: (1:2:1), TR0=2: (1:4:6:4:1)
  403.     binomial0 = IsClip(srchClip) ? NOP() : \
  404.                 (TR0 == 0)       ? bobbed : \
  405.                 (TR0 == 1)       ? (ChromaMotion ? ts1.Merge( bobbed, 0.25 ) : ts1.MergeLuma( bobbed, 0.25 )): \
  406.                                    (ChromaMotion ? ts1.Merge( ts2, 0.357 ).Merge( bobbed, 0.125 ) : ts1.MergeLuma( ts2, 0.357 ).MergeLuma( bobbed, 0.125 ))
  407.  
  408.     # Remove areas of difference between temporal blurred motion search clip and bob that are not due to bob-shimmer - removes general motion blur
  409.     repair0 = (IsClip(srchClip) || Rep0 == 0) ? binomial0 : binomial0.QTGMC_KeepOnlyBobShimmerFixes( bobbed, Rep0, (RepChroma && ChromaMotion) )
  410.  
  411.     # Blur image and soften edges to assist in motion matching of edge blocks. Blocks are matched by SAD (sum of absolute differences between blocks), but even
  412.     # a slight change in an edge from frame to frame will give a high SAD due to the higher contrast of edges
  413.     spatialBlur = (IsClip(srchClip) || SrchClipPP == 0) ? NOP() : \
  414.                   (!yuy2 && SrchClipPP == 1) ? repair0.BilinearResize( w/2, h/2 ).RemoveGrain( 12,CMrg, planar=true ).BilinearResize( w, h ) : \
  415.                   (!yuy2)                    ? repair0.RemoveGrain( 12,CMrg, planar=true ).GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=2 ) : \
  416.                                                repair0.RemoveGrain( 12,CMrg, planar=true ).Planar2Interleaved().GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=2 ).Interleaved2Planar()
  417.     spatialBlur = (IsClip(spatialBlur) && SrchClipPP > 1) ? (ChromaMotion ? spatialBlur.Merge( repair0, 0.1 ) : spatialBlur.MergeLuma( repair0, 0.1 )) : spatialBlur
  418.     tweluin26 = isyuy2(repair0) ? mt_lutxy( repair0.planar2interleaved.ConvertToYV16, bobbed.planar2interleaved.ConvertToYV16, "x 3 + y < x 3 + x 3 - y > x 3 - y ? ?", U=CMmt,V=CMmt ).ConvertToYuy2.interleaved2planar : \
  419.     mt_lutxy( repair0, bobbed, "x 3 + y < x 3 + x 3 - y > x 3 - y ? ?", U=CMmt,V=CMmt )
  420.     tweaked     = (!IsClip(srchClip) && SrchClipPP > 1) ? tweluin26 : NOP()
  421.     srchClip    = IsClip(srchClip)  ? srchClip : \
  422.                   (SrchClipPP == 0) ? repair0 : \
  423.                   (SrchClipPP < 3)  ? spatialBlur : \
  424.                                       isclip(spatialBlur) && isyuy2(spatialBlur) ? spatialBlur.planar2interleaved.ConvertToYV16.mt_lutxy( isclip(tweaked) ? tweaked.planar2interleaved.ConvertToYV16 : tweaked, \
  425.     "x 7 + y < x 2 + x 7 - y > x 2 - x 51 * y 49 * + 100 / ? ?", U=CMmt,V=CMmt ).ConvertToYuy2.interleaved2planar : \
  426.     spatialBlur.mt_lutxy( tweaked, "x 7 + y < x 2 + x 7 - y > x 2 - x 51 * y 49 * + 100 / ? ?", U=CMmt,V=CMmt )
  427.     # Calculate forward and backward motion vectors from motion search clip
  428.     srchSuper = IsClip(srchSuper) ? srchSuper : \
  429.                 (maxTR > 0)       ? srchClip.MSuper( pel=SubPel, sharp=SubPelInterp, hpad=hpad, vpad=vpad, chroma=ChromaMotion, planar=true ) : NOP()
  430.     bVec3 = IsClip(bVec3) ? bVec3 : \
  431.             (maxTR > 2)   ? srchSuper.MAnalyse( isb=true,  delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  432.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  433.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  434.     bVec2 = IsClip(bVec2) ? bVec2 : \
  435.             (maxTR > 1)   ? srchSuper.MAnalyse( isb=true,  delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  436.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  437.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  438.     bVec1 = IsClip(bVec1) ? bVec1 : \
  439.             (maxTR > 0)   ? srchSuper.MAnalyse( isb=true,  delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  440.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  441.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  442.     fVec1 = IsClip(fVec1) ? fVec1 : \
  443.             (maxTR > 0)   ? srchSuper.MAnalyse( isb=false, delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  444.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  445.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  446.     fVec2 = IsClip(fVec2) ? fVec2 : \
  447.             (maxTR > 1)   ? srchSuper.MAnalyse( isb=false, delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  448.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  449.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  450.     fVec3 = IsClip(fVec3) ? fVec3 : \
  451.             (maxTR > 2)   ? srchSuper.MAnalyse( isb=false, delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  452.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  453.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  454.  
  455.     # Expose search clip, motion search super clip and motion vectors to calling script through globals
  456.     QTGMC_SetUserGlobal( GlobalNames, "srchClip",  srchClip,  ReplaceGlobals )
  457.     QTGMC_SetUserGlobal( GlobalNames, "srchSuper", srchSuper, ReplaceGlobals )
  458.     QTGMC_SetUserGlobal( GlobalNames, "bVec1",     bVec1,     ReplaceGlobals )
  459.     QTGMC_SetUserGlobal( GlobalNames, "fVec1",     fVec1,     ReplaceGlobals )
  460.     QTGMC_SetUserGlobal( GlobalNames, "bVec2",     bVec2,     ReplaceGlobals )
  461.     QTGMC_SetUserGlobal( GlobalNames, "fVec2",     fVec2,     ReplaceGlobals )
  462.     QTGMC_SetUserGlobal( GlobalNames, "bVec3",     bVec3,     ReplaceGlobals )
  463.     QTGMC_SetUserGlobal( GlobalNames, "fVec3",     fVec3,     ReplaceGlobals )
  464.  
  465.  
  466.     #---------------------------------------
  467.     # Noise Processing
  468.  
  469.     # >>>> Interleaved YUY2 for denoising, planar whilst pre-motion compensating
  470.  
  471.     # Expand fields to full frame size before extracting noise (allows use of motion vectors which are frame-sized)
  472.     fullClip  = (NoiseProcess == 0) ? NOP() : \
  473.                 (InputType > 0)     ? clip : \
  474.                                       clip.QTGMC_Bob( 0,1.0 )
  475.     fullClip  = (yuy2 && NoiseTR > 0) ? fullClip.Interleaved2Planar() : fullClip
  476.     fullSuper = (NoiseTR > 0)         ? fullClip.MSuper( pel=SubPel, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise, planar=true ) : NOP() #TEST chroma OK?
  477.  
  478.     # Create a motion compensated temporal window around current frame and use to guide denoisers
  479.     noiseWindow = (NoiseProcess == 0) ? NOP() : \
  480.                   (!DenoiseMC)        ? fullClip : \
  481.                   (NoiseTR == 0)      ? fullClip : \
  482.                   (NoiseTR == 1)      ? Interleave( fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ), \
  483.                                                     fullClip, \
  484.                                                     fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) ) : \
  485.                                         Interleave( fullClip.MCompensate( fullSuper, fVec2, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ), \
  486.                                                     fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ), \
  487.                                                     fullClip, \
  488.                                                     fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ), \
  489.                                                     fullClip.MCompensate( fullSuper, bVec2, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) )
  490.     noiseWindow = (yuy2 && NoiseTR > 0) ? noiseWindow.Planar2Interleaved() : noiseWindow
  491.     dnWindow = (NoiseProcess == 0)      ? NOP() : \
  492.                (Denoiser == "dfttest")  ? noiseWindow.dfttest( Y=true, U=ChromaNoise, V=ChromaNoise, sigma=Sigma*4, tbsize=noiseTD, threads=DftThreads, lsb=lsbd ) : \
  493.                                           noiseWindow.FFT3DFilter( plane=(ChromaNoise ? 4 : 0), sigma=Sigma, bt=noiseTD )
  494.     dnwindow = (Denoiser == "dfttest") && lsbd ? isyuy2(Input) ? dnWindow.ConvertToYv16.ditherpost(mode=6, U=ChromaNoise?3:2, V=ChromaNoise?3:2, slice=false).ConvertToYUY2 : dnWindow.ditherpost(mode=6, U=ChromaNoise?3:2, V=ChromaNoise?3:2, slice=false) : dnWindow
  495.  
  496.     # Rework denoised clip to match source format - various code paths here: discard the motion compensation window, discard doubled lines (from point resize)
  497.     # Also reweave to get interlaced noise if source was interlaced (could keep the full frame of noise, but it will be poor quality from the point resize)
  498.     denoised = (NoiseProcess == 0) ? NOP() : \
  499.                (!DenoiseMC)        ? ((InputType > 0) ? dnWindow : dnWindow.SeparateFields().SelectEvery( 4, 0,3 ).Weave()) : \
  500.                (InputType > 0)     ? ((NoiseTR == 0)  ? dnWindow : dnWindow.SelectEvery( noiseTD, NoiseTR )) : \
  501.                                      dnWindow.SeparateFields().SelectEvery( noiseTD*4, NoiseTR*2,NoiseTR*6+3 ).Weave()
  502.  
  503.     # >>>> Switch to planar YUY2 for noise bypass
  504.  
  505.     CNmt1   = ChromaNoise ? 3 : 1
  506.     CNmt2   = ChromaNoise ? 3 : 2
  507.     CNmt128 = ChromaNoise ? 3 : -128
  508.  
  509.     # Get actual noise from difference. Then 'deinterlace' where we have weaved noise - create the missing lines of noise in various ways
  510.     planarDenoised = (NoiseProcess == 0) ? NOP() : yuy2 ? denoised.Interleaved2Planar() : denoised
  511.     noise = (totalRestore > 0.0)  ? Isyuy2(planarClip) ? mt_makediff( planarClip.planar2interleaved.ConvertToYV16, isclip(planarDenoised) ? planarDenoised.planar2interleaved.ConvertToYV16 : planarDenoised, U=CNmt1,V=CNmt1 ).ConvertToYuy2.interleaved2planar : \
  512.     mt_makediff( planarClip, planarDenoised, U=CNmt1,V=CNmt1 ) : NOP()
  513.     deintNoise = (NoiseProcess == 0 || totalRestore == 0.0) ? NOP() : \
  514.                  (InputType != 0)                           ? noise : \
  515.                  (NoiseDeint == "Bob")                      ? noise.QTGMC_Bob( 0,0.5 ) : \
  516.                  (NoiseDeint == "Generate")                 ? noise.QTGMC_Generate2ndFieldNoise( denoised, ChromaNoise ) : \
  517.                                                               noise.DoubleWeave()
  518.     # Motion-compensated stabilization of generated noise
  519.     noiseSuper = (StabilizeNoise) ? deintNoise.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise, planar=true ) : NOP()
  520.     mcNoise    = (StabilizeNoise) ? deintNoise.MCompensate( noiseSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) : NOP()
  521.     finalNoise = (StabilizeNoise) ? isclip(deintNoise) && isyuy2(deintNoise) ? mt_lutxy( deintNoise.planar2interleaved.ConvertToYV16, mcNoise.planar2interleaved.ConvertToYV16, \
  522.     "x 128 - abs y 128 - abs > x y ? 0.6 * x y + 0.2 * +", U=CNmt1,V=CNmt1 ).ConvertToYuy2.interleaved2planar : isclip(mcNoise) && isyuy2(mcNoise) ? mt_lutxy( deintNoise, mcNoise.planar2interleaved.ConvertToYV16, "x 128 - abs y 128 - abs > x y ? 0.6 * x y + 0.2 * +", U=CNmt1,V=CNmt1 ).ConvertToYuy2.interleaved2planar : \
  523.     mt_lutxy( deintNoise, mcNoise, "x 128 - abs y 128 - abs > x y ? 0.6 * x y + 0.2 * +", U=CNmt1,V=CNmt1 ) : deintNoise
  524.  
  525.     # If NoiseProcess=1 denoise input clip. If NoiseProcess=2 leave noise in the clip and let the temporal blurs "denoise" it for a stronger effect
  526.     innerClip = (NoiseProcess == 1) ? denoised : clip
  527.  
  528.  
  529.     #---------------------------------------
  530.     # Interpolation
  531.  
  532.     # >>>> Interleaved YUY2 for interpolation
  533.  
  534.     # Support badly deinterlaced progressive content - drop half the fields and reweave to get 1/2fps interlaced stream appropriate for QTGMC processing
  535.     ediInput = (InputType == 2 || InputType == 3) ? innerClip.SeparateFields().SelectEvery(4,0,3).Weave() : innerClip
  536.  
  537.     # Create interpolated image as starting point for output
  538.     edi1 = defined(EdiExt) ? EdiExt.PointResize( w,h, 0,(EdiExt.Height()-h)/2, -0,h+epsilon ) : \
  539.                              QTGMC_Interpolate( ediInput, InputType, EdiMode, NNSize, NNeurons, EdiQual, EdiMaxD, EdiThreads, \
  540.                                                 yuy2 ? clip.QTGMC_Bob( 0,0.5 ) : bobbed, ChromaEdi )
  541.  
  542.     # >>>> Switch to planar YUY2 during next step - remains planar until very end of script except blurring for back blending & SVThin
  543.  
  544.     # InputType=2,3: use motion mask to blend luma between original clip & reweaved clip based on ProgSADMask setting. Use chroma from original clip in any case
  545.     inputTypeBlend = (ProgSADMask > 0.0) ? MMask( srchClip, bVec1, kind=1, ml=ProgSADMask, planar=true ) : NOP()
  546.     edi = (InputType != 2 && InputType != 3) ? (!yuy2 ? edi1 : edi1.Interleaved2Planar()) :\
  547.           (ProgSADMask <= 0.0)               ? (!yuy2 ? edi1.MergeChroma( innerClip ) : edi1.MergeChroma( innerClip ).Interleaved2Planar()) : \
  548.                                                (!yuy2 ? mt_merge( innerClip, edi1, inputTypeBlend, U=2,V=2 ) : \
  549.                                                         mt_merge( innerClip.ConvertToYV16, edi1.ConvertToYV16, inputTypeBlend, U=2,V=2 ).ConvertToYuy2.interleaved2planar)
  550.  
  551.     # Get the max/min value for each pixel over neighboring motion-compensated frames - used for temporal sharpness limiting
  552.     ediSuper = (TR1 > 0 || temporalSL)   ? edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, planar=true ) : NOP()
  553.     bComp1   = (temporalSL)              ? edi.MCompensate( ediSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) : NOP()
  554.     fComp1   = (temporalSL)              ? edi.MCompensate( ediSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) : NOP()
  555.     tMax     = (temporalSL)              ? isyuy2(edi) ? edi.planar2interleaved.ConvertToYV16.mt_logic( isclip(fComp1) ? fComp1.planar2interleaved.ConvertToYV16 : fComp1, "max", \
  556.     U=3,V=3 ).mt_logic( isclip(bComp1) ? bComp1.planar2interleaved.ConvertToYV16 : bComp1, "max", U=3,V=3 ).ConvertToYuy2.interleaved2planar : edi.mt_logic( fComp1, "max", U=3,V=3 ).mt_logic( bComp1, "max", U=3,V=3 )    : NOP()
  557.     tMin     = (temporalSL)              ? isyuy2(edi) ? edi.planar2interleaved.ConvertToYV16.mt_logic( isclip(fComp1) ? fComp1.planar2interleaved.ConvertToYV16 : fComp1, "min", \
  558.     U=3,V=3 ).mt_logic( isclip(bComp1) ? bComp1.planar2interleaved.ConvertToYV16 : bComp1, "min", U=3,V=3 ).ConvertToYuy2.interleaved2planar : edi.mt_logic( fComp1, "min", U=3,V=3 ).mt_logic( bComp1, "min", U=3,V=3 )    : NOP()
  559.     bComp3   = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, bVec3, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) : NOP()
  560.     fComp3   = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, fVec3, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) : NOP()
  561.     tMax     = (SLRad > 1 && temporalSL) ? isyuy2(tMax) ? tMax.planar2interleaved.ConvertToYV16.mt_logic( isclip(fComp3) ? fComp3.planar2interleaved.ConvertToYV16 : fComp3, "max", \
  562.     U=3,V=3 ).mt_logic( isclip(bComp3) ? bComp3.planar2interleaved.ConvertToYV16 : bComp3, "max", U=3,V=3 ).ConvertToYuy2.interleaved2planar : tMax.mt_logic( fComp3, "max", U=3,V=3 ).mt_logic( bComp3, "max", U=3,V=3 )   : tMax
  563.     tMin     = (SLRad > 1 && temporalSL) ? isyuy2(tMin) ? tMin.planar2interleaved.ConvertToYV16.mt_logic( isclip(fComp3) ? fComp3.planar2interleaved.ConvertToYV16 : fComp3, "min", \
  564.     U=3,V=3 ).mt_logic( isclip(bComp3) ? bComp3.planar2interleaved.ConvertToYV16 : bComp3, "min", U=3,V=3 ).ConvertToYuy2.interleaved2planar : tMin.mt_logic( fComp3, "min", U=3,V=3 ).mt_logic( bComp3, "min", U=3,V=3 )   : tMin
  565.  
  566.  
  567.     #---------------------------------------
  568.     # Create basic output
  569.  
  570.     # Use motion vectors to blur interpolated image (edi) with motion-compensated previous and next frames. As above, this is done to remove shimmer from
  571.     # alternate frames so the same binomial kernels are used. However, by using motion-compensated smoothing this time we avoid motion blur. The use of
  572.     # MDegrain1 (motion compensated) rather than TemporalSmooth makes the weightings *look* different, but they evaluate to the same values
  573.     # Create linear weightings of neighbors first                                                                                             -2    -1     0    1     2
  574.     degrain1 = (TR1 > 0) ? edi.MDegrain1( ediSuper, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb) : NOP()  # 0.00  0.33  0.33  0.33  0.00
  575.     degrain2 = (TR1 > 1) ? edi.MDegrain1( ediSuper, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb) : NOP()  # 0.33  0.00  0.33  0.00  0.33
  576.     degrain1 = (TR1 > 0) && lsb ? isyuy2(Input) ? degrain1.planar2interleaved.ConvertToYV16.ditherpost(mode=6, slice=false).ConvertToYuy2.interleaved2planar : degrain1.ditherpost(mode=6, slice=false) : degrain1
  577.     degrain2 = (TR1 > 1) && lsb ? isyuy2(Input) ? degrain2.planar2interleaved.ConvertToYV16.ditherpost(mode=6, slice=false).ConvertToYuy2.interleaved2planar : degrain2.ditherpost(mode=6, slice=false) : degrain2
  578.  
  579.     # Combine linear weightings to give binomial weightings - TR1=0: (1), TR1=1: (1:2:1), TR1=2: (1:4:6:4:1)
  580.     binomial1 = (TR1 == 0) ? edi : \
  581.                 (TR1 == 1) ? degrain1.Merge( edi, 0.25 ) : \
  582.                              degrain1.Merge( degrain2, 0.2 ).Merge( edi, 0.0625 )
  583.  
  584.     # Remove areas of difference between smoothed image and interpolated image that are not bob-shimmer fixes: repairs residual motion blur from temporal smooth
  585.     repair1 = (Rep1 == 0) ? binomial1 : binomial1.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep1, RepChroma )
  586.  
  587.     # Apply source match - use difference between output and source to succesively refine output [extracted to function to clarify main code path]
  588.     match = (SourceMatch == 0) ? repair1 : \
  589.                                  repair1.QTGMC_ApplySourceMatch( InputType, ediInput, bVec1,fVec1, bVec2,fVec2, SubPel, SubPelInterp, hpad, vpad, \
  590.                                                                  ThSAD1, ThSCD1, ThSCD2, SourceMatch, MatchTR1, MatchEdi, MatchNNSize, MatchNNeurons, \
  591.                                                                  MatchEdiQual, MatchEdiMaxD, MatchTR2, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, \
  592.                                                                  MatchEdiMaxD2, MatchEnhance, EdiThreads, lsb )
  593.  
  594.     # Lossless=2 - after preparing an interpolated, de-shimmered clip, restore the original source fields into it and clean up any artefacts.
  595.     # This mode will not give a true lossless result because the resharpening and final temporal smooth are still to come, but it will add further detail.
  596.     # However, it can introduce minor combing. This setting is best used together with source-match (it's effectively the final source-match stage).
  597.     lossed1 = (Lossless == 2) ? QTGMC_MakeLossless( match, innerClip, InputType ) : match
  598.  
  599.  
  600.     #---------------------------------------
  601.     # Resharpen / retouch output
  602.  
  603.     # Resharpen to counteract temporal blurs. Little sharpening needed for source-match mode since it has already recovered sharpness from source
  604.     vresharp1 = (SMode == 2) ? isyuy2(lossed1) ? Merge( lossed1.planar2interleaved.ConvertToYV16.mt_expand( mode="vertical", U=3,V=3 ), \
  605.     lossed1.planar2interleaved.ConvertToYV16.mt_inpand( mode="vertical", U=3,V=3 ) ).ConvertToYuy2.interleaved2planar : \
  606.     Merge( lossed1.mt_expand( mode="vertical", U=3,V=3 ), lossed1.mt_inpand( mode="vertical", U=3,V=3 ) ) : NOP()
  607.     vresharp  = (Precise && SMode == 2) ? isclip(vresharp1) && isyuy2(vresharp1) ? vresharp1.planar2interleaved.ConvertToYV16.mt_lutxy( lossed1.planar2interleaved.ConvertToYV16, \
  608.     "x y < x 1 + x y > x 1 - x ? ?", U=3,V=3 ).ConvertToYuy2.interleaved2planar : vresharp1.mt_lutxy( lossed1, "x y < x 1 + x y > x 1 - x ? ?", U=3,V=3 ) : vresharp1 # Precise mode: reduce tiny overshoot
  609.     resharp   = (SMode == 0) ? lossed1 : \
  610.                 (SMode == 1) ? isyuy2(lossed1) ? lossed1.planar2interleaved.ConvertToYV16.mt_lutxy( lossed1.RemoveGrain( rgBlur, planar=true ).planar2interleaved.ConvertToYV16,  \
  611.     "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 ).ConvertToYuy2.interleaved2planar : lossed1.mt_lutxy( lossed1.RemoveGrain( rgBlur, planar=true ),  "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 ) : \
  612.                                isyuy2(lossed1) ? lossed1.planar2interleaved.ConvertToYV16.mt_lutxy( vresharp.RemoveGrain( rgBlur, planar=true ).planar2interleaved.ConvertToYV16, \
  613.     "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 ).ConvertToYuy2.interleaved2planar : lossed1.mt_lutxy( vresharp.RemoveGrain( rgBlur, planar=true ), "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 )
  614.  
  615.     # Slightly thin down 1-pixel high horizontal edges that have been widened into neigboring field lines by the interpolator
  616.     SVThinSc = SVThin * 6.0
  617.     vertMedD = (SVthin > 0.0) ? isyuy2(lossed1) ? mt_lutxy( lossed1.planar2interleaved.ConvertToYV16, lossed1.VerticalCleaner( mode=1, modeU=-1, modeV=-1, planar=true ).planar2interleaved.ConvertToYV16, \
  618.     "y x - " + string(SVThinSc) + " * 128 +", U=1,V=1 ).ConvertToYuy2.interleaved2planar : mt_lutxy( lossed1, lossed1.VerticalCleaner( mode=1, modeU=-1, modeV=-1, planar=true ), "y x - " + string(SVThinSc) + " * 128 +", U=1,V=1 ) : NOP()
  619.     vertMedD = (SVthin > 0.0) ? (!yuy2 ? vertMedD.Blur( 1,0 ) : vertMedD.Planar2Interleaved().Blur( 1,0 ).Interleaved2Planar()) : NOP()
  620.     neighborD = (SVthin > 0.0) ? isclip(vertMedD) && isyuy2(vertMedD) ? mt_lutxy( vertMedD.planar2interleaved.ConvertToYV16, vertMedD.RemoveGrain( rgBlur,-1, planar=true ).planar2interleaved.ConvertToYV16, \
  621.     "y 128 - abs x 128 - abs > y 128 ?" ).ConvertToYuy2.interleaved2planar : mt_lutxy( vertMedD, vertMedD.RemoveGrain( rgBlur,-1, planar=true ), "y 128 - abs x 128 - abs > y 128 ?" ) : NOP()
  622.     thin      = (SVthin > 0.0) ? isclip(resharp) && isyuy2(resharp) ? resharp.planar2interleaved.ConvertToYV16.mt_adddiff( isclip(neighborD) ? neighborD.planar2interleaved.ConvertToYV16 : neighborD, U=2,V=2 ).ConvertToYuy2.interleaved2planar : resharp.mt_adddiff( neighborD, U=2,V=2 ) : resharp
  623.  
  624.     # Back blend the blurred difference between sharpened & unsharpened clip, before (1st) sharpness limiting (Sbb == 1,3). A small fidelity improvement
  625.     backBlend1 = (Sbb != 1 && Sbb != 3) ? thin : \
  626.                  !yuy2 ? thin.mt_makediff( mt_makediff( thin, lossed1, U=1,V=1 ).RemoveGrain( 12, -1, planar=true ) \
  627.                              .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 ) : \
  628.                          thin.planar2interleaved.ConvertToYV16.mt_makediff( mt_makediff( thin.planar2interleaved.ConvertToYV16, lossed1.planar2interleaved.ConvertToYV16, U=1,V=1 ).ConvertToYuy2.interleaved2planar.RemoveGrain( 12, -1, planar=true ) \
  629.                              .Planar2Interleaved().GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ).ConvertToYV16, U=2,V=2 ).ConvertToYuy2.Interleaved2Planar()
  630.  
  631.     # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  632.     # Occurs here (before final temporal smooth) if SLMode == 1,2. This location will restrict sharpness more, but any artefacts introduced will be smoothed
  633.     sharpLimit1 = (SLMode == 1) ? backBlend1.Repair( ((SLrad <= 1) ? edi : backBlend1.Repair( edi, 12, planar=true )), 1, planar=true ) : \
  634.                   (SLMode == 2) ? isyuy2(backBlend1) ? backBlend1.planar2interleaved.ConvertToYV16.mt_clamp( tMax.planar2interleaved.ConvertToYV16,tMin.planar2interleaved.ConvertToYV16, Sovs,Sovs, U=3,V=3 ).ConvertToYuy2.interleaved2planar : backBlend1.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  635.                                   backBlend1
  636.  
  637.     # Back blend the blurred difference between sharpened & unsharpened clip, after (1st) sharpness limiting (Sbb == 2,3). A small fidelity improvement
  638.     backBlend2 = (Sbb < 2) ? sharpLimit1 : \
  639.                  !yuy2     ? sharpLimit1.mt_makediff( mt_makediff( sharpLimit1, lossed1, U=1,V=1 ).RemoveGrain( 12, -1, planar=true ) \
  640.                                         .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 ) : \
  641.                              sharpLimit1.planar2interleaved.ConvertToYV16.mt_makediff( mt_makediff( sharpLimit1.planar2interleaved.ConvertToYV16, lossed1.planar2interleaved.ConvertToYV16, U=1,V=1 ).ConvertToYuy2.interleaved2planar.RemoveGrain( 12, -1, planar=true ) \
  642.                                         .Planar2Interleaved().GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ).ConvertToYV16, U=2,V=2 ).ConvertToYuy2.Interleaved2Planar()
  643.  
  644.     # Add back any extracted noise, prior to final temporal smooth - this will restore detail that was removed as "noise" without restoring the noise itself
  645.     # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  646.     addNoise1 = (GrainRestore <= 0.0) ? backBlend2 : \
  647.         isyuy2(backBlend2) ? backBlend2.planar2interleaved.ConvertToYV16.mt_adddiff( finalNoise.planar2interleaved.ConvertToYV16.mt_lut( "x " + noiseCentre + " - " + string(GrainRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 ).ConvertToYuy2.interleaved2planar : \
  648.         backBlend2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " - " + string(GrainRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  649.  
  650.     # Final light linear temporal smooth for denoising
  651.     stableSuper = (TR2 > 0) ? addNoise1.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, planar=true ) : NOP()
  652.     stable  = (TR2 == 0) ? addNoise1 : \
  653.               (TR2 == 1) ? addNoise1.MDegrain1( stableSuper, bVec1,fVec1,                           thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : \
  654.               (TR2 == 2) ? addNoise1.MDegrain2( stableSuper, bVec1,fVec1, bVec2,fVec2,              thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : \
  655.                            addNoise1.MDegrain3( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb )
  656.     stable  = (TR2 > 0) && lsb ? isyuy2(Input) ? stable.planar2interleaved.ConvertToYV16.ditherpost(mode=6, slice=false).ConvertToYuy2.Interleaved2Planar() : stable.ditherpost(mode=6, slice=false) : stable
  657.  
  658.     # Remove areas of difference between final output & basic interpolated image that are not bob-shimmer fixes: repairs motion blur caused by temporal smooth
  659.     repair2 = (Rep2 == 0) ? stable : stable.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep2, RepChroma )
  660.  
  661.     # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  662.     # Occurs here (after final temporal smooth) if SLMode == 3,4. Allows more sharpening here, but more prone to introducing minor artefacts
  663.     sharpLimit2 = (SLMode == 3) ? repair2.Repair( ((SLrad <= 1) ? edi : repair2.Repair( edi, 12, planar=true )), 1, planar=true ) : \
  664.                   (SLMode == 4) ? isyuy2(repair2) ? repair2.planar2interleaved.ConvertToYV16.mt_clamp( tMax.planar2interleaved.ConvertToYV16,tMin.planar2interleaved.ConvertToYV16, Sovs,Sovs, U=3,V=3 ).ConvertToYuy2.interleaved2planar : repair2.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  665.                                   repair2
  666.  
  667.     # Lossless=1 - inject source fields into result and clean up inevitable artefacts. Provided NoiseRestore=0.0 or 1.0, this mode will make the script result
  668.     # properly lossless, but this will retain source artefacts and cause some combing (where the smoothed deinterlace doesn't quite match the source)
  669.     lossed2 = (Lossless == 1) ? QTGMC_MakeLossless( sharpLimit2, innerClip, InputType ) : sharpLimit2
  670.  
  671.     # Add back any extracted noise, after final temporal smooth. This will appear as noise/grain in the output
  672.     # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  673.     addNoise2 = (NoiseRestore <= 0.0) ? lossed2 : \
  674.         isyuy2(lossed2) ? lossed2.planar2interleaved.ConvertToYV16.mt_adddiff( finalNoise.planar2interleaved.ConvertToYV16.mt_lut( "x " + noiseCentre + " - " + string(NoiseRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 ).ConvertToYuy2.interleaved2planar : \
  675.         lossed2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " - " + string(NoiseRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  676.  
  677.  
  678.     #---------------------------------------
  679.     # Post-Processing
  680.  
  681.     # Shutter motion blur - get level of blur depending on output framerate and blur already in source
  682.     blurLevel = (ShutterAngleOut * FPSDivisor - ShutterAngleSrc) * 100.0 / 360.0
  683.     Assert( blurLevel >= 0, "Cannot reduce motion blur already in source: increase ShutterAngleOut or FPSDivisor" )
  684.     Assert( blurLevel <= 200, "Exceeded maximum motion blur level: decrease ShutterAngleOut or FPSDivisor" )
  685.  
  686.     # ShutterBlur mode 2,3 - get finer resolution motion vectors to reduce blur "bleeding" into static areas
  687.     rBlockDivide = Select( ShutterBlur, 1, 1, 2, 4 )
  688.     rBlockSize = BlockSize / rBlockDivide
  689.     rOverlap   = Overlap   / rBlockDivide
  690.     rBlockSize = (rBlockSize < 4) ? 4 : rBlockSize
  691.     rOverlap   = (rOverlap   < 2) ? 2 : rOverlap
  692.     rBlockDivide = BlockSize / rBlockSize
  693.     rLambda = Lambda / (rBlockDivide * rBlockDivide)
  694.     sbBVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( bVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  695.                                                           truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : bVec1
  696.     sbFVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( fVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  697.                                                           truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : fVec1
  698.  
  699.     # Shutter motion blur - use MFlowBlur to blur along motion vectors
  700.     sblurSuper = (ShutterBlur > 0) ? addNoise2.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, planar=true ) : NOP()
  701.     sblur =      (ShutterBlur > 0) ? addNoise2.MFlowBlur( sblurSuper, sbBVec1, sbFVec1, blur=blurLevel, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) : NOP()
  702.  
  703.     # Shutter motion blur - use motion mask to reduce blurring in areas of low motion - also helps reduce blur "bleeding" into static areas, then select blur type
  704.     sbMotionMask = (ShutterBlur > 0 && SBlurLimit > 0) ? MMask( srchClip, bVec1, kind=0, ml=SBlurLimit, planar=true ) : NOP()
  705.     sblurred     = (ShutterBlur == 0) ? addNoise2 : \
  706.                    (SBlurLimit == 0)  ? sblur : \
  707.                                         isyuy2(addNoise2) ? mt_merge( addNoise2.planar2interleaved.ConvertToYV16, isclip(sblur) ? sblur.planar2interleaved.ConvertToYV16 : sblur, sbMotionMask.planar2interleaved.ConvertToYV16, U=3,V=3 ).ConvertToYuy2.interleaved2planar : \
  708.                                         mt_merge( addNoise2, sblur, sbMotionMask, U=3,V=3 )
  709.     # Reduce frame rate
  710.     decimated = (FPSDivisor != 1) ? sblurred.SelectEvery( FPSDivisor, 0 ) : sblurred
  711.  
  712.     # Crop off temporary vertical padding
  713.     cropped = Border ? decimated.Crop( 0, 4, -0, -4 ) : decimated
  714.     h = Border ? h-8 : h
  715.  
  716.     # Show output of choice + settings
  717.     # >>>> Restore YUY2 to interleaved
  718.     output = (ShowNoise == 0.0) ? cropped : isyuy2(finalNoise) ? finalNoise.planar2interleaved.ConvertToYV16.mt_lut( "x 128 - " + string(ShowNoise) + " * 128 +", U=CNmt128,V=CNmt128 ).ConvertToYuy2.interleaved2planar : \
  719.     finalNoise.mt_lut( "x 128 - " + string(ShowNoise) + " * 128 +", U=CNmt128,V=CNmt128 )
  720.     output = yuy2 ? output.Planar2Interleaved() : output
  721.     return (ShowSettings == false) ? output : \
  722.         output.Subtitle( "TR0=" + string(TR0) + " | TR1=" + string(TR1) + " | TR2=" + string(TR2) + " | Rep0=" + string(Rep0) + " | Rep1=" + string(Rep1) + \
  723.         " | Rep2=" + string(Rep2) + " | RepChroma=" + string(RepChroma) + "\nEdiMode='" + EdiMode + "' | NNSize=" + string(NNSize) + " | NNeurons=" + \
  724.         string(NNeurons) + " | EdiQual=" + string(EdiQual) + " | EdiMaxD=" + string(EdiMaxD) + " | ChromaEdi='" + ChromaEdi + "' | EdiThreads=" + \
  725.         string(EdiThreads) + "\nSharpness=" + string(Sharpness, "%.2f") + " | SMode=" + string(SMode) + " | SLMode=" + string(SLMode) + " | SLRad=" + \
  726.         string(SLRad) + " | SOvs=" + string(SOvs) + " | SVThin=" + string(SVThin, "%.2f") + " | Sbb=" + string(Sbb) + "\nSrchClipPP=" + string(SrchClipPP) + \
  727.         " | SubPel=" + string(SubPel) + " | SubPelInterp=" + string(SubPelInterp) + " | BlockSize=" + string(BlockSize) + " | Overlap=" + string(Overlap) + \
  728.         "\nSearch=" + string(Search) + " | SearchParam=" + string(SearchParam) + " | PelSearch=" + string(PelSearch) + " | ChromaMotion=" + \
  729.         string(ChromaMotion) + " | TrueMotion=" + string(TrueMotion) + "\nLambda=" + string(Lambda) + " | LSAD=" + string(LSAD) + " | PNew=" + string(PNew) + \
  730.         " | PLevel=" + string(PLevel) + " | GlobalMotion=" + string(GlobalMotion) + " | DCT=" + string(DCT) + "\nThSAD1=" + string(ThSAD1) + " | ThSAD2=" + \
  731.         string(ThSAD2) + " | ThSCD1=" + string(ThSCD1) + " | ThSCD2=" + string(ThSCD2) + "\nSourceMatch=" + string(SourceMatch) + " | MatchPreset='" + \
  732.         MatchPreset + "' | MatchEdi='" + MatchEdi + "'\nMatchPreset2='" + MatchPreset2 + "' | MatchEdi2='" + MatchEdi2 + "' | MatchTR2=" + string(MatchTR2) + \
  733.         " | MatchEnhance=" + string(MatchEnhance, "%.2f") + " | Lossless=" + string(Lossless) + "\nNoiseProcess=" + string(NoiseProcess) + " | Denoiser='" + \
  734.         Denoiser + "' | DftThreads=" + string(DftThreads) + " | DenoiseMC=" + string(DenoiseMC) + " | NoiseTR=" + string(NoiseTR) + " | Sigma=" + \
  735.         string(Sigma, "%.2f") + "\nChromaNoise=" + string(ChromaNoise) + " | ShowNoise=" + string(ShowNoise, "%.2f") + " | GrainRestore=" + \
  736.         string(GrainRestore, "%.2f") + " | NoiseRestore=" + string(NoiseRestore, "%.2f") + "\nNoiseDeint='" + NoiseDeint + "' | StabilizeNoise=" + \
  737.         string(StabilizeNoise) + " | InputType=" + string(InputType) + " | ProgSADMask=" + string(ProgSADMask, "%.2f") + "\nFPSDivisor=" + \
  738.         string(FPSDivisor) + " | ShutterBlur=" + string(ShutterBlur) + " | ShutterAngleSrc=" + string(ShutterAngleSrc, "%.2f") + " | ShutterAngleOut=" + \
  739.         string(ShutterAngleOut, "%.2f") + " | SBlurLimit=" + string(SBlurLimit) + "\nBorder=" + string(Border) + " | Precise=" + string(Precise) + \
  740.         "\nPreset='" + Preset + "' | Tuning='" + Tuning + "' | GlobalNames='" + GlobalNames + "' | PrevGlobals='" + PrevGlobals + "' | ForceTR=" + \
  741.         string(ForceTR), font="Lucida Console", size=11, lsp=12 )
  742. }
  743.  
  744.  
  745. #---------------------------------------
  746. # Helpers
  747.  
  748. # Same as Bob, but keeps the field order the same.
  749. function QTGMC_Bob(clip cp, float "b", float "c", int "height" )
  750. {
  751.   h = Default(height, cp.Height)
  752.   w = cp.Width
  753.   shift = GetParity(cp) ? 0.25 : -0.25
  754.  
  755.   yv12c = IsYV12(cp) ? true : false
  756.  
  757.   yv12c ? cp.SeparateFields() : nop()
  758.  
  759.   oeven=yv12c ? SelectEven() : nop()
  760.   oodd=yv12c ? SelectOdd() : nop()
  761.  
  762.   even=yv12c ? oeven.ConvertToY8.BicubicResize(w, h, b, c, 0, shift, w, Height()).AssumeFrameBased() : nop()
  763.   odd=yv12c ? oodd.ConvertToY8.BicubicResize(w, h, b, c, 0, -shift, w, Height()).AssumeFrameBased() : nop()
  764.  
  765.   evenChr=yv12c ? Interleave(oeven.UToY8, oeven.VToY8).BicubicResize(w/2, h/2, b, c, 0, shift, w/2, Height()/2).AssumeFrameBased() : nop()
  766.   oddChr=yv12c ? Interleave(oodd.UToY8, oodd.VToY8).BicubicResize(w/2, h/2, b, c, 0, -shift, w/2, Height()/2).AssumeFrameBased() : nop()
  767.  
  768.   yv12c ? YToUV(Interleave(evenChr.SelectEven(), oddChr.SelectEven()),Interleave(evenChr.SelectOdd(), oddChr.SelectOdd()),Interleave(even, odd)) : cp.Bob( b,c, h )
  769.   GetParity(cp) ? AssumeTFF() : AssumeBFF()
  770. }
  771.  
  772.  
  773. # Interpolate input clip using method given in EdiMode. Use Fallback or Bob as result if mode not in list. If ChromaEdi string if set then interpolate chroma
  774. # separately with that method (only really useful for EEDIx). The function is used as main algorithm starting point and for first two source-match stages
  775. function QTGMC_Interpolate( clip Input, int InputType, string EdiMode, int NNSize, int NNeurons, int EdiQual, int EdiMaxD, int EdiThreads, clip "Fallback", \
  776.                             string "ChromaEdi" )
  777. {
  778.     # >>>> YUY2 is interleaved here
  779.  
  780.     ChromaEdi = default( ChromaEdi, "" )
  781.     CEed = (ChromaEdi == "")
  782.  
  783.     interp = (InputType == 1)            ? Input : \
  784.              (EdiMode == "NNEDI3")       ? Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  785.              (EdiMode == "NNEDI2")       ? Input.NNEDI2( field=-2, nsize=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  786.              (EdiMode == "NNEDI")        ? Input.NNEDI( field=-2, U=CEed,V=CEed ) : \
  787.              (EdiMode == "EEDI3+NNEDI3") ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed, \
  788.                                                         sclip=Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) ) : \
  789.              (EdiMode == "EEDI3")        ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed ) : \
  790.              (EdiMode == "EEDI2")        ? Input.SeparateFields().EEDI2( field=-2, maxd=EdiMaxD ) : \
  791.              (EdiMode == "Yadif")        ? Input.Yadif( mode=3 ) : \
  792.              (EdiMode == "TDeint")       ? Input.TDeInt( mode=1 ) : \
  793.              (EdiMode == "RepYadif")     ? Repair( Input.Yadif( mode=3 ), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ), 2, 0 ) : \
  794.                                            default( Fallback, Input.QTGMC_Bob( 0,0.5 ) )
  795.  
  796.     interpuv = (InputType == 1)        ? NOP() : \
  797.                (ChromaEdi == "NNEDI3") ? Input.NNEDI3( field=-2, nsize=4, nns=0, qual=1, threads=EdiThreads, Y=false ) : \
  798.                (ChromaEdi == "Yadif")  ? Input.Yadif( mode=3 ) : \
  799.                (ChromaEdi == "Bob")    ? Input.QTGMC_Bob( 0,0.5 ) : \
  800.                                          NOP()
  801.  
  802.     return (!IsClip(interpuv)) ? interp : interp.MergeChroma( interpuv )
  803. }
  804.  
  805. # Helper function: Compare processed clip with reference clip: only allow thin, horizontal areas of difference, i.e. bob shimmer fixes
  806. # Rough algorithm: Get difference, deflate vertically by a couple of pixels or so, then inflate again. Thin regions will be removed
  807. #                  by this process. Restore remaining areas of difference back to as they were in reference clip.
  808. function QTGMC_KeepOnlyBobShimmerFixes( clip Input, clip Ref, int Rep, bool Chroma )
  809. {
  810.     # >>>> YUY2 is planar here
  811.  
  812.     # ed is the erosion distance - how much to deflate then reflate to remove thin areas of interest: 0 = minimum to 5 = maximum
  813.     # od is over-dilation level  - extra inflation to ensure areas to restore back are fully caught:  0 = none to 3 = one full pixel
  814.     # If Rep < 10, then ed = Rep and od = 0, otherwise ed = 10s digit and od = 1s digit (nasty method, but kept for compatibility with original TGMC)
  815.     Rep    = default( Rep,    1    )
  816.     Chroma = default( Chroma, true )
  817.     ed = (Rep < 10) ? Rep : Rep / 10
  818.     od = (Rep < 10) ? 0   : Rep % 10
  819.     RCrg  = Chroma ? 3 : 1
  820.     RCrgo = Chroma ? 3 : 2
  821.  
  822.     diff = mt_makediff(Isyuy2(Ref) ? Ref.planar2interleaved.ConvertToYV16 : Ref, Isyuy2(Input) ? Input.planar2interleaved.ConvertToYV16 : Input, U=3,V=3 )
  823.  
  824.     # Areas of positive difference                                                                # ed = 0 1 2 3 4 5 6 7
  825.     choke1 =                        diff.  mt_inpand( mode="vertical", U=RCrg,V=RCrg )            #      x x x x x x x x    1 pixel   \
  826.     choke1 = (ed > 2)             ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . x x x x x    1 pixel    |  Deflate to remove thin areas
  827.     choke1 = (ed > 5)             ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . . . . x x    1 pixel   /
  828.     choke1 = (ed % 3 != 0)        ? choke1.mt_deflate( U=RCrg,V=RCrg )                 : choke1   #      . x x . x x . x    A bit more deflate & some horizonal effect
  829.     choke1 = Isyv16(choke1) && Isyuy2(Input) ? choke1.ConvertToYuy2.interleaved2planar : choke1
  830.     choke1 = (ed == 2 || ed == 5) ? choke1.RemoveGrain( 4, planar=true )               : choke1   #      . . x . . x . .    Local median
  831.                                                                                                                      
  832.     choke1 = Isyuy2(choke1) ? choke1.planar2interleaved.ConvertToYV16 : choke1
  833.     choke1 =                        choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg )            #      x x x x x x x x    1 pixel  \
  834.     choke1 = (ed > 1)             ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . x x x x x x    1 pixel   | Reflate again
  835.     choke1 = (ed > 4)             ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . . . x x x    1 pixel  /
  836.  
  837.     # Over-dilation - extra reflation up to about 1 pixel
  838.     choke1 = (od == 0)            ? choke1 : \
  839.              (od == 1)            ? choke1.mt_inflate( U=RCrg,V=RCrg ) : \
  840.              (od == 2)            ? choke1.mt_inflate( U=RCrg,V=RCrg ).mt_inflate( U=RCrg,V=RCrg ) : \
  841.                                     choke1.mt_expand ( U=RCrg,V=RCrg )
  842.  
  843.     # Areas of negative difference (similar to above)
  844.     choke2 =                        diff.  mt_expand( mode="vertical", U=RCrg,V=RCrg )        
  845.     choke2 = (ed > 2)             ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  846.     choke2 = (ed > 5)             ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  847.     choke2 = (ed % 3 != 0)        ? choke2.mt_inflate( U=RCrg,V=RCrg )                 : choke2
  848.     choke2 = Isyv16(choke2) && Isyuy2(Input) ? choke2.ConvertToYuy2.interleaved2planar : choke2
  849.     choke2 = (ed == 2 || ed == 5) ? choke2.RemoveGrain( 4, planar=true )               : choke2
  850.     choke2 = Isyuy2(choke2) ? choke2.planar2interleaved.ConvertToYV16 : choke2
  851.     choke2 =                        choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg )
  852.     choke2 = (ed > 1)             ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  853.     choke2 = (ed > 4)             ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  854.     choke2 = (od == 0)            ? choke2 : \
  855.              (od == 1)            ? choke2.mt_deflate( U=RCrg,V=RCrg )  : \
  856.              (od == 2)            ? choke2.mt_deflate( U=RCrg,V=RCrg ).mt_deflate( U=RCrg,V=RCrg ) : \
  857.                                     choke2.mt_inpand ( U=RCrg,V=RCrg )
  858.  
  859.     # Combine above areas to find those areas of difference to restore
  860.     restore = diff.mt_lutxy( choke1, "x 129 < x y 128 < 128 y ? ?", U=RCrg,V=RCrg ).mt_lutxy( choke2, "x 127 > x y 128 > 128 y ? ?", U=RCrg,V=RCrg )
  861.     fin4ret = Isyuy2(Input) ? Input.planar2interleaved.ConvertToYV16.mt_adddiff( restore, U=RCrgo,V=RCrgo ) : Input.mt_adddiff( restore, U=RCrgo,V=RCrgo )
  862.     return Isyuy2(Ref) ? fin4ret.ConvertToYuy2.interleaved2planar : fin4ret
  863. }
  864.  
  865.  
  866. # Given noise extracted from an interlaced source (i.e. the noise is interlaced), generate "progressive" noise with a new "field" of noise injected. The new
  867. # noise is centered on a weighted local average and uses the difference between local min & max as an estimate of local variance
  868. # YUY2 clip input is planar, but must pass interleaved version of clip to setup noise
  869. function QTGMC_Generate2ndFieldNoise( clip Input, clip InterleavedClip, bool "ChromaNoise" )
  870. {
  871.     # >>>> YUY2 is planar here. Noise is generated (AddGrainC) interleaved, but immediately made planar
  872.     ChromaNoise = default( ChromaNoise, false )
  873.     CNmt1 = ChromaNoise ? 3 : 1
  874.     origNoise = Input.SeparateFields()
  875.     origNoise = Isyuy2(origNoise) ? origNoise.planar2interleaved.ConvertToYV16 : origNoise
  876.     noiseMax  = origNoise.mt_expand( mode="square", U=CNmt1,V=CNmt1 ).mt_expand( mode="horizontal", U=CNmt1,V=CNmt1 )
  877.     noiseMin  = origNoise.mt_inpand( mode="square", U=CNmt1,V=CNmt1 ).mt_inpand( mode="horizontal", U=CNmt1,V=CNmt1 )
  878.     random    = BlankClip( InterleavedClip.SeparateFields(), color_yuv=$808080 ).AddGrainC( var=1800, uvar=ChromaNoise ? 1800 : 0 )
  879.     random    = InterleavedClip.IsYUY2() ? random.ConvertToYV16 : random
  880.     varRandom = mt_makediff( noiseMax, noiseMin, U=CNmt1,V=CNmt1 ).mt_lutxy( random, "x 128 - y * 256 / 128 +", U=CNmt1,V=CNmt1)
  881.     newNoise  = noiseMin.mt_adddiff( varRandom, U=CNmt1,V=CNmt1 )
  882.     return Isyuy2(origNoise) ? Interleave( origNoise, newNoise ).Weave().ConvertToYuy2.interleaved2planar : Interleave( origNoise, newNoise ).Weave()
  883. }
  884.  
  885.  
  886. # Insert the source lines into the result to create a true lossless output. However, the other lines in the result have had considerable processing and won't
  887. # exactly match source lines. There will be some slight residual combing. Use vertical medians to clean a little of this away
  888. function QTGMC_MakeLossless( clip Input, clip Source, int InputType )
  889. {
  890.     Assert( InputType != 1, "Lossless modes are incompatible with InputType=1" )
  891.  
  892.     # >>>> YUY2: 'Input' is planar, 'Source' is interleaved (changed to planar here for processing) - returns planar result
  893.  
  894.     # Weave the source fields and the "new" fields that have generated in the input
  895.     srcFields1 = (InputType == 0) ? Source.SeparateFields() : Source.SeparateFields().SelectEvery( 4, 0,3 )
  896.     srcFields  = Source.IsYUY2() ? srcFields1.Interleaved2Planar() : srcFields1
  897.     newFields  = Input.SeparateFields().SelectEvery( 4, 1,2 )
  898.     processed  = Interleave( srcFields, newFields ).SelectEvery(4, 0,1,3,2 ).Weave()
  899.  
  900.     # Clean some of the artefacts caused by the above - creating a second version of the "new" fields
  901.     vertMedian  = processed.VerticalCleaner( mode=1, planar=true )
  902.     vertMedDiff = mt_makediff( Isyuy2(processed) ? processed.planar2interleaved.ConvertToYV16 : \
  903.     processed, Isyuy2(vertMedian) ? vertMedian.planar2interleaved.ConvertToYV16 : vertMedian, U=3,V=3 )
  904.     vmNewDiff1  = vertMedDiff.SeparateFields().SelectEvery( 4, 1,2 )
  905.     vmNewDiff1  = Isyv16(vmNewDiff1) && Isyuy2(Source) ? vmNewDiff1.ConvertToYuy2.interleaved2planar : vmNewDiff1
  906.     vmNewDiff2  = vmNewDiff1.VerticalCleaner( mode=1, planar=true )
  907.     vmNewDiff2  = Isyuy2(vmNewDiff2) ? vmNewDiff2.planar2interleaved.ConvertToYV16.mt_lutxy( vmNewDiff1.planar2interleaved.ConvertToYV16, \
  908.     "x 128 - y 128 - * 0 < 128 x 128 - abs y 128 - abs < x y ? ?", U=3,V=3 ) : \
  909.     vmNewDiff2.mt_lutxy( vmNewDiff1, "x 128 - y 128 - * 0 < 128 x 128 - abs y 128 - abs < x y ? ?", U=3,V=3 )
  910.     vmNewDiff2  = Isyv16(vmNewDiff2) && Isyuy2(Source) ? vmNewDiff2.ConvertToYuy2.interleaved2planar : vmNewDiff2
  911.     vmNewDiff3  = vmNewDiff2.Repair( vmNewDiff2.RemoveGrain( 2, planar=true ), 1, planar=true )
  912.  
  913.     # Reweave final result
  914.     newfd = Isyuy2(newFields) ? newFields.planar2interleaved.ConvertToYV16.mt_makediff( vmNewDiff3.planar2interleaved.ConvertToYV16, U=3,V=3 ).ConvertToYuy2.interleaved2planar : \
  915.     newFields.mt_makediff( vmNewDiff3, U=3,V=3 )
  916.     return Interleave( srcFields, newfd).SelectEvery( 4, 0,1,3,2 ).Weave()
  917. }
  918.  
  919.  
  920. # Source-match, a three stage process that takes the difference between deinterlaced input and the original interlaced source, to shift the input more towards
  921. # the source without introducing shimmer. All other arguments defined in main script
  922. function QTGMC_ApplySourceMatch( clip Deinterlace, int InputType, val Source, val bVec1, val fVec1, val bVec2, val fVec2, \
  923.                                  int SubPel, int SubPelInterp, int hpad, int vpad, int ThSAD1, int ThSCD1, int ThSCD2, int SourceMatch, \
  924.                                  int MatchTR1, string MatchEdi, int MatchNNSize, int MatchNNeurons, int MatchEdiQual, int MatchEdiMaxD,\
  925.                                  int MatchTR2, string MatchEdi2, int MatchNNSize2, int MatchNNeurons2, int MatchEdiQual2, int MatchEdiMaxD2, \
  926.                                  float MatchEnhance, int EdiThreads, bool lsb )
  927. {
  928.     # >>>> YUY2: 'Deinterlace' is planar, 'Source' is interleaved (changed to planar here for all processing except interpolation) - returns planar result
  929.     yuy2 = Source.IsYUY2()
  930.     Source = yuy2 ? Source.Interleaved2Planar() : Source
  931.  
  932.     # Basic source-match. Find difference between source clip & equivalent fields in interpolated/smoothed clip (called the "error" in formula below). Ideally
  933.     # there should be no difference, we want the fields in the output to be as close as possible to the source whilst remaining shimmer-free. So adjust the
  934.     # *source* in such a way that smoothing it will give a result closer to the unadjusted source. Then rerun the interpolation (edi) and binomial smooth with
  935.     # this new source. Result will still be shimmer-free and closer to the original source.
  936.     # Formula used for correction is P0' = P0 + (P0-P1)/(k+S(1-k)), where P0 is original image, P1 is the 1st attempt at interpolation/smoothing , P0' is the
  937.     # revised image to use as new source for interpolation/smoothing, k is the weighting given to the current frame in the smooth, and S is a factor indicating
  938.     # "temporal similarity" of the error from frame to frame, i.e. S = average over all pixels of [neighbor frame error / current frame error] . Decreasing
  939.     # S will make the result sharper, sensible range is about -0.25 to 1.0. Empirically, S=0.5 is effective [will do deeper analysis later]
  940.     errorTemporalSimilarity = 0.5  # S in formula described above
  941.     errorAdjust1   = Select( MatchTR1, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  942.     match1Clip     = (SourceMatch < 1 || InputType == 1) ? Deinterlace : Deinterlace.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  943.     match1Update   = (SourceMatch < 1 || MatchTR1 == 0) \
  944.                         ? Source : Isyuy2(Source) ? mt_lutxy( Source.planar2interleaved.ConvertToYV16, match1Clip.planar2interleaved.ConvertToYV16, "x " + string(errorAdjust1 + 1) + " * y " + string(errorAdjust1) + " * -", U=3,V=3 ).ConvertToYuy2.interleaved2planar : \
  945.                         mt_lutxy( Source, match1Clip, "x " + string(errorAdjust1 + 1) + " * y " + string(errorAdjust1) + " * -", U=3,V=3 )
  946.     match1Edi      = (SourceMatch == 0) ? NOP() : \
  947.                      !yuy2 ? match1Update.QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) : \
  948.                              match1Update.Planar2Interleaved() \
  949.                                          .QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) \
  950.                                          .Interleaved2Planar()
  951.     match1Super    = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, planar=true ) : NOP()
  952.     match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MDegrain1( match1Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : NOP()
  953.     match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) ? match1Edi.MDegrain1( match1Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : NOP()
  954.     match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) && lsb ? Isyuy2(Deinterlace) ? match1Degrain1.planar2interleaved.ConvertToYV16.ditherpost(mode=6, slice=false).ConvertToYuy2.interleaved2planar : match1Degrain1.ditherpost(mode=6, slice=false) : match1Degrain1
  955.     match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) && lsb ? Isyuy2(Deinterlace) ? match1Degrain2.planar2interleaved.ConvertToYV16.ditherpost(mode=6, slice=false).ConvertToYuy2.interleaved2planar : match1Degrain2.ditherpost(mode=6, slice=false) : match1Degrain2
  956.     match1         = (SourceMatch < 1) ? Deinterlace : \
  957.                      (MatchTR1 == 0)   ? match1Edi : \
  958.                      (MatchTR1 == 1)   ? match1Degrain1.Merge( match1Edi, 0.25 ) : \
  959.                                          match1Degrain1.Merge( match1Degrain2, 0.2 ).Merge( match1Edi, 0.0625 )
  960.  
  961.     # Enhance effect of source-match stages 2 & 3 by sharpening clip prior to refinement (source-match tends to underestimate so this will leave result sharper)
  962.     malu = Isyuy2(match1) ? match1.planar2interleaved.ConvertToYV16.mt_lutxy( match1.RemoveGrain( 12, planar=true ).planar2interleaved.ConvertToYV16, \
  963.     "x x y - "+ string(MatchEnhance) + " * +", U=3,V=3 ).ConvertToYuy2.interleaved2planar : \
  964.     match1.mt_lutxy( match1.RemoveGrain( 12, planar=true ), "x x y - "+ string(MatchEnhance) + " * +", U=3,V=3 )
  965.     match1Shp = (SourceMatch > 1 && MatchEnhance > 0.0) ? malu : match1
  966.  
  967.     # Source-match refinement. Find difference between source clip & equivalent fields in (updated) interpolated/smoothed clip. Interpolate & binomially smooth
  968.     # this difference then add it back to output. Helps restore differences that the basic match missed. However, as this pass works on a difference rather than
  969.     # the source image it can be prone to occasional artefacts (difference images are not ideal for interpolation). In fact a lower quality interpolation such
  970.     # as a simple bob often performs nearly as well as advanced, slower methods (e.g. NNEDI3)
  971.     match2Clip     = (SourceMatch < 2 || InputType == 1) ? match1Shp : match1Shp.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  972.     matchdifyuyin26= Isclip(Source) ? Isyuy2(Source) ? mt_makediff( Source.planar2interleaved.ConvertToYV16, match2Clip.planar2interleaved.ConvertToYV16, U=3,V=3 ).ConvertToYuy2.interleaved2planar : nop() : nop()
  973.     match2Diff     = (SourceMatch > 1) ? !Isyuy2(Deinterlace) ? mt_makediff( Source, match2Clip, U=3,V=3 ) : matchdifyuyin26 : NOP()
  974.     match2Edi      = (SourceMatch <= 1) ? NOP() : \
  975.                      !yuy2 ? match2Diff.QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) : \
  976.                              match2Diff.Planar2Interleaved() \
  977.                                        .QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) \
  978.                                        .Interleaved2Planar()
  979.     match2Super    = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, planar=true ) : NOP()
  980.     match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MDegrain1( match2Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : NOP()
  981.     match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) ? match2Edi.MDegrain1( match2Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : NOP()
  982.     match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) && lsb ? isyuy2(match2Degrain1) ? match2Degrain1.planar2interleaved.ConvertToYV16.ditherpost(mode=6, slice=false).ConvertToYuy2.interleaved2planar : match2Degrain1.ditherpost(mode=6, slice=false) : match2Degrain1
  983.     match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) && lsb ? isyuy2(match2Degrain2) ? match2Degrain2.planar2interleaved.ConvertToYV16.ditherpost(mode=6, slice=false).ConvertToYuy2.interleaved2planar : match2Degrain2.ditherpost(mode=6, slice=false) : match2Degrain2
  984.     match2         = (SourceMatch < 2) ? match1 : \
  985.                      (MatchTR2 == 0)   ? match2Edi : \
  986.                      (MatchTR2 == 1)   ? match2Degrain1.Merge( match2Edi, 0.25 ) : \
  987.                                          match2Degrain1.Merge( match2Degrain2, 0.2 ).Merge( match2Edi, 0.0625 )
  988.  
  989.     # Source-match second refinement - correct error introduced in the refined difference by temporal smoothing. Similar to error correction from basic step
  990.     errorAdjust2   = Select( MatchTR2, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  991.     matlutin26 = Isyuy2(Deinterlace) && isclip(match2Edi) ? mt_lutxy( match2Edi.planar2interleaved.ConvertToYV16, match2.planar2interleaved.ConvertToYV16, \
  992.     "x " + string(errorAdjust2 + 1) + " * y " + string(errorAdjust2) + " * -", U=3,V=3 ).ConvertToYuy2.interleaved2planar : nop()
  993.     match3Update   = (SourceMatch < 3 || MatchTR2 == 0) \
  994.                          ? match2Edi : !Isyuy2(Deinterlace) ? mt_lutxy( match2Edi, match2, "x " + string(errorAdjust2 + 1) + " * y " + string(errorAdjust2) + " * -", U=3,V=3 ) : matlutin26
  995.     match3Super    = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, planar=true ) : NOP()
  996.     match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MDegrain1( match3Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : NOP()
  997.     match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) ? match3Update.MDegrain1( match3Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : NOP()
  998.     match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) && lsb ? isyuy2(match3Degrain1) ? match3Degrain1.planar2interleaved.ConvertToYV16.ditherpost(mode=6, slice=false).ConvertToYuy2.interleaved2planar : match3Degrain1.ditherpost(mode=6, slice=false) : match3Degrain1
  999.     match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) && lsb ? isyuy2(match3Degrain2) ? match3Degrain2.planar2interleaved.ConvertToYV16.ditherpost(mode=6, slice=false).ConvertToYuy2.interleaved2planar : match3Degrain2.ditherpost(mode=6, slice=false) : match3Degrain2
  1000.     match3         = (SourceMatch < 3) ? match2 : \
  1001.                      (MatchTR2 == 0)   ? match3Update : \
  1002.                      (MatchTR2 == 1)   ? match3Degrain1.Merge( match3Update, 0.25 ) : \
  1003.                                          match3Degrain1.Merge( match3Degrain2, 0.2 ).Merge( match3Update, 0.0625 )
  1004.  
  1005.     # Apply difference calculated in source-match refinement
  1006.     return (SourceMatch < 2) ? match1 : Isyuy2(match1Shp) ? match1Shp.planar2interleaved.ConvertToYV16.mt_adddiff( match3.planar2interleaved.ConvertToYV16, U=3,V=3 ).ConvertToYuy2.interleaved2planar : \
  1007.     match1Shp.mt_adddiff( match3, U=3,V=3 )
  1008. }
  1009.  
  1010.  
  1011. # Set global variable called "Prefix_Name" to "Value". Throws exception if global already exists unless Replace=true, in which case the global is overwritten
  1012. function QTGMC_SetUserGlobal( string Prefix, string Name, val Value, bool "Replace" )
  1013. {
  1014.     Replace = default( Replace, false )
  1015.     globalName = Prefix + "_" + Name
  1016.  
  1017.     # Tricky logic to check global: enter catch block if Replace=true *or* globalName doesn't exist (i.e. need to set the global), the exception is not rethrown
  1018.     # Not entering catch block means that Replace=false and global exists - so it throws an exception back to AviSynth
  1019.     try { Assert( !Replace && defined(Eval(globalName)) ) }
  1020.     catch (e)
  1021.     {
  1022.         Eval( "global " + globalName + " = Value" )
  1023.         Replace = true
  1024.     }
  1025.     Assert( Replace, """Multiple calls to QTGMC, set PrevGlobals="Replace" or read documentation on 'Multiple QTGMC Calls'""" )
  1026. }
  1027.  
  1028. # Return value of global variable called "Prefix_Name". Returns NOP() if it doesn't exist or Reuse is false
  1029. function QTGMC_GetUserGlobal( string Prefix, string Name, bool "Reuse" )
  1030. {
  1031.     Reuse = default( Reuse, false )
  1032.     globalName = Prefix + "_" + Name
  1033.  
  1034.     try       { ret = Reuse ? Eval( globalName ) : NOP() }
  1035.     catch (e) { ret = NOP() }
  1036.     return ret
  1037. }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!