POST_76

/*  TITULO: Control del brillo de una bombilla mediante un Dimmer AC y Bluetooth

    AUTOR:

    MARIANO DEL CAMPO GARCÍA (@2017) --> INGENIERO TÉCNICO INDUSTRIAL ESPECIALIDAD ELECTRÓNICA
    - FACEBOOK: https://www.facebook.com/mariano.delcampogarcia
    - TWITTER: https://twitter.com/MarianoCampoGa
    - CORREO: marianodc83@gmail.com


    DESCRIPCIÓN DEL PROGRAMA

    Con este programa regulamos el brillo de una bombilla de 28W/220VAC mediante un Dimmer AC,
    enviándole pulsos PWM, de un valor comprendido entre 14 y 90, desde la APP Android llamada
    "1 Chammel Dimmer Bluetooth" para que nuestro Arduino los reciba gracias al módulo bluetooth
    HC-05 que tiene conectado en modo esclavo.

    Descargar de la APP Android "1 Channel Dimmer Bluetooth":
    https://mega.nz/#!WgYHgCTD!js9T2o6VwISlUIGmsYOGYkYicMLAcZ_FeWwKVtgnvXU


    ESQUEMA DE CONEXION

                                      +-----+
         +----[PWR]-------------------| USB |--+
         |                            +-----+  |
         |         GND/RST2  [ ][ ]            |
         |       MOSI2/SCK2  [ ][ ]  A5/SCL[ ] |
         |          5V/MISO2 [ ][ ]  A4/SDA[ ] |
         |                             AREF[ ] |
         |                              GND[ ] |
         | [ ]N/C                    SCK/13[ ] |
         | [ ]IOREF                 MISO/12[ ] |
         | [ ]RST                   MOSI/11[ ]~|
         | [ ]3V3    +---+               10[ ]~|
         | [ ]5v    -| A |-               9[ ]~|   Pin PWM del Dimmer AC
         | [ ]GND   -| R |-               8[ ] |
         | [ ]GND   -| D |-                    |
         | [ ]Vin   -| U |-               7[ ] |   Pin RX del módulo Bluetooth HC-05
         |          -| I |-               6[ ]~|   Pin TX del módulo Bluetooth HC-05
         | [ ]A0    -| N |-               5[ ]~|
         | [ ]A1    -| O |-               4[ ] |
         | [ ]A2     +---+           INT1/3[ ]~|
         | [ ]A3                     INT0/2[ ] |
         | [ ]A4/SDA  RST SCK MISO     TX>1[ ] |
         | [ ]A5/SCL  [ ] [ ] [ ]      RX<0[ ] |
         |            [ ] [ ] [ ]              |
         |  UNO_R3    GND MOSI 5V  ____________/
          \_______________________/

  NOTAS:

   - Más conexiones del Dimmer AC.
       - Pin 5V --> +5V de Arduino
       - Pin GND --> GND de Arduino
       - Pin MODE --> +5V de Arduino (Para modo PWM del Dimmer AC)
       - Conector AC IN --> 220VAC
       - Conector AC LOAD --> Bombilla de 28W/220VAC
   - Alimentación del módulo Bluetooth HC-05:
       - Pin +5V del módulo Bluetooth HC-05 --> +5V de Arduino.
       - Pin GND del módulo Bluetooth HC-05 --> GND de Arduino.
*/


  #include <SoftwareSerial.h>

  // Definimos el objeto para la comunicación serie (Bluetooth)
  SoftwareSerial BT(6,7); // 6 RX, 7 TX.

  int CH1=14; // Valor del PWM que aplicamos al Dimmer AC (Inicialmente Atenuación al 100%)
  int i=0; // Variable de control

  char mensaje[3]; // Cadena para almacenar los caracteres que recibidos a través de Bluetooth
  byte posicion=0;  // Variable para movernos por los elementos de la cadena.
  const int Pin_PWM = 9; // Pin digital donde conectamos el pin PWM del Dimmer AC


  void setup()
  {
    Serial.begin(9600); // Comienzo de la comunicación con el monitor serie (BAUDIOS)
    // Comienzo de la comunicación con el módulo Bluetooth HC-05 (configurable mediante comandos AT)
    BT.begin(38400); // Velocidad de comunicación por defecto del módulo Bluetooth HC-05
  }


  void loop()
  {
    if(BT.available()) // Si hay datos procedentes de la comunicación Bluetooth dentro del buffer...
    {
      // memset borra el contenido de la cadena "mensaje" desde la posición 0 hasta el final (sizeof)
      memset(mensaje, 0, sizeof(mensaje));

      while(BT.available()>0) // Mientras haya datos en el buffer...
      {
        delay(50); // Retardo para mejorar la recepción de datos
        mensaje[posicion] = BT.read(); // Lee un carácter y lo almacena en una posición de la cadena "mensaje"
        posicion++; // Se incrementa una posición de la cadena
      }
      posicion=0; // Inicializa la posición de la cadena
      i=0; // Inicializa la variable de control
    }

    // Valores de seguridad que nos envía la APP antes de enviar el valor de "CH1"
    if(mensaje[0]=='X' && mensaje[1]=='A')
    {
      CH1=(int)mensaje[2]; // Guarda el carácter recibido dentro de la variable "CH1", pero en "modo entero"

      // Atenuación al 100% --> Bombilla OFF
      if(CH1<14)
      {
        CH1=14;
      }

      // Atenuación al 0% --> Bombilla ON
      if(CH1>90)
      {
        CH1=90;
      }
    }

    // Condición que solamente se ejecuta una vez por cada cadena completa recibida a través de Bluetooth
    if(i==0)
      {
        // Manda el valor del PWM al Dimmer AC
        analogWrite(Pin_PWM, CH1);
        // Envía el valor del PWM a través del monitor serie para poder visualizarlo
        Serial.print("Valor del PWM: ");
        Serial.println(CH1);
        i=1; // Actualizamos la variable de control
      }
  }