mGmTrans.uc

class mGmTrans extends Mutator
    config(mGmTrans);

function bool CheckReplacement( Actor Other, out byte bSuperRelevant )
{
    local int i;
    local WeaponLocker L;

    bSuperRelevant = 0;

    if ( xWeaponBase(Other) != None )
    {
        if ( string( xWeaponBase(Other).WeaponType ) ~= "XWeapons.TransLauncher" )
        {
            xWeaponBase(Other).WeaponType = class'mGmTransLauncher';
            return false;
        }
    }
    else if ( WeaponPickup(Other) != None )
    {
        if ( string(Other.Class) ~= "XWeapons.Transpickup" )
        {
            ReplaceWith( Other, "mGmTransPickup" );
            return false;
        }
    }
    else if ( WeaponLocker(Other) != None )
    {
        L = WeaponLocker(Other);

        for (i = 0; i < L.Weapons.Length; i++)
        {
            if ( string( L.Weapons[i].WeaponClass ) ~= "XWeapons.TransLauncher" )
                L.Weapons[i].WeaponClass = class'mGmTransLauncher';
        }
    }

    return true;
}

function string GetInventoryClassOverride(string InventoryClassName)
{
    if (InventoryClassName == "XWeapons.TransLauncher")
        InventoryClassName = "mGmTrans.mGmTransLauncher";

    return Super.GetInventoryClassOverride(InventoryClassName);
}

defaultproperties
{
     GroupName="Daschinia's Modified Translocator"
     FriendlyName="mGmTrans"
     Description="Makes the translocator beacons explode for fun and giggles."
}