MY CODE: SRGameType.uc
Some code here that is irrelevant...
...
State MatchInProgress
{

    function CloseShops()
    {
        local int i;
        local Controller C;
        local Pickup Pickup;

        bTradingDoorsOpen = False;
        for( i=0; i<ShopList.Length; i++ )
        {
            if( ShopList[i].bCurrentlyOpen )
                ShopList[i].CloseShop();
        }

        SelectShop();

        foreach AllActors(class'Pickup', Pickup)
        {
            if ( Pickup.bDropped )
            {
                Pickup.Destroy();
            }
        }

        // Tell all players to stop showing the path to the trader
        for ( C = Level.ControllerList; C != none; C = C.NextController )
        {
            if ( C.Pawn != none && C.Pawn.Health > 0 )
            {
                // Restore pawn collision during trader time
                C.Pawn.bBlockActors = C.Pawn.default.bBlockActors;

                if ( KFPlayerController(C) != none )
                {
                    KFPlayerController(C).SetShowPathToTrader(false);
                    KFPlayerController(C).ClientForceCollectGarbage();

                    if ( WaveNum < FinalWave - 1 )
                    {
                        // Have Trader tell players that the Shop's Closed
                        KFPlayerController(C).ClientLocationalVoiceMessage(C.PlayerReplicationInfo, none, 'TRADER', 6);
                    }
                }
            }
        }
    }

    function BeginState()
    {
        Super.BeginState();

        WaveNum = InitialWave;
        InvasionGameReplicationInfo(GameReplicationInfo).WaveNumber = WaveNum;

        // Ten second initial countdown
        WaveCountDown = 10;// Modify this if we want to make it take long for zeds to spawn initially

        SetupPickups();
    }

    function SetupPickups()
    {
        local int NumWeaponPickups, NumAmmoPickups, Random, i, j;
        local int m;

        // Randomize Available Ammo Pickups
        if ( GameDifficulty >= 5.0 ) // Suicidal and Hell on Earth
        {
            NumWeaponPickups = WeaponPickups.Length * 0.25;
            NumAmmoPickups = AmmoPickups.Length * 0.25;
        }
        else if ( GameDifficulty >= 4.0 ) // Hard
        {
            NumWeaponPickups = WeaponPickups.Length * 0.50;
            NumAmmoPickups = AmmoPickups.Length * 0.50;
        }
        else if ( GameDifficulty >= 2.0 ) // Normal
        {
            NumWeaponPickups = WeaponPickups.Length * 0.75;
            NumAmmoPickups = AmmoPickups.Length * 0.75;
        }
        else // Beginner
        {
            NumWeaponPickups = WeaponPickups.Length * 1.00;
            NumAmmoPickups = AmmoPickups.Length * 1.00;
        }

        // Always have at least 1 pickup
        NumWeaponPickups = Max(1, NumWeaponPickups);
        NumAmmoPickups = Max(1, NumAmmoPickups);

        // reset all the of the pickups
        for ( m = 0; m < WeaponPickups.Length ; m++ )
        {
            if(WeaponPickups[m] != None)
            {
                WeaponPickups[m].DisableMe();
            }
        }

        for ( m = 0; m < AmmoPickups.Length ; m++ )
        {
            if( AmmoPickups[m] != None )
            {
                AmmoPickups[m].GotoState('Sleeping', 'Begin');
            }
        }

        // Ramdomly select which pickups to spawn
        for ( i = 0; i < NumWeaponPickups && j < 10000; i++ )
        {
            Random = Rand(WeaponPickups.Length);
            if(WeaponPickups.Length==0) break;
            if ( WeaponPickups[Random]!=None && !WeaponPickups[Random].bIsEnabledNow )
            {
                WeaponPickups[Random].EnableMe();
            }
            else
            {
                i--;
            }

            j++;
        }

        for ( i = 0; i < NumAmmoPickups && j < 10000; i++ )
        {
            Random = Rand(AmmoPickups.Length);
            if(AmmoPickups.Length==0) break;
            if ( AmmoPickups[Random]!=None && AmmoPickups[Random].bSleeping )
            {
                AmmoPickups[Random].GotoState('Pickup');
            }
            else
            {
                i--;
            }

            j++;
        }
    }
}

ORIGINAL KFMod.KFGameType
    function SetupPickups()
    {
        local int NumWeaponPickups, NumAmmoPickups, Random, i, j;
        local int m;

        // Randomize Available Ammo Pickups
        if ( GameDifficulty >= 5.0 ) // Suicidal and Hell on Earth
        {
            NumWeaponPickups = WeaponPickups.Length * 0.1;
            NumAmmoPickups = AmmoPickups.Length * 0.1;
        }
        else if ( GameDifficulty >= 4.0 ) // Hard
        {
            NumWeaponPickups = WeaponPickups.Length * 0.2;
            NumAmmoPickups = AmmoPickups.Length * 0.35;
        }
        else if ( GameDifficulty >= 2.0 ) // Normal
        {
            NumWeaponPickups = WeaponPickups.Length * 0.3;
            NumAmmoPickups = AmmoPickups.Length * 0.5;
        }
        else // Beginner
        {
            NumWeaponPickups = WeaponPickups.Length * 0.5;
            NumAmmoPickups = AmmoPickups.Length * 0.65;
        }

        // reset all the of the pickups
        for ( m = 0; m < WeaponPickups.Length ; m++ )
        {
            WeaponPickups[m].DisableMe();
        }

        for ( m = 0; m < AmmoPickups.Length ; m++ )
        {
            AmmoPickups[m].GotoState('Sleeping', 'Begin');
        }

        // Ramdomly select which pickups to spawn
        for ( i = 0; i < NumWeaponPickups && j < 10000; i++ )
        {
            Random = Rand(WeaponPickups.Length);

            if ( !WeaponPickups[Random].bIsEnabledNow )
            {
                WeaponPickups[Random].EnableMe();
            }
            else
            {
                i--;
            }

            j++;
        }

        for ( i = 0; i < NumAmmoPickups && j < 10000; i++ )
        {
            Random = Rand(AmmoPickups.Length);

            if ( AmmoPickups[Random].bSleeping )
            {
                AmmoPickups[Random].GotoState('Pickup');
            }
            else
            {
                i--;
            }

            j++;
        }
    }