; this has been made over the routine that loads an enemy Pokemon
; had to find a point to break the routine where
; 1: stats had already been loaded into RAM
; 2: working with registers bc, de, and hl was not a problem (for convenience)

#org 3EB10
jp Main ; jumps to the new stuff

#org 3FE88
Main:
ld a,(D22D)
cp a, 2 ; are we in a trainer battle?
jp z, ApplyStatBoosts ; if so the stat boosts are applied, otherwise fallthrough

#org 3FE90
Original:
; original routine stuff, that is, original 3EB10-3EB37
ld hl,D073
ld de,C616
ld bc,000B
call Label3026
ld a,(D204)
dec a
ld c,a
ld b,01
ld hl,DEB9
ld a,03
call Label2D83
ld hl,D21A
ld de,C6C1
ld bc,000A
call Label3026
ret ; the original routine finishes at this point

ApplyStatBoosts:
;    [1,32]: boost = 0
;   [33,54]: boost = level/16
;   [55,73]: boost = level/16 + level/16
;   [74,77]: boost = level/8
;   [78,99]: boost = level/8 + level/32
; [100,100]: boost = level/4

ld hl,D217 ; point to the first stat LSB (Max HP)
ld c,7 ; there are seven stats (HP includes Max and Cur)
ld a,(D143) ; get enemy's level

level100to100:
cp a,$64
jr c,level78to99 ; if not between 100 and 100, skip
ld d,2 ; level will be halved twice
call boost ; boost the stats
jr Original ; we are done

level78to99:
cp a,$4E
jr c,level74to77
ld d,3
call boost ; level/(2^3) = level/8
ld hl,D217 ; hl and c are lost at this point
ld c,7
ld d,5
call boost ; level/(2^5) = level/32 --> level/8 + level/32
jr Original ;

level74to77:
cp a,$4A
jr c,level55to73
ld d,3
call boost ; level/8
jr Original

level55to73:
cp a,$37
jr c,level33to54
ld d,4
call boost
ld hl,D217
ld c,7
ld d,4
call boost ; level/16 + level/16
jr Original

level33to54:
cp a,$21
jr c,level0to32
ld d,4
call boost ; level/16
; fallthrough

level0to32:
jr Original ; no boost if level<33

#org 3EB13
boost:
ld a,(D143) ; get enemy's level (a gets overwritten on every loop)
ld b,a
ld e,d ; save d for later
halve: ; halve level d times
srl b
dec d
jr nz,halve
ld a,(hl) ; a = attack LSB before boost has been applied
add a,b
ld (hl),a ; load a+b into the stat
jr nc,finish ; overflow check
dec hl ; if overflow, add 0x100 to the stat
inc (hl) ; inc MSB
inc hl ; point to LSB again
finish:
inc hl
inc hl ; point to the next stat LSB
dec c ; one less stat left
ld d,e
jr nz,boost ; loop if not done
ret ; otherwise return