การเชื่อมต่ออุปกรณ์เข้ากับ NETPIE สำหรับ GP2Y1010AU0F

/* Connect to SHARP PM2.5 Sensor*/
#include <PMsensor.h>
PMsensor PM;
/* connect to wifi */
#include <ESP8266WiFi.h>
const char* ssid     = "YOUR WiFi Network Name’"; // ssid wifi
const char* password = "PASSWORD PUT IN HERE"; // it is recommended to use WPA/WPA2
WiFiClient client;
/* connect to netpie */
#include <MicroGear.h>
#define APPID "REPLACE ME WITH YOUR APP ID" // APPLICATION (APPID)
#define KEY "REPLACE ME WITH YOUR DEVICE KEY" // device key
#define SECRET "REPLACE ME WITH YOUR SECRET KEY"  // *secret device key
#define FEEDID  "REPLACE ME WITH YOUR FEED NAME"  // feed name
#define ALIAS   "PLEASE GIVE ME A MEANINGFUL NAME TO CALL ME"
MicroGear microgear(client);
/* Variable */
int timer = 0;
char str[32];

void onMsghandler(char *topic, uint8_t* msg, unsigned int msglen) {
  Serial.print("Incoming message --> ");
  msg[msglen] = '\0';
  Serial.println((char *)msg);
}

void onConnected(char *attribute, uint8_t* msg, unsigned int msglen) {
  Serial.println("Connected to NETPIE...");
  microgear.setAlias(ALIAS);
}

void setup() {
  Serial.begin(115200);
  // Initialize PM Sensor
  /////(infrared LED pin, sensor pin)  /////
  PM.init(D5, A0);
  // Initialize microgear
  microgear.on(MESSAGE, onMsghandler);
  microgear.on(CONNECTED, onConnected);     //optional
  microgear.on(ERROR, onConnected);
  microgear.on(INFO, onConnected);
  //Wait for WiFi Establishement
  Serial.println("Starting...");
  if (WiFi.begin(ssid, password)) {
    while (WiFi.status() != WL_CONNECTED) {
      delay(500);
      Serial.print(".");
    }
  }
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  microgear.init(KEY, SECRET, ALIAS);
  microgear.connect(APPID);
}

void loop() {
  if (microgear.connected()) {
    Serial.print("*");
    microgear.loop();
    if (timer >= 60000) {

      float pm = 0;
      int err = PMsensorErrSuccess;

      if ((err = PM.read(&pm, true, 0.1)) != PMsensorErrSuccess) {
        Serial.print("data Error = ");
        Serial.println(err);
        return;
      }
      Serial.print("PM2.5: ");
      Serial.print(pm);
      Serial.println(" ppm");

      //STRING FOR FEED
      String  data = "{\"Room_PM2_5\":"; //FEED NAME HERE
      data += pm ;
      data += "}";

      sprintf(str, "%.2f",pm);
      Serial.println(str);
      microgear.publish("/roomquality", str); //Publish to the NETPIE for Freeboard and the other utilization
      Serial.println((char*) data.c_str());
      Serial.print("Sending --> ");
      microgear.writeFeed(FEEDID, data);    //YOUR  FEED ID, API KEY

      timer = 0;
    }
    else timer += 200;
  } else {
    Serial.println("connection lost, reconnect...");
    if (timer >= 5000) {
      microgear.connect(APPID);
      timer = 0;
    }
    else timer += 200;
  }
    delay(200);
}