# Maintainer:  <[email protected]>
# Contributor: Vitalii Kuzhdin <[email protected]>
# Contributor: bartus <arch-user-repoᘓbartus.33mail.com>
# Contributor: Andrzej Giniewicz <[email protected]>

pkgbase="fbx-sdk"
pkgname=(
  "${pkgbase}"
  "${pkgbase}-samples"
)
pkgver=2020.3.7
_pkgver="${pkgver//.}"
pkgrel=3
pkgdesc="Platform and API toolkit to transfer existing content into the FBX format"
arch=('x86_64')
url="https://www.autodesk.com/products/fbx/overview"
license=('LicenseRef-Autodesk-FBX-SDK-2020-License')
options=(
  'staticlibs'
  # '!strip'
  # '!debug'
)
_pkgsrc="${pkgbase}-${pkgver}"
source=("${pkgbase}.sh"
        "${pkgbase}.csh")
source_x86_64=("${_pkgsrc}-x86_64.tar.gz::https://damassets.autodesk.net/content/dam/autodesk/www/files/fbx${pkgver//.}_fbxsdk_gcc_linux.tar.gz")
sha256sums=('b67a77380802c669c73834adcd9e51207c65c5b6d131737b004cd821db0e9d5f'
            '9862ac85265188d89704c27e78278634ea3d21fd66e055ff6d99fb97e048c80e')
sha256sums_x86_64=('191c6b0a549f1e70154a04705ddbf52232d049a6e5ae17801a2bc2bf60b84e0b')

prepare() {
  cd "${srcdir}"
  chmod +x ./"fbx${_pkgver}_fbxsdk_linux"
}

build() {
  cd "${srcdir}"
  rm -rf "${_pkgsrc}"
  mkdir -p "${_pkgsrc}"
  printf "yes\nn\n" | ./"fbx${_pkgver}_fbxsdk_linux" "${srcdir}/${_pkgsrc}"

  cd "${_pkgsrc}"
  # fix typo
  sed -i 's/mLefttChild/mLeftChild/g' "include/fbxsdk/core/base/fbxredblacktree.h"
}

package_fbx-sdk() {
  depends=(
    'gcc-libs'
    'glibc'
    'libxml2-legacy'
    'zlib'
  )

  cd "${srcdir}"
  install -vDm644 "${pkgbase}.sh"  "${pkgdir}/etc/profile.d/${pkgbase}.sh"
  install -vDm644 "${pkgbase}.csh" "${pkgdir}/etc/profile.d/${pkgbase}.csh"

  install -vd "${pkgdir}/opt/${pkgbase}" \
              "${pkgdir}/usr/include" \
              "${pkgdir}/usr/lib" \
              "${pkgdir}/usr/share/doc/${pkgbase}" \
              "${pkgdir}/usr/share/licenses/${pkgbase}"

  cp -a --no-preserve=mode,ownership "${_pkgsrc}" -T "${pkgdir}/opt/${pkgbase}"

  ln -vsf "/opt/${pkgbase}/FBX_SDK_Online_Documentation.html" "${pkgdir}/usr/share/doc/${pkgbase}/"
  ln -vsf "/opt/${pkgbase}/License.txt" "${pkgdir}/usr/share/licenses/${pkgbase}/"

  cd "${pkgdir}/opt/${pkgbase}"
  rm -rf "samples"

  find "include" -mindepth 1 -maxdepth 1 -execdir \
    ln -vsf "/opt/${pkgbase}/include/{}" "${pkgdir}/usr/include/" \;
  find "lib/release" -type f -name 'libfbxsdk.*' -execdir \
    ln -vsf "/opt/${pkgbase}/lib/release/{}" "${pkgdir}/usr/lib/" \;
}

package_fbx-sdk-samples() {
  pkgdesc+=" (samples)"
  depends=(
    "${pkgbase}=${pkgver}-${pkgrel}"
  )

  cd "${srcdir}/${_pkgsrc}"
  install -vd "${pkgdir}/opt/${pkgbase}" \
              "${pkgdir}/usr/share/doc/${pkgbase}"

  cp -a --no-preserve=mode,ownership "samples" -t "${pkgdir}/opt/${pkgbase}"

  ln -vsf "/opt/${pkgbase}/samples" "${pkgdir}/usr/share/doc/${pkgbase}/"
}