TILE_BLACK EQU $10

DIR_UP    EQU 0
DIR_DOWN  EQU 1
DIR_LEFT  EQU 2
DIR_RIGHT EQU 3

UP_KEY   EQU 6
DOWN_KEY EQU 7

Pong:
    call ClearScreen
; uncomment if not in bank f (i.e. used buffer overflow RCE exploit in trade center)
;   ld a, $0f
;   ld ($2000), a

.waitingLoop
    ld a, $ff
    ld [wSerialExchangeNybbleReceiveData], a
    call PlaySound ; mute music
    ld a, 12
    call LinkBattleExchangeData_PrintWaiting_ExchangeNybbles
    ld a, [wSerialExchangeNybbleReceiveData]
    cp 12
    jr nz, .waitingLoop

; load the black tiles to VRAM
    di
.waitVblank
    ldh a, [rSTAT]
    cp $81
    jr nz, .waitVblank
    ld hl, $9100
    ld bc, $16 * 3
    ld a, $ff
    call FillMemory
    ei

.newGame
; init game params
    ld hl, wPad1Offset
    ld a, 7
    ld [hli], a ; wPad1Offset
    ld [hli], a ; wPad2Offset
    inc a
    ld [hli], a ; wBallCoordY
    ldh a, [hSerialConnectionStatus]
    cp USING_INTERNAL_CLOCK
    ld a, 1
    ld c, 1 << DIR_UP + 1 << DIR_RIGHT
    jr z, .notOppositeSide
    ld a, 18
    ld c, 1 << DIR_UP + 1 << DIR_LEFT
.notOppositeSide
    ld [hli], a ; wBallCoordX
    ld a, [wRandomStartYFlag]
    xor 1
    ld [wRandomStartYFlag], a
    and a
    jr nz, .ok
    inc c ; replace DIR_UP with DIR_DOWN
.ok
    ld [hl], c ; wBallDirection
    call RefreshPadsAndBall
    ld c, 12
    call DelayFrames

.mainLoop
    call RefreshPadsAndBall
    ld a, [wGameOver]
    and a
    jr z, .notGameOver
    dec a
    ld [wGameOver], a
    jr z, .newGame
.notGameOver
    call HandleJoypadInput
.skipJoypad
    call SendPadOffset
    call MoveBall
    jr .mainLoop

RefreshPadsAndBall:
; draw bg, horizontal walls, and vertical voids
    call DrawBackground
    call DrawVoids
; refresh player pad
    ld hl, wTileMap
    ld a, [wPad1Offset]
    call DrawPadFromOffset
; refresh enemy pad
    ld hl, wTileMap + 19
    ld a, [wPad2Offset]
    call DrawPadFromOffset
; refresh ball
    ld hl, wTileMap
    ld a, [wBallCoordX]
    ld e, a
    ld d, 0
    add hl, de
    ld a, [wBallCoordY]
    ld bc, 20
    call AddNTimes
;   xor a
    ld [hl], a
    ret

DrawBackground:
    ld hl, wTileMap
    call .drawWall
    ld a, TILE_BLACK
    ld bc, 20 * (18 - 2)
    call FillMemory
;   jr .drawWall
.drawWall
    ld bc, 20
    xor a
    jp FillMemory

DrawVoids:
    ld hl, wTileMap + 20 * 1
    call DrawFullVerticalBlackLine
    ld hl, wTileMap + 20 * 1 + 19
;   jr DrawFullVerticalBlackLine

DrawFullVerticalBlackLine:
    ld a, TILE_BLACK
    ld e, 16
DrawVerticalLine:
; hl = start address
; e = how many tiles
; a = tile
    ld bc, 20
.loop
    ld [hl], a
    add hl, bc
    dec e
    ret z
    jr .loop

DrawPadFromOffset:
    ld bc, 20
    call AddNTimes
    xor a
    ld e, 4
    jr DrawVerticalLine

HandleJoypadInput:
    ld bc, wPad1Offset
    ld a, [bc]
    ld hl, hJoyInput
    bit UP_KEY, [hl]
    jr z, .checkDown
    dec a ; cp 1
    ret z ; can't move up
    ld [bc], a
;   ret
.checkDown
    bit DOWN_KEY, [hl]
    ret z
    cp 17 - 4
    ret z
    inc a
    ld [bc], a
    ret

SendPadOffset:
    ld a, [bc] ; wPad1Offset
SendByte:
    ld [wSerialExchangeNybbleSendData], a
.syncLoop1
    call Serial_ExchangeNybble
    call DelayFrame
    ld a, [wSerialExchangeNybbleReceiveData]
    inc a
    jr z, .syncLoop1
    ld b, 5
.syncLoop2
    call DelayFrame
    call Serial_ExchangeNybble
    dec b
    jr nz, .syncLoop2
    ld a, [wSerialExchangeNybbleReceiveData]
    ld [wPad2Offset], a
    ret

MoveBall:
    ld hl, wBallCoordY ; handle vertical movement first
    ld e, 2
    ld a, [wBallDirection]
.loop
    rrca
    jr nc, .notUpOrLeft
    dec [hl]
.notUpOrLeft
    rrca
    jr nc, .notDownOrRight
    inc [hl]
.notDownOrRight
    dec e
    inc hl ; wBallCoordX
    jr nz, .loop ; go back to handle horizontal movement
; handle collisions
    dec hl
    dec hl
    ld a, [hl] ; wBallCoordY
    cp 16
    jr z, .wall
    dec a ; cp 1
    jr z, .wall
.handleCorners
    inc hl
    ld a, [hl] ; wBallCoordX
    cp 18
    jr z, .voidOrPad2
    dec a ; cp 1
    jr z, .voidOrPad1
    ret
.wall
; change Y movement
    ld c, 1 << DIR_UP + 1 << DIR_DOWN
    call .updateBallDirectionAndPlayClickSound
; properly handle the corners
    jr .handleCorners
.voidOrPad2
    ld a, [wPad2Offset]
    jr .voidOrPad
.voidOrPad1
    ld a, [wPad1Offset]
.voidOrPad
    dec hl ; wBallCoordY
    ld e, 4
.padBounceCheckLoop
    cp [hl]
    jr z, .pad
    inc a ; next pad tile
    dec e
    jr nz, .padBounceCheckLoop
; game over
    ld a, 3
    ld [wGameOver], a
    ret
.pad
; change X movement
    ld c, 1 << DIR_LEFT + 1 << DIR_RIGHT
;   jr .updateBallDirectionAndPlayClickSound
.updateBallDirectionAndPlayClickSound
    ld a, [wBallDirection]
    xor c
    ld [wBallDirection], a
    ld a, SFX_POUND
    jp PlaySound