zipLogFiles

@ECHO OFF

set sourceFolder=%1
set targetFolder=%2

if "%sourceFolder%"=="" set sourceFolder=E:\jboss-eap-7.3\standalone\log
if "%targetFolder%"=="" set targetFolder=C:\logs
set excludeFile=server.log

set today=%date:~3,2%%date:~6,2%%date:~10,4%
if not exist %sourceFolder% echo Logs could not be found. & goto :EOF
if exist "%targetFolder%\logs_%today%.zip" echo Logs for this day have already been extracted. & goto :EOF
if not exist %targetFolder% mkdir %targetFolder%
if not exist "%targetFolder%\logs_%today%.zip" goto ZIP-FILES

:ZIP-FILES

powershell.exe "Compress-Archive %sourceFolder% "%targetFolder%\logs_%today%.zip""

goto DELETE-FILES

:DELETE-FILES

set callingFolder=%cd%
cd /d %sourceFolder%

for %%i in (*) do (
    REM only process log files
    if /i "%%~xi" == ".log" (
        if /i %%i==server.log (echo Not deleting today's log file.) else (echo Deleting %%i & del %%i)
    )
)

cd %callingFolder%

echo Log files have been zipped to %targetFolder%\logs_%today%.zip

goto :EOF