M in triangle task

// Тип точка-вектор
type Point = record
  x,y: real;
  class function operator-(p1, p2: Point): Point;
  begin
    Result.x := p1.x - p2.x;
    Result.y := p1.y - p2.y;
  end;
end;

// Создание точки
function Pnt(x, y: real): Point;
begin
  Result.x := x;
  Result.y := y
end;

// Косое произведение векторов (cross-product)
function cP(p1, p2: Point): real;
begin
  Result := p1.x * p2.y - p1.y * p2.x;
end;

begin
  var (x1, y1) := ReadInteger2('Координаты точки A:');
  var a := pnt(x1, y1);

  var (x2, y2) := ReadInteger2('Координаты точки B:');
  var b := pnt(x2, y2);

  var (x3, y3) := ReadInteger2('Координаты точки C:');
  var c := pnt(x3, y3);

  var (xm, ym) := ReadInteger2('Координаты точки M:');
  var m := pnt(xm, ym);

  //Найдем координаты векторов AB, AM, BC, BM, AC, CM

  var ab := b - a;
  var am := m - a;

  var bc := c - b;
  var bm := m - b;

  var ca := a - c;
  var cm := m - c;

  // Вычислим косое произведение для (AB, AM), (BC, BM) и (AC, CM)
  // Если все три произведения одного знака, то точка M внутри треугольника ABC

  if (sign(cP(ab, am)) = sign(cP(bc, bm))) and (sign(cP(bc, bm)) = sign(cP(ca, cm))) then
    println('Точка M строго внутри треугольника')
  else
    println('Точка M либо вне треугольника, либо на одной из сторон');
end.