#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
#include <sqlx>

#define PLUGIN "SQLx Login"
#define SITE "ArenaMIXPug.net"

new Handle:g_SqlTuple;
new Query[512];

new g_UserName_MySQL[33][33]

public plugin_init(){

    register_plugin(PLUGIN,AMXX_VERSION_STR,"Thales");
    register_message( get_user_msgid( "SayText" ), "MessageSayText" );


}

public plugin_cfg() g_SqlTuple = SQL_MakeStdTuple();

public client_authorized(Client)
{
    if(is_user_hltv(Client)) return PLUGIN_HANDLED;

    new SteamID[32];
    get_user_authid(Client,SteamID,charsmax(SteamID));

    new Data[1];
    Data[0] = Client;

    formatex(Query,charsmax(Query),"SELECT * FROM `arenamix_members` WHERE `gamer_steam` = '%s'",SteamID);
    SQL_ThreadQuery(g_SqlTuple,"AutenticarSteamID",Query,Data,1);

    return PLUGIN_HANDLED;
}

public AutenticarSteamID(FailState,Handle:Query,Error[],Errcode,Data[],DataSize)
{
    static Client;
    Client = Data[0];

    new SteamID[32];
    get_user_authid(Client,SteamID,charsmax(SteamID));

    if(FailState == TQUERY_CONNECT_FAILED)
    {
        server_print("[%s] Conexao ao mySQL falhou! (Revise os dados de Login)",PLUGIN);
        server_cmd("kick #%d ^"Erro na DB, contate: %s^"",get_user_userid(Client),SITE);
        return PLUGIN_HANDLED;
    }
    else if(FailState == TQUERY_QUERY_FAILED)
    {
        server_print("[%s] Query falhou! (Revise as tabelas do mySQL)",PLUGIN);
        server_cmd("kick #%d ^"Erro na DB, contate1: %s^"",get_user_userid(Client),SITE);
        return PLUGIN_HANDLED;
    }
    if(Errcode)
    {
        server_print("[%s] Querry falhou! (%s)",PLUGIN,Errcode);
        server_cmd("kick #%d ^"Erro na DB, contate2: %s^"",get_user_userid(Client),SITE);
        return PLUGIN_HANDLED;
    }
    if(!SQL_MoreResults(Query))
    {
        server_print("[%s] SteamID nao encontrada: (%s)",PLUGIN,SteamID);
        server_cmd("kick #%d ^"Cadastre-se: %s^"",get_user_userid(Client),SITE);
        return PLUGIN_HANDLED;
    }
    else
    {
        SQL_ReadResult(Query,SQL_FieldNameToNum(Query,"real_name"),g_UserName_MySQL[Client], 32);

        client_cmd(Client,"name ^"%s^"",g_UserName_MySQL[Client]);
        return PLUGIN_HANDLED;
    }
    return PLUGIN_HANDLED;
}
public plugin_end() SQL_FreeHandle(g_SqlTuple);

public client_infochanged( client )
{
    static const name[ ] = "name";

    new szNewName[ 32 ]
    get_user_info( client, name, szNewName, 31 );

    if( !equal( szNewName, g_UserName_MySQL[client] ) )
    {
        set_user_info( client, name, g_UserName_MySQL[client] );
    }
}

public MessageSayText( iMsgId, iDest, iReceiver )
{
    static const Cstrike_Name_Change[ ] = "#Cstrike_Name_Change";

    static szMessage[ sizeof( Cstrike_Name_Change ) + 1 ];
    get_msg_arg_string( 2, szMessage, sizeof( szMessage ) - 1 );

    return equal( szMessage, Cstrike_Name_Change ) ? PLUGIN_HANDLED : PLUGIN_CONTINUE;
}