Standard3ColorMaskExtended

Shader "Custom/Standard3ColorMask" {
    Properties {
        _Mask ("mask (RGBA)", 2D) = "black" {}

        _ColorR ("ColorR", Color) = (1,1,1,1)
        _MainTex ("AlbedoR (RGB)", 2D) = "white" {}
        _SpecR ("SpecR (RGB)", 2D) = "black" {}
        _NormalR ("NormalR", 2D) = "bump" {}
        _EmissionR ("EmissionR (RGB)", 2D) = "black" {}

        _ColorG ("ColorG", Color) = (1,1,1,1)
        _MainTexG ("AlbedoG (RGB)", 2D) = "white" {}
        _SpecG ("SpecG (RGB)", 2D) = "black" {}
        _NormalG ("NormalG", 2D) = "bump" {}
        _EmissionG ("EmissionG (RGB)", 2D) = "black" {}

        _ColorB ("ColorB", Color) = (1,1,1,1)
        _MainTexB ("AlbedoB (RGB)", 2D) = "white" {}
        _SpecB ("SpecB (RGB)", 2D) = "black" {}
        _NormalB ("NormalB", 2D) = "bump" {}
        _EmissionB ("EmissionB (RGB)", 2D) = "black" {}

        [HDR]
        _EmissionColor("EmissionColor", Color) = (0,0,0)
    }
    SubShader {
        Tags { "RenderType"="Opaque" }
        LOD 200

        CGPROGRAM
        // Physically based Standard lighting model, and enable shadows on all light types
        #pragma surface surf StandardSpecular fullforwardshadows

        // Use shader model 3.0 target, to get nicer looking lighting
        #pragma target 3.0

        sampler2D _MainTex,_MainTexG,_MainTexB,_Mask;
        sampler2D _NormalR,_NormalG,_NormalB;
        sampler2D _SpecR,_SpecG,_SpecB;
        sampler2D _EmissionR,_EmissionG,_EmissionB;
        half4 _EmissionColor;

        struct Input {
            float2 uv_MainTex;
            float2 uv_MainTexG;
            float2 uv_MainTexB;
        };

        fixed4 _ColorR,_ColorG,_ColorB;

        void surf (Input IN, inout SurfaceOutputStandardSpecular o) {

            fixed4 mask = tex2D (_Mask, IN.uv_MainTex);
            // Albedo comes from a texture tinted by color
            fixed4 c = (tex2D (_MainTex, IN.uv_MainTex) * mask.r + tex2D (_MainTexG, IN.uv_MainTexG) * mask.g + tex2D (_MainTexB, IN.uv_MainTexB) * mask.b) * ( _ColorR * mask.r + _ColorG * mask.g + _ColorB * mask.b) ;

            o.Albedo = c.rgb;

            o.Normal = UnpackNormal ( tex2D (_NormalR, IN.uv_MainTex) * mask.r + tex2D (_NormalG, IN.uv_MainTexG) * mask.g + tex2D (_NormalB, IN.uv_MainTexB) * mask.b );

            fixed4 spec = tex2D (_SpecR, IN.uv_MainTex) * mask.r + tex2D (_SpecG, IN.uv_MainTexG) * mask.g + tex2D (_SpecB, IN.uv_MainTexB) * mask.b;
            o.Specular = spec.rgb;
            o.Smoothness = spec.a;

            o.Emission = _EmissionColor * ( tex2D (_EmissionR, IN.uv_MainTex) * mask.r + tex2D (_EmissionG, IN.uv_MainTexG) * mask.g + tex2D (_EmissionB, IN.uv_MainTexB) * mask.b );

            o.Alpha = c.a;
        }
        ENDCG
    }
    FallBack "Diffuse"
}