DRUGWARS.8XP

Lbl G
ClrHome
Disp "","","      J.M.'S DRUGWAR","        SIMULATION","","       VERSION 2.98"
2000→Z
5500→Y
{0,0,0,0,0,0,100}→⌊STASH
{0,0,0,0,0,0,0,0}→⌊DVARS
0→V
100→K
0→G
1→B
0→I
0→J
100→T
0→M
0→N
0→O
0→P
0→Q
0→R
100→U
0→θ
Pause
ClrHome
Disp "","      ORIGINAL GAME","        FOR IBM BY:","       JOHN E. DELL","",""
Output(8,8,"(1=YES,2=NO)"
Input "     INSTRUCTIONS? ",X
If X=1:Then
ClrHome
Disp "THIS IS A GAME OF BUYING","AND SELLING. YOUR GOAL IS","TO PAY OFF YOUR DEBT TO","THE LOAN SHARK, AND THEN","MAKE AS MUCH MONEY AS","POSSIBLE IN A 1 MONTH","PERIOD. WATCH OUT FOR THE","POLICE IF YOU DEAL TOO","HEAVILY! YOUR MAIN DRUG"
Pause
ClrHome
Disp "STASH WILL BE IN THE","BRONX. (IT'S A NICE","NEIGHBORHOOD)"
Pause
ClrHome
Disp "     PRICES FOR DRUGS","         PER UNIT","","  COCAINE     15000-30000","  HEROIN      5000-14000","  ACID        1000-4500","  WEED        300-900","  SPEED       70-250","  LUDES       10-60"
Pause
ClrHome
Disp "GENERALLY, TYPE THE FIRST","LETTER OF WHAT YOU WANT","TO DO, I.E.: W=WEED,","L=LUDES, ETC… BUT, 1=YES","AND 2=NO. THE LAST NUMBER","IN THE PRICES LIST IS YOUR","WALLET. THE LAST NUMBER IN","YOUR TRENCH COAT IS FREE","SPACE."
Pause
End
If X=2:Then
Goto R0
End
If X=3:Then
ClrHome
Disp "YOU FOUND A SECRET MAN !!"
Input "ENABLE ENDLESS MODE? ",X
If X=1:Then
ClrHome
Disp "WHEN ENDLESS MODE IS","ENABLED, THE GAME WILL GO","PAST THE NORMAL 31 DAYS","YOU ARE ALLOWED. A QUIT","OPTION WILL BE AVAILABLE","TO YOU ON THE MAIN MENU."
Pause
1→θ
θ→⌊DVARS(1)
Goto R0
Else
Goto R0
End
Goto R0
End

Lbl R0
ClrHome
Menu("RANDOMIZE METHOD","RANDOMIZE SEED",R1,"ENTER SEED",R2,"DON'T SEED",0)
Lbl R1
ClrHome
Disp "","","","PRESS ENTER TO","BEGIN RANDOMIZING"
Pause
ClrHome
Disp "","","","PRESS ENTER TO","STOP RANDOMIZING"
Repeat F=105
getKey→F
randInt(­8388608,8388607)
End
Ans→⌊DVARS(4)
Ans→rand
Goto 0
Lbl R2
ClrHome
Disp "ENTER SEED","(­8388608-8388607):"
Input "",F
If F<­8388608 or F>8388607:Then
Disp "SEED OUT OF RANGE"
Pause
Goto R2
End
F→⌊DVARS(4)
F→rand

Lbl 0
0→X
round(rand*1500+1500,0)*10→C
round(rand*900+500,0)*10→H
round(rand*350+100,0)*10→A
round(rand*60+30,0)*10→W
round(rand*18+7,0)*10→S
round(rand*5+1,0)*10→L
round(rand*19,0)→D
If D=0 or D=1
Goto A
If D=2:Then
ClrHome
Disp "YOU WERE MUGGED IN THE","SUBWAY !!"
Pause
(Z(4/5))→Z
(int(Z)→Z
Goto A
End
If D=3:Then
ClrHome
Disp "COPS MADE A BIG COKE","BUST !!  PRICES ARE","OUTRAGEOUS !!"
Pause
round(C*6,0)→C
Goto A
End
If D=4:Then
ClrHome
Disp "COLUMBIAN FREIGHTER","DUSTED THE COAST GUARD !!","WEED PRICES HAVE BOTTOMED","OUT !!"
Pause
W/5→W
(int(W)→W
Goto A
End
If D=5:Then
If K>70
Goto A
(int(rand*7+2)→F
If R>0:Then
(int(rand*7+2)→G
R/G→G
(int(G)→G
R-G→R
End
If Q>0:Then
(int(rand*7+2)→G
Q/G→G
(int(G)→G
Q-G→Q
End
If P>0:Then
(int(rand*7+2)→G
P/G→G
(int(G)→G
P-G→P
End
If O>0:Then
(int(rand*7+2)→G
O/G→G
(int(G)→G
O-G→O
End
If N>0:Then
(int(rand*7+2)→G
N/G→G
(int(G)→G
N-G→N
End
If M>0:Then
(int(rand*7+2)→G
M/G→G
(int(G)→G
M-G→M
End
(T-M-N-O-P-Q-R)→K
ClrHome
Disp "POLICE DOGS CHASE YOU","FOR   BLOCKS !!"
Output(2,5,F)
Pause
ClrHome
Disp "YOU DROPPED SOME DRUGS !!","THAT'S A DRAG MAN !!"
Pause
Goto A
End
If D=6:Then
If P<10
Goto A
(int(rand*4+2)→F
(int(P/F)→G
P-G→P
(T-M-N-O-P-Q-R)→K
ClrHome
Disp "YOUR MAMA MADE SOME","BROWNIES AND USED YOUR","WEED !!"
For(F,1,300)
End
Disp "","THEY WERE GREAT !!"
Pause
Goto A
End
If D=7:Then
ClrHome
Disp "PIGS ARE SELLING CHEAP","HEROIN FROM LAST WEEK'S","RAID !!"
Pause
round(H/6,0)→H
Goto A
End
If D=8:Then
If K<15
Goto A
randInt(1,15)→F
ClrHome
If F=1
Disp "YOU FOUND   UNIT OF:"
If F>1 and F<10
Disp "YOU FOUND   UNITS OF:"
If F≥10
Disp "YOU FOUND    UNITS OF:"
Output(1,11,F)
randInt(0,5)→X
If X=0:Then
Disp "           LUDES"
(R+F)→R
End
If X=1:Then
Disp "           SPEED"
(Q+F)→Q
End
If X=2:Then
Disp "            WEED"
(P+F)→P
End
If X=3:Then
Disp "            ACID"
(O+F)→O
End
If X=4:Then
Disp "          HEROIN"
(N+F)→N
End
If X=5:Then
Disp "         COCAINE"
(M+F)→M
End
Disp "ON A DEAD DUDE IN THE","SUBWAY !!"
(T-M-N-O-P-Q-R)→K
Pause
Goto A
End
If D=9:Then
ClrHome
Disp "THERE IS SOME WEED THAT","SMELLS LIKE PARAQUAT","HERE !! IT LOOKS GOOD !!","WILL YOU SMOKE IT?"
Input "",X
If X=1:Then
ClrHome
Disp "YOU HALLUCINATE FOR THREE","DAYS ON THE WILDEST TRIP","YOU EVER IMAGINED !!!"
For(F,1,300)
End
Disp "","THEN YOU DIE BECAUSE YOUR","BRAIN HAS DISINTEGRATED","!!!"
For(F,1,300)
End
Goto C
End
Goto A
End
If D=10:Then
ClrHome
Disp "RIVAL DRUG DEALERS RAIDED","A PHARMACY AND ARE SELLING","C H E A P  L U D E S !!!"
Pause
round(L/6,0)→L
Goto A
End
If D=11:Then
ClrHome
Disp "ADDICTS ARE BUYING HEROIN","AT OUTRAGEOUS PRICES!!"
Pause
round(H*6,0)→H
Goto A
End
If D=12:Then
ClrHome
Disp "THE MARKET HAS BEEN","FLOODED WITH CHEAP HOME-","MADE ACID!!!"
round(A/10,0)→A
Pause
Goto A
End
If D=13:Then
If Z<400
Goto A
ClrHome
randInt(250,400)→F
Disp "WILL YOU BUY A NEW TRENCH","COAT WITH MORE POCKETS","FOR     BUCKS?"
Output(3,5,F
F→G
Input "",X
If X=1:Then
int(rand*34+6)→F
(T+F)→T
(T-M-N-O-P-Q-R)→K
(Z-G)→Z
0→F:0→G
End
Goto A
End
If D=14:Then
If Z<500
Goto A
If K≥5:Then
ClrHome
int(rand*250+250)→F
randInt(250,500)→F
Disp "WILL YOU BUY A"
randInt(0,3)→X
If X=0
Disp "BERETTA"
If X=1
Disp "SATURDAY NIGHT SPECIAL"
If X=2
Disp ".38 SPECIAL"
If X=3
Disp "RUGER"
Disp "FOR     DOLLARS?"
Output(3,5,F)
Input "",X
If X=1:Then
(I+1)→I
(Z-F)→Z
(T-5)→T
(T-M-N-O-P-Q-R)→K
End
End
Goto A
End
If D≥15 and D≤19:Then
If (M+N+O+P+Q+R)≥50:Then
Goto RF
Else
(int(rand*30+1)→X

If X=1 or X=8 or X=15 or X=23:Then
Goto RF
Else
Goto 0
End
Lbl RF
int(randInt(1,100)/(K+1)→X
If X≥1:Then
round(X/0.62,0)+1→D
If D>63
63→D
ClrHome
Disp "OFFICER HARDASS AND"
If D<10
Disp "  OF HIS DEPUTIES","ARE AFTER YOU!"
If D≥10
Disp "   OF HIS DEPUTIES","ARE AFTER YOU!"
Output(2,1,D)
D+1→D
Pause
Goto M

Lbl M
If J≥100
Goto C
ClrHome
Menu("BEING CHASED!!","VIEW GUNS",H,"VIEW DAMAGE",I,"NUMBER OF PIGS",J,"RUN",K,"FIGHT",L)
Lbl H
ClrHome
Disp "NUMBER OF GUNS YOU HAVE:"
Disp I
Pause
Goto M
Lbl I
ClrHome
Disp "YOUR DAMAGE: "
Output(1,14,J)
Disp "","","","","","","(100 DAMAGE AND YOU DIE!)"
Pause
Goto M
Lbl J
ClrHome
Disp "THERE ARE:"
Output(1,12,D)
Disp "PIGS STILL CHASING YOU!"
Pause
Goto M
Lbl K
ClrHome
Output(5,9,"RUNNING")
For(F,1,250)
End
(int(rand*6)→X
If X=0 or X=1:Then
Lbl GA
ClrHome
Disp "YOU LOST THEM IN THE","ALLEYS !!"
Pause
If B=31
Goto A
Goto 0
End
If X≥2 and X≤4:Then
ClrHome
Disp "YOU CAN'T SHAKE THEM!"
Pause
Goto O
End
If X=5:Then
int(rand*6)→X
If X=0:Then
If R<1:Then
Goto GA
Else
"           LUDES"→Str4
randInt(1,10)→G
If R-G<0:Then
R→G
(R-G)→R
End
End
End
If X=1:Then
If Q<1:Then
Goto GA
Else
"           SPEED"→Str4
randInt(1,10)→G
If Q-G<0:Then
Q→G
(Q-G)→Q
End
End
End
If X=2:Then
If P<1:Then
Goto GA
Else
"            WEED"→Str4
randInt(1,10)→G
If P-G≤0:Then
P→G
(P-G)→P
End
End
End
If X=3:Then
If O<1:Then
Goto GA
Else
"            ACID"→Str4
randInt(1,10)
If O-G≤0:Then
O→G
(O-G)→O
End
End
End
If X=4:Then
If N<1:Then
Goto GA
Else
"          HEROIN"→Str4
randInt(1,10)→G
If N-G≤0:Then
N→G
(N-G)→N
End
End
End
If X=5:Then
If M<1:Then
Goto GA
Else
"         COCAINE"→Str4
randInt(1,10)→G
If M-G≤0:Then
M→G
(M-G)→M
End
End
End
End
ClrHome
Disp "    YOU LOST THEM !!",""
For(F,1,300)
End
Disp "BUT YOU DROPPED"
If G=1
Disp "  UNIT OF",Str4,"DURING THE CHASE !!"
If G=0 or G>1 and G<10
Disp "  UNITS OF",Str4,"DURING THE CHASE !!"
If G=10
Disp "   UNITS OF",Str4,"DURING THE CHASE !!"
Output(4,1,G)
Pause
If B=31
Goto A
Goto 0

Lbl L
If I=0:Then
ClrHome
Disp "YOU DON'T HAVE ANY GUNS!"
Pause
Disp "YOU HAVE TO RUN!"
Pause
Goto M
End
ClrHome
Disp "YOU'RE FIRING ON THEM !!!","","",""
0→E
Pause
For(F,1,I)
int(rand*(I*2)→X
If X=0:Then
Disp "YOU MISSED THEM !!!"
Pause
Else
Disp "YOU KILLED ONE !!"
(E+1)→E
(D-1)→D
Pause
If D≤0
Goto N
End
End
ClrHome
If E=0
Goto O
If E=1
Disp "","","","     KILLED   PIG !!"
If E>1 and E<10
Disp "","","","     KILLED   PIGS !!"
If E≥10
Disp "","","","     KILLED    PIGS !!"
Output(4,13,E)
Pause
If D=1
Goto O
int(rand*2)→X
If X=0
Goto O
int(rand*((D/3)/1)+1→X
ClrHome
If X=1
Disp "","","","1 PIG FLED THE SCENE !!"
If X>1 and X<10
Disp "","","","  PIGS FLED THE SCENE !!"
If X≥10
Disp "","","","   PIGS FLED THE SCENE !!"
Output(4,1,X)
D-X→D
Pause
Lbl O
int(rand*3)*D-(int(rand*19+2)→X
ClrHome
Disp "THEY ARE FIRING","ON YOU MAN !!"
Pause
If X=0:Then
Disp "","","THEY MISSED !!"
Pause
Goto M
Else
Disp "","","YOU'VE BEEN HIT !!"
Pause
If X<0
­X→X
D→E
If E>15
15→E
If I≠0:Then
If J≠0 and K≠0:Then
If (int(rand*100))<(J/K)*100 or (J/K)*100>80:Then
1→E
(int(rand*20)→F
If F≥19:Then
ClrHome
Disp "YOU DROPPED A GUN","WHILE RUNNING !!","THAT'S A DRAG MAN !!"
Pause
I-1→I
T+5→T
(T-M-N-O-P-Q-R)→K
End
End
End
End
(int(rand*(X*0.5)*E*1)+(E/2)→F
(J+F)→J
(int(J)→J
If J≥100:Then
Disp "THEY WASTED YOU MAN !!!","WHAT A DRAG !!!"
Pause
Goto C
Else
Goto M
End
Goto M
End
Lbl N
ClrHome
Disp "YOU KILLED ALL","OF THEM !!!!",""
int((rand*5801+200)→X
(Z+X)→Z
Pause
If X<1000
Disp "YOU FOUND     DOLLARS ON"
If X≥1000
Disp "YOU FOUND      DOLLARS ON"
Output(4,11,X)
Disp "OFFICER HARDASS'","CARCASS !!!"
Pause
If Z≥1200 and J≥1:Then
ClrHome
(int(rand*801+200)+(J*50)→F
If F<1000
Disp "WILL YOU PAY     DOLLARS"
If F≥1000
Disp "WILL YOU PAY      DOLLARS"
Disp "TO HAVE A DOCTOR SEW","YOU UP?"
Output(1,14,F
Input "",X
If X=1:Then
If (Z-F)<0:Then
ClrHome
Disp "COME BACK WHEN YOU","HAVE THE CASH"
Pause
Goto 0
Else
(Z-F)→Z
0→J
End
End
If X=2:Then
ClrHome
Disp "BEAT IT KID !!"
Pause
Goto 0
End
End
Goto 0
End
End
End
Lbl A
If B=1:Then
2→X
X→⌊DVARS(2)
End
If B=31 and θ=0:Then
If ⌊DVARS(3)=0:Then
ClrHome
Disp "","","","","        LAST DAY!!","     SELL YOUR SHIT!!"
Pause
1→⌊DVARS(3)
End
End
ClrHome
⌊DVARS(1)→θ
If θ=1
Menu("DRUGWAR!","SEE PRICES",1,"TRENCH COAT",2,"BUY",3,"SELL",4,"JET",5,"CHECK STASH",6,"SEE LOAN SHARK",7,"VISIT BANK",8,"QUIT",C)
Menu("DRUGWAR!","SEE PRICES",1,"TRENCH COAT",2,"BUY",3,"SELL",4,"JET",5,"CHECK STASH",6,"SEE LOAN SHARK",7,"VISIT BANK",8)
Lbl 1
ClrHome
Disp C,H,A,W,S,L,"",Y,Z
Output(1,1,"COCAINE")
Output(2,1,"HEROIN")
Output(3,1,"ACID")
Output(4,1,"WEED")
Output(5,1,"SPEED")
Output(6,1,"LUDES")
Output(8,1,"DEBT")
Output(9,1,"WALLET")
Pause
Goto A
Lbl 2
ClrHome
Disp M,N,O,P,Q,R,"",I,K
Output(1,1,"COCAINE")
Output(2,1,"HEROIN")
Output(3,1,"ACID")
Output(4,1,"WEED")
Output(5,1,"SPEED")
Output(6,1,"LUDES")
Output(8,1,"GUNS")
Output(9,1,"FREE SPACE")
Pause
Goto A
Lbl 3
ClrHome
Disp "          DAY",""
Output(1,15,B)
Input "WHAT TO BUY? ",F
If F=0
Goto A
If F≠C and F≠H and F≠A and F≠W and F≠S and F≠L
Goto 3
If F=C
1→X
If F=H
2→X
If F=A
3→X
If F=W
4→X
If F=S
5→X
If F=L
6→X
int((Z/F)→E
Disp "","HOW MUCH","WILL YOU BUY ?"
If E<10
Disp "YOU CAN AFFORD (   )"
If E≥10 and E<100
Disp "YOU CAN AFFORD (    )"
If E≥100 and E<1000
Disp "YOU CAN AFFORD (     )"
If E≥1000 and E<10000
Disp "YOU CAN AFFORD (      )"
If E≥10000 and E<100000
Disp "YOU CAN AFFORD (       )"
If E≥100000
Disp "YOU CAN AFFORD (        )"
If K<10
Disp "YOU CAN HOLD (   )"
If K≥10 and K<100
Disp "YOU CAN HOLD (    )"
If K≥100 and K<1000
Disp "YOU CAN HOLD (     )"
If K≥1000
Disp "YOU CAN HOLD (      )"
If X=1
Output(5,10,"COCAINE")
If X=2
Output(5,10,"HEROIN")
If X=3
Output(5,10,"ACID")
If X=4
Output(5,10,"WEED")
If X=5
Output(5,10,"SPEED")
If X=6
Output(5,10,"LUDES")
Output(7,18,E)
Output(8,16,K)
Input "",G
If G>K:Then
ClrHome
Disp "","","","","      YOU CAN'T HOLD","     THAT MANY MAN !!"
Pause
Goto 3
End
If G<0:Then
ClrHome
Disp "","","","","      ARE YOU HIGH??","  YOU CAN'T BUY NEGATIVE","       DRUGS MAN !!"
Pause
Goto 3
End
If G>E:Then
ClrHome
Disp "","","","","      YOU DON'T HAVE","     THAT MUCH MAN !!"
Pause
Goto 3
End
(Z-(FG))→Z
If F=C
(M+G)→M
If F=H
(N+G)→N
If F=A
(O+G)→O
If F=W
(P+G)→P
If F=S
(Q+G)→Q
If F=L
(R+G)→R
(T-M-N-O-P-Q-R)→K
Goto A
Lbl 4
ClrHome
Disp "          DAY",""
Output(1,15,B)
Input "WHAT TO SELL? ",F
If F=0
Goto A
If F≠C and F≠H and F≠A and F≠W and F≠S and F≠L
Goto 4
If F=C:Then
1→X
M→E
End
If F=H:Then
2→X
N→E
End
If F=A:Then
3→X
O→E
End
If F=W:Then
4→X
P→E
End
If F=S:Then
5→X
Q→E
End
If F=L:Then
6→X
R→E
End
Disp "","HOW MUCH","WILL YOU SELL ?"
If E<10
Disp "YOU HAVE (   )"
If E≥10 and E<100
Disp "YOU HAVE (    )"
If E≥100 and E<1000
Disp "YOU HAVE (     )"
If E≥1000
Disp "YOU HAVE (      )"
If X=1
Output(5,10,"COCAINE")
If X=2
Output(5,10,"HEROIN")
If X=3
Output(5,10,"ACID")
If X=4
Output(5,10,"WEED")
If X=5
Output(5,10,"SPEED")
If X=6
Output(5,10,"LUDES")
Output(7,12,E)
Input "",G
If G>E:Then
ClrHome
Disp "","","","","      YOU DON'T HAVE","     THAT MANY MAN !!"
Pause
Goto 4
End
If G<0:Then
ClrHome
Disp "","","","","      ARE YOU HIGH??","  YOU CAN'T SELL NEGATIVE","       DRUGS MAN !!"
Pause
Goto 4
End
If F=C
(M-G)→M
If F=H
(N-G)→N
If F=A
(O-G)→O
If F=W
(P-G)→P
If F=S
(Q-G)→Q
If F=L
(R-G)→R
(Z+FG)→Z
(T-M-N-O-P-Q-R)→K
Goto A
Lbl 5
ClrHome
Menu("WHERE TO, DUDE?","BRONX",R,"GHETTO",B,"CENTRAL PARK",B,"MANHATTAN",B,"CONEY ISLAND",B,"BROOKLYN",B,"OOPS… STAY!",A)
Lbl R
⌊DVARS(2)→X
If X=2:Then
ClrHome
Disp "YOU'RE ALREADY","IN THE BRONX!"
Pause
Goto 5
End
2→X
X→⌊DVARS(2)
Goto S
Lbl B
1→X
X→⌊DVARS(2)
Lbl S
If B=31 and θ=0
Goto C
ClrHome
Disp "","","","","     SUBWAY"
(B+1)→B
int((Y*1.10)→Y
int((V*1.05)→V
Goto 0
Lbl 6
⌊DVARS(2)→X
If X=1:Then
ClrHome
Disp "YOUR STASH IS IN THE","BRONX!!","","YOU CAN'T ACCESS IT","FROM HERE, MAN!!"
Pause
Goto A
End
ClrHome
Menu("YOUR STASH","CHECK STASH",CS,"TAKE DRUGS",TD,"STASH DRUGS",SD,"NEVER MIND",A)
Lbl CS
ClrHome
Disp ⌊STASH(1),⌊STASH(2),⌊STASH(3),⌊STASH(4),⌊STASH(5),⌊STASH(6),"","",⌊STASH(7)
Output(1,1,"COCAINE")
Output(2,1,"HEROIN")
Output(3,1,"ACID")
Output(4,1,"WEED")
Output(5,1,"SPEED")
Output(6,1,"LUDES")
Output(9,1,"FREE SPACE")
Pause
Goto 6
Lbl SD
ClrHome
Disp "DAY NUMBER:",B
Input "WHAT TO STASH? ",F
If F≠C and F≠H and F≠A and F≠W and F≠S and F≠L
Goto 3
If F=C:Then:M→E:1→X:End
If F=H:Then:N→E:2→X:End
If F=A:Then:O→E:3→X:End
If F=W:Then:P→E:4→X:End
If F=S:Then:Q→E:5→X:End
If F=L:Then:R→E:6→X:End
⌊STASH(7)→G
Disp "","STASH HOW MUCH"
If G<10
Disp "YOU CAN STASH (   )"
If G≥10 and G<100
Disp "YOU CAN STASH (    )"
If G=100
Disp "YOU CAN STASH (     )"
If X=1
Output(5,16,"COCAINE?")
If X=2
Output(5,16,"HEROIN?")
If X=3
Output(5,16,"ACID?")
If X=4
Output(5,16,"WEED?")
If X=5
Output(5,16,"SPEED?")
If X=6
Output(5,16,"LUDES?")
Output(6,17,⌊STASH(7))
Input "",G
If G>E or G>⌊STASH(7) or G<0
Goto SD
If F=C:Then
(⌊STASH(1)+G)→⌊STASH(1):M-G→M:End
If F=H:Then
(⌊STASH(2)+G)→⌊STASH(2):N-G→N:End
If F=A:Then
(⌊STASH(3)+G)→⌊STASH(3):O-G→O:End
If F=W:Then
(⌊STASH(4)+G)→⌊STASH(4):P-G→P:End
If F=S:Then
(⌊STASH(5)+G)→⌊STASH(5):Q-G→Q:End
If F=L:Then
(⌊STASH(6)+G)→⌊STASH(6):R-G→R:End
(T-M-N-O-P-Q-R)→K
(U-⌊STASH(1)-⌊STASH(2)-⌊STASH(3)-⌊STASH(4)-⌊STASH(5)-⌊STASH(6))→⌊STASH(7)
Goto 6
Lbl TD
ClrHome
Disp "DAY NUMBER:",B
Input "WHAT TO TAKE? ",F
If F≠C and F≠H and F≠A and F≠W and F≠S and F≠L
Goto 4
If F=C:1→E
If F=H:2→E
If F=A:3→E
If F=W:4→E
If F=S:5→E
If F=L:6→E
Disp "","TAKE HOW MUCH"
If ⌊STASH(E)<10
Disp "YOU CAN TAKE (   )"
If ⌊STASH(E)≥10 and ⌊STASH(E)<100
Disp "YOU CAN TAKE (    )"
If ⌊STASH(E)≥100 and ⌊STASH(E)<1000
Disp "YOU CAN TAKE (     )"
If ⌊STASH(E)≥1000
Disp "YOU CAN TAKE (      )"
If E=1
Output(5,15,"COCAINE?")
If E=2
Output(5,15,"HEROIN?")
If E=3
Output(5,15,"ACID?")
If E=4
Output(5,15,"WEED?")
If E=5
Output(5,15,"SPEED?")
If E=6
Output(5,15,"LUDES?")
Output(6,16,⌊STASH(E))
Input "",G
If G>⌊STASH(E) or G<0
Goto TD
If F=C:Then
(⌊STASH(1)-G)→⌊STASH(1):M+G→M:End
If F=H:Then
(⌊STASH(2)-G)→⌊STASH(2):N+G→N:End
If F=A:Then
(⌊STASH(3)-G)→⌊STASH(3):O+G→O:End
If F=W:Then
(⌊STASH(4)-G)→⌊STASH(4):P+G→P:End
If F=S:Then
(⌊STASH(5)-G)→⌊STASH(5):Q+G→Q:End
If F=L:Then
(⌊STASH(6)-G)→⌊STASH(6):R+G→R:End
(T-M-N-O-P-Q-R)→K
(U-⌊STASH(1)-⌊STASH(2)-⌊STASH(3)-⌊STASH(4)-⌊STASH(5)-⌊STASH(6))→⌊STASH(7)
Goto 6
Lbl 7
⌊DVARS(2)→X
If X=1:Then
ClrHome
Disp "THE LOAN SHARK ONLY DEALS","IN THE BRONX."
Pause
Goto A
End
ClrHome
Menu("LOAN SHARK…","REPAY",P,"BORROW",Q)
Lbl P
ClrHome
Disp "YOUR DEBT IS: $","","YOUR WALLET: $","","HOW MUCH TO REPAY ?"
Output(1,16,Y)
Output(3,15,Z)
Input "$",F
If F>Z or F<0 or F>Y
Goto 7
(Y-F)→Y
(Z-F)→Z
Goto A
Lbl Q
ClrHome
Disp "YOUR DEBT: $","","YOUR WALLET: $","","HOW MUCH TO BORROW ?"
Output(1,13,Y)
Output(3,15,Z)
Input "$",F
If F>9450:Then
ClrHome
Disp "YOU THINK HE IS CRAZY,","MAN !!!"
Pause
Goto Q
End
If F<0
Goto 7
(Y+F)→Y
(Z+F)→Z
Goto A
Lbl 8
ClrHome
Menu("      BANK      ","CHECK BALANCE",D,"DEPOSIT",E,"WITHDRAW",F,"GOODBYE",A)
Lbl D
ClrHome
Disp "YOUR ACCOUNT:","$"
Output(2,2,V)
Pause
Goto 8
Lbl NS
ClrHome
Disp "YOU CAN ONLY","DEPOSIT AND","WITHDRAW CASH","AT THE BRONX","BRANCH!!"
Pause
Goto 8
Lbl E
⌊DVARS(2)→X
If X=1
Goto NS
ClrHome
Disp "HOW MUCH TO DEPOSIT?","YOU HAVE: $",""
Output(2,12,Z)
Input "$",G
If G>Z or G<0
Goto E
If G=0
Goto 8
(V+G)→V
(Z-G)→Z
Goto 8
Lbl F
⌊DVARS(2)→X
If X=1
Goto NS
ClrHome
Disp "HOW MUCH TO WITHDRAW?","BALANCE: $",""
Output(2,11,V)
Input "$",G
If G=0
Goto 8
If G>V or G<0
Goto F
(V-G)→V
(Z+G)→Z
Goto 8
Lbl C
ClrHome
Output(5,5,"CONGRATULATIONS !!
For(F,1,450)
End
ClrHome
Disp "","","        GAME OVER!",""
(V+Z-Y)→V
If V<0:Then
0→V
Else
√(V/31.5)/5.25→V
If V>100
100→V
End
round(V,0)→V
Disp "","        YOUR SCORE","      (ON A SCALE OF","      1 TO 100): ",""
Output(8,18,V)
Pause
ClrHome
Input "PLAY AGAIN? ",V
If V=1
Goto G
ClrHome
Disp "","","","","        THANKS FOR","        PLAYING !!"
Pause
ClrHome
"