#Name: boss_summoning.zs
#reloadable
#Author: Keaft

import crafttweaker.data.IData;
import crafttweaker.block.IBlock;
import crafttweaker.block.IBlockState;
import crafttweaker.command.ICommandManager;
import crafttweaker.entity.AttributeInstance;
import crafttweaker.entity.IEntity;
import crafttweaker.entity.IEntityDefinition;
import crafttweaker.entity.IEntityEquipmentSlot;
import crafttweaker.entity.IEntityLivingBase;
import crafttweaker.event.EntityJoinWorldEvent;
import crafttweaker.event.IEventCancelable;
import crafttweaker.event.PlayerInteractBlockEvent;
import crafttweaker.event.PlayerInteractEvent;
import crafttweaker.events.IEventManager;
import crafttweaker.formatting.IFormattedText;
import crafttweaker.item.IItemStack;
import crafttweaker.world.IBlockPos;
import crafttweaker.world.IWorld;
import crafttweaker.player.IPlayer;

zenClass BasicBoss {
    // statics can't change
    static name as string = "tacoZombie";

    // variables can be changed, DO declare variables for everything that I want to be able to change, likely establish defaults, but definitely vars for changing.
    var bossEvent as PlayerInteractBlockEvent;
    var bossClass as IEntityLivingBase;
    var maxHealth as int = 50;
    var armor as int = 0;
    var mainHandSlotItem as IItemStack = null;
    var offHandSlotItem as IItemStack = null;
    var headSlotItem as IItemStack = <minecraft:diamond_helmet>;
    var chestSlotItem as IItemStack = null;
    var legsSlotItem as IItemStack = null;
    var feetSlotItem as IItemStack = null;
    var localSummonMessage as string = "You feel the ground shake beneath you.";

    // methods (functions), bits of functionality.

    zenConstructor(eventParam as PlayerInteractBlockEvent){ // called whenever the class is initialized. Every call does the following instructions. Makes sure that I don't have to call every instruction every time.
        bossEvent = eventParam;
        // bossEvent.player.sendMessage("hi");
        var bossClass as IEntityLivingBase = <entity:minecraft:zombie>.createEntity(bossEvent.entityLivingBase.world);
        // bossEvent.player.sendMessage(this.bossClass.displayName as string);
        bossClass.setPosition(crafttweaker.util.Position3f.create(bossEvent.x, bossEvent.y + 1, bossEvent.z).asBlockPos());
        bossClass.setCustomName(name);
        bossClass.setItemToSlot(crafttweaker.entity.IEntityEquipmentSlot.mainHand(),mainHandSlotItem);
        bossClass.setItemToSlot(crafttweaker.entity.IEntityEquipmentSlot.offhand(),offHandSlotItem);
        bossClass.setItemToSlot(crafttweaker.entity.IEntityEquipmentSlot.head(),headSlotItem);
        bossClass.setItemToSlot(crafttweaker.entity.IEntityEquipmentSlot.chest(),chestSlotItem);
        bossClass.setItemToSlot(crafttweaker.entity.IEntityEquipmentSlot.legs(),legsSlotItem);
        bossClass.setItemToSlot(crafttweaker.entity.IEntityEquipmentSlot.feet(),feetSlotItem);
        bossClass.getAttribute("generic.maxHealth").baseValue = maxHealth; // Setting a baseValue needs a double even though the int works?
        bossClass.getAttribute("generic.armor").baseValue = armor;
        bossClass.health = maxHealth; // Health is a float???
        bossEvent.entityLivingBase.world.spawnEntity(bossClass);
        server.commandManager.executeCommand(server,"execute @a[x=" + bossEvent.x as int + ",y=" + bossEvent.y as int + ",z=" + bossEvent.z as int + ",r=15] ~ ~ ~ tellraw @a[x=~1,y=~1,z=~1,rm=0,r=15] [\"" + localSummonMessage + "\"]");

        // setBossPosition(bossEvent.x, bossEvent.y + 1, bossEvent.z);
    }

    // function setBossPosition(posX as int, posY as int, posZ as int){

    // }

    // function spawnBoss(){
        // bossEvent.player.sendMessage("saved the event properly.");
        // bossEvent.player.sendMessage(bossClass.displayName);

    //     this.bossClass.setPosition(crafttweaker.util.Position3f.create(eventParam.x, eventParam.y + 1, eventParam.z).asBlockPos());
        // bossEvent.entityLivingBase.world.spawnEntity(bossClass);
    // }
}

print("Initializing 'boss_summoning'...");

var altarBlocks = [
    <minecraft:stone>/* ,
    <minecraft:grass> */
] as IBlock[];

var spawnItems = [
    <minecraft:diamond>
] as IItemStack[];
// Associative array to associate IBlock with IEntityLivingBase

/*     val changingArray = {
        <minecraft:dirt> : zombie
    } as IEntityLivingBase[IItemStack]; */

events.onPlayerInteractBlock(function(event as PlayerInteractBlockEvent){
var currentAltar as IItemStack = null;
var currentItem as IItemStack = null;
var currentHand as string = null;
    // If it is on the client or the OFF_HAND, do not continue. 1.12.2 forge doesn't seem to be able to differentiate which hand is being fired here while crafttweaker does, but limiting it to 1 makes sure it doesn't fire multiple times.
    if(event.world.remote || event.hand == "OFF_HAND") {
        return;
    }
    // Find if the block right clicked is an altar block, and then record which block it is to later determine boss summon.
    for i, block in altarBlocks {
        if (block has event.block) {
            currentAltar = block;
            break;
        }
    }
    // If block is found proceed, otherwise ignore.
	if (!isNull(currentAltar)) {
        // Record each hand's current items
		var mhItem = event.player.mainHandHeldItem;
		var ohItem = event.player.offHandHeldItem;
        // If the current held items are null, stop here.
        if (isNull(mhItem) && isNull(ohItem)){
            return;
        }
        // Check if the held item is in the spawnItems list and write which item it is to later determine properties about the boss, as well as write which hand the item was found in prioritizing the main hand.
        for i, item in spawnItems {
            if (!isNull(mhItem) && item has mhItem){
                currentItem = item;
                currentHand = "main";
                break;
            }
            if (!isNull(ohItem) && item has ohItem){
                currentItem = item;
                currentHand = "offhand";
                break;
            }
        }
        // If the currentItem isn't written and still null, then inform the player and stop here.
        if (isNull(currentItem)){
                event.player.sendMessage("The altar rejects your offering.");
                event.cancel();
                return;
            }
        // Erase the item from the correct hand if 1, and Subtract the item if greater than 1.
        if (currentHand == "main"){
			event.player.setItemToSlot(IEntityEquipmentSlot.mainHand(), mhItem.amount == 1 ? null : mhItem.withAmount(mhItem.amount - 1));
            event.player.sendMessage("The " + mhItem.displayName + " wrenches from your hand.");
        } else {
            event.player.setItemToSlot(IEntityEquipmentSlot.offhand(), ohItem.amount == 1 ? null : ohItem.withAmount(ohItem.amount - 1));
            event.player.sendMessage("The " + ohItem.displayName + " wrenches from your hand.");
        }
        // Perform boss summon here.
        var myBasicBoss = BasicBoss(event); // this is a function call to the constructor
        // myBasicBoss.spawnBoss();
	}
});

print("Initialized 'boss_summoning'");