POST_41

[code]
/*  TITULO: Robot láser controlado con un Joystick Analógico.

    AUTOR:

    MARIANO DEL CAMPO GARCÍA (@2016) --> INGENIERO TÉCNICO INDUSTRIAL ESPECIALIDAD ELECTRÓNICA
    - FACEBOOK: https://www.facebook.com/mariano.delcampogarcia
    - TWITTER: https://twitter.com/MarianoCampoGa
    - CORREO: marianodc83@gmail.com


    DESCRIPCIÓN DEL PROGRAMA

    Con este programa controlamos la posición del punto rojo de un láser (que he adherido a una
    plataforma de dos ejes gobernada por mricro servos SG90) mediante un joystick analógico.
    Descomentando dos partes del código, podremos visualizar el ángulo que tiene el láser
    respecto del eje x y del eje y, a través del monitor serie del IDE de Arduino.


    ESQUEMA DE CONEXION

                                      +-----+
         +----[PWR]-------------------| USB |--+
         |                            +-----+  |
         |         GND/RST2  [ ][ ]            |
         |       MOSI2/SCK2  [ ][ ]  A5/SCL[ ] |
         |          5V/MISO2 [ ][ ]  A4/SDA[ ] |
         |                             AREF[ ] |
         |                              GND[ ] |
         | [ ]N/C                    SCK/13[ ] |
         | [ ]IOREF                 MISO/12[ ] |
         | [ ]RST                   MOSI/11[ ]~|
         | [ ]3V3    +---+               10[ ]~|  Cable Naranja del servo_y
         | [ ]5v    -| A |-               9[ ]~|  Cable Naranja del servo_x
         | [ ]GND   -| R |-               8[ ] |  Pin SW del joystick
         | [ ]GND   -| D |-                    |
         | [ ]Vin   -| U |-               7[ ] |  Pin S del módulo láser
         |          -| I |-               6[ ]~|
    VRx  | [ ]A0    -| N |-               5[ ]~|
    VRy  | [ ]A1    -| O |-               4[ ] |
         | [ ]A2     +---+           INT1/3[ ]~|
         | [ ]A3                     INT0/2[ ] |
         | [ ]A4/SDA  RST SCK MISO     TX>1[ ] |
         | [ ]A5/SCL  [ ] [ ] [ ]      RX<0[ ] |
         |            [ ] [ ] [ ]              |
         |  UNO_R3    GND MOSI 5V  ____________/
          \_______________________/

  NOTAS:

   - Conexión del joystick:
       - VCC del joystick --> VCC de Arduino
       - GND del joystick --> GND de Arduino
       - VRx --> Pin analógico A0 de Arduino
       - VRy --> Pin analógico A1 de Arduino
       - SW --> Pin digital 8 de Arduino
   - Conexión del módulo láser:
       - VCC del módulo láser --> VCC de Arduino
       - GND del módulo láser  --> GND de Arduino
       - S del módulo láser  --> Pin digital 7 de Arduino
   - Alimentación de los micro servos de la plataforma
       - Cable rojo de los micro servos --> VCC de Arduino
       - Cable marrón de los micro servos --> GND de Arduino
*/

  // Incluir la librería Servo
  #include <Servo.h>

  Servo servo_x; // Crear un objeto tipo Servo llamado servo_x para el movimiento X de la plataforma
  Servo servo_y; // Crear un objeto tipo Servo llamado servo_y para el movimiento Y de la plataforma

  // Variables para el funcionamiento del programa
  int angulo_x = 90 ;
  int angulo_y = 90 ;
  int valor_x = 0;
  int valor_y = 0;
  int potenciometro_x = A0;
  int potenciometro_y = A1;
  int pulsador_SW = 8 ;
  int LASER = 7 ;
  int encender = 0;
  int anterior = 0;
  int estado = 0;

  void setup()
  {
    Serial.begin(9600);  // Comienzo de la comunicación serie
    servo_x.attach(9) ;  // Pin digital 9 para el servo_x
    servo_y.attach(10) ; // Pin digital 10 para el servo_y

    pinMode(pulsador_SW, INPUT_PULLUP) ; // Pin digital 8 como entrada PULL-UP
    pinMode(LASER, OUTPUT); // Pin digital 7 como salida
  }

  void loop()
  {
    mover_servo_x(); // Llamada a la función que mueve el eje x de la plataforma
    mover_servo_y(); // Llamada a la función que mueve el eje y de la plataforma

    delay(60); // Control de la velocidad del robot

    disparo_LASER();  // Llamada a la función que enciende/apaga el láser
  }

  // Función que mueve el eje x de la plataforma
  void mover_servo_x()
  {
   // Lee el valor del potenciómetro en X
    valor_x = analogRead(potenciometro_x);

    // Si la lectura es mayor de 600
    if ( valor_x > 600 )
    {
      if( angulo_x > 30) // Límitamos el ángulo mínimo en x a 30º
      {
        angulo_x--; // Disminuimos el ángulo en x un grado
      }
    }

    // Si la lectura es menor de 400
    else if (valor_x < 400)
    {
      if( angulo_x < 150) // Limitamos el ángulo máximo en x a 150º
      {
        angulo_x++; // Aumentamos el ángulo en x un grado
      }
    }
    servo_x.write(angulo_x); // Movemos el servo_x

    // Descomentar únicamente para visualizar la posición del láser en el eje y.
    // Serial.print("Angulo Eje X: ");
    // Serial.println(angulo_x);
    // delay(100); Para visualizar los valores a través del monitor serie
  }

  // Función que mueve el eje y de la plataforma
  void mover_servo_y()
  {
   // Lee el valor del potenciómetro en Y
    valor_y = analogRead(potenciometro_y);

    // Si la lectura es mayor de 600
    if (valor_y > 600)
    {
      if( angulo_y < 150)  // Limitamos el ángulo máximo en y a 150º
      {
        angulo_y++;    // Aumentamos el ángulo en y un grado
      }
    }

    // Si la lectura es menor de 400
    else if ( valor_y < 400 )
    {
      if( angulo_y > 30) // Limitamos el ángulo mínimo en y a 30º
      {
        angulo_y-- ;    // Disminuimos el ángulo en y un grado
      }
    }
    servo_y.write(angulo_y); // Movemos el servo_y

    // Descomentar únicamente para visualizar la posición del láser en el eje y.
    // Serial.print("Angulo Eje Y: ");
    // Serial.println(angulo_y);
    // delay(100); Para visualizar los valores a través del monitor serie
  }

  // Función que enciende/apaga el láser
  void disparo_LASER()
  {
    estado = digitalRead(pulsador_SW); // Guardamos el estado actual del pulsador_SW

    if(estado && anterior == 0) // Comparamos el estado actual y el anterior del pulsador
    {
      encender = 1 - encender;
      delay(200); // Evita los rebotes del pulsador_SW
    }

    anterior = estado; // Actualizamos el estado del pulsador SW

    if(encender) // Si el estado interno del pulsador pasa de "LOW" a "HIGH".
    {
      digitalWrite(LASER, LOW); // LÁSER apagado
    }

    else // Si el estado interno del pulsador pasa de "HIGH" a "LOW".
    {
      digitalWrite(LASER, HIGH); // LÁSER encendido
    }
  }


[/code]